From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1183763-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 717821382C5
for <garchives@archives.gentoo.org>; Wed, 1 Jul 2020 03:08:02 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id A3156E08FF;
Wed, 1 Jul 2020 03:08:01 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 761C4E08FF
for <gentoo-commits@lists.gentoo.org>; Wed, 1 Jul 2020 03:08:01 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id AE64434F19C
for <gentoo-commits@lists.gentoo.org>; Wed, 1 Jul 2020 03:07:58 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 6EE7A2C5
for <gentoo-commits@lists.gentoo.org>; Wed, 1 Jul 2020 03:07:54 +0000 (UTC)
From: "Michał Górny" <mgorny@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Michał Górny" <mgorny@gentoo.org>
Message-ID: <1593572871.c4256f68d3589570443075eccbbafacf661f785f.mgorny@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-python/pillow/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-python/pillow/Manifest dev-python/pillow/pillow-7.2.0.ebuild
X-VCS-Directories: dev-python/pillow/
X-VCS-Committer: mgorny
X-VCS-Committer-Name: Michał Górny
X-VCS-Revision: c4256f68d3589570443075eccbbafacf661f785f
X-VCS-Branch: master
Date: Wed, 1 Jul 2020 03:07:54 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 2a3d7cc3-d434-49a9-88ab-9cc0438b370f
X-Archives-Hash: 49a4f0adaa4b8eb08dbded661758f34b
commit: c4256f68d3589570443075eccbbafacf661f785f
Author: Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Wed Jul 1 02:53:58 2020 +0000
Commit: Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Wed Jul 1 03:07:51 2020 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=c4256f68
dev-python/pillow: Bump to 7.2.0
Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>
dev-python/pillow/Manifest | 1 +
dev-python/pillow/pillow-7.2.0.ebuild | 100 ++++++++++++++++++++++++++++++++++
2 files changed, 101 insertions(+)
diff --git a/dev-python/pillow/Manifest b/dev-python/pillow/Manifest
index 03200d461bc..3e752043770 100644
--- a/dev-python/pillow/Manifest
+++ b/dev-python/pillow/Manifest
@@ -1,3 +1,4 @@
DIST pillow-6.2.2.tar.gz 37538464 BLAKE2B dfd9b81490a8adb4e12ecbf6764e4e27573c9a087877ac37275a9fb42b89f0cd8cab8d7ca0b45c9a00bf38ca5b1d83de68f5fc35ff19031bfcc1495ee3a5f5b7 SHA512 0f2c3bfd921247fa11645eadc42e184182a401ccbdb8f10215312e96c8c28f2382f5413b56acd78fab1dffc6fa53cc8588ce960543af65c4769451874c2c918e
DIST pillow-7.0.0.tar.gz 37880130 BLAKE2B be940cbdced884c33f2b3979be113b1bc8974814c9532fe80203395184f90eccba1cd9a5017fec1f0c30a21ff06abc46560d5c6d67938dbf640f2e8e08b7e554 SHA512 187173a525d4f3f01b4898633263b53a311f337aa7b159c64f79ba8c7006fd44798a058e7cc5d8f1116bad008e4142ff303456692329fe73b0e115ef5c225d73
DIST pillow-7.1.2.tar.gz 38933761 BLAKE2B b1d8cedeb0e8108af3bc5de672bcf812cb2f5ef8a9a23db45b3d5fc9d383d7d534ee63fbfce27f9ee4318982dec46e1e60eb55ce5aa14588b1468792c8188f5b SHA512 4e20f6dbc3c9d138de6270b14e85911ac5d2953328be4fd4b0754d8fe834625f914ee1f1b2f32cfb26ab57b6ea4b74d14a81a65938cbb94895c0afcd639bb38f
+DIST pillow-7.2.0.tar.gz 39125407 BLAKE2B f49015922c34473590740c9fa63435f85f9a517b3295abd2e758941b95162cef0fb1fa2a0e6ee0ac86323709ee3af02888f6e029a1905f13698e82c1f38d5d94 SHA512 ac9c7c8f445b3f67f51bea13fad118d1612c45272c26d33bec286f3c2e198912b934378c4bf986b409aaa2a83d92ff176ee4d25f28701d61746c9cb86d0f412b
diff --git a/dev-python/pillow/pillow-7.2.0.ebuild b/dev-python/pillow/pillow-7.2.0.ebuild
new file mode 100644
index 00000000000..71526b251ea
--- /dev/null
+++ b/dev-python/pillow/pillow-7.2.0.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..9} )
+PYTHON_REQ_USE='tk?,threads(+)'
+
+inherit distutils-r1 toolchain-funcs virtualx
+
+MY_PN=Pillow
+MY_P=${MY_PN}-${PV}
+
+DESCRIPTION="Python Imaging Library (fork)"
+HOMEPAGE="https://python-pillow.org/"
+SRC_URI="https://github.com/python-pillow/Pillow/archive/${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${MY_P}"
+
+LICENSE="HPND"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="examples imagequant jpeg jpeg2k lcms test tiff tk truetype webp xcb zlib"
+REQUIRED_USE="test? ( jpeg tiff )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+ dev-python/olefile[${PYTHON_USEDEP}]
+ imagequant? ( media-gfx/libimagequant:0 )
+ jpeg? ( virtual/jpeg:0 )
+ jpeg2k? ( media-libs/openjpeg:2= )
+ lcms? ( media-libs/lcms:2= )
+ tiff? ( media-libs/tiff:0=[jpeg,zlib] )
+ truetype? ( media-libs/freetype:2= )
+ webp? ( media-libs/libwebp:0= )
+ xcb? ( x11-libs/libxcb )
+ zlib? ( sys-libs/zlib:0= )"
+DEPEND="${RDEPEND}
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ test? (
+ dev-python/pytest[${PYTHON_USEDEP}]
+ media-gfx/imagemagick[png]
+ )
+"
+
+distutils_enable_sphinx docs \
+ dev-python/sphinx_rtd_theme
+
+python_configure_all() {
+ # It's important that these flags are also passed during the install phase
+ # as well. Make sure of that if you change the lines below. See bug 661308.
+ mydistutilsargs=(
+ build_ext
+ --disable-platform-guessing
+ $(use_enable truetype freetype)
+ $(use_enable jpeg)
+ $(use_enable jpeg2k jpeg2000)
+ $(use_enable lcms)
+ $(use_enable tiff)
+ $(use_enable imagequant)
+ $(use_enable webp)
+ $(use_enable webp webpmux)
+ $(use_enable xcb)
+ $(use_enable zlib)
+ )
+
+ # setup.py sucks at adding the right toolchain paths but it does
+ # accept additional ones from INCLUDE and LIB so set these. You
+ # wouldn't normally need these at all as the toolchain should look
+ # here anyway but this setup.py does stupid things.
+ export \
+ INCLUDE=${ESYSROOT}/usr/include \
+ LIB=${ESYSROOT}/usr/$(get_libdir)
+
+ # We have patched in this env var.
+ tc-export PKG_CONFIG
+}
+
+src_test() {
+ virtx distutils-r1_src_test
+}
+
+python_test() {
+ "${EPYTHON}" selftest.py --installed || die "selftest failed with ${EPYTHON}"
+ # no:relaxed: pytest-relaxed plugin make our tests fail. deactivate if installed
+ pytest -vv -p no:relaxed || die "Tests fail with ${EPYTHON}"
+}
+
+python_install() {
+ python_doheader src/libImaging/*.h
+ distutils-r1_python_install
+}
+
+python_install_all() {
+ if use examples ; then
+ docinto example
+ dodoc docs/example/*
+ docompress -x /usr/share/doc/${PF}/example
+ fi
+ distutils-r1_python_install_all
+}