[gentoo-commits] repo/gentoo:master commit in: app-admin/vault/

["Zac Medico" <zmedico@gentoo.org>]

commit:     d4d78ad8a53af7da57f8995560480724a77c327a
Author:     Zac Medico <zmedico <AT> gentoo <DOT> org>
AuthorDate: Thu Jun 11 03:55:16 2020 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Thu Jun 11 03:55:41 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d4d78ad8

app-admin/vault: Bump to version 1.4.2 (bug 727660)

Bug: https://bugs.gentoo.org/727660
Package-Manager: Portage-2.3.100, Repoman-2.3.22
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 app-admin/vault/Manifest           |  2 ++
 app-admin/vault/vault-1.4.2.ebuild | 72 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/app-admin/vault/Manifest b/app-admin/vault/Manifest
index a8764c1ee9b..3eadbce54f3 100644
--- a/app-admin/vault/Manifest
+++ b/app-admin/vault/Manifest
@@ -1,2 +1,4 @@
 DIST vault-1.4.0-webui.tar.xz 1211468 BLAKE2B 5a7b221f2339ca451f6bc2df7b1a4611a9f7786305ec0631d0e7130fb0287f764553d8a8a99ade5d28a2ae39fca1028b5a3c7299a5049acff0d1a3c1e9b8124f SHA512 3b17221e189f9e5fa73afbae3496e4d1105401a94ce5f99ff1c6975ca25b20485a05dc7f0b0c469d29d896524370d8fa23157d401d28e2e92a71a4813a4d9ba6
 DIST vault-1.4.0.tar.gz 33097110 BLAKE2B 837f23a50128b0fab6542fc6a596d911267a1e14453091f22171db2ccf6a1a3d0aacdb3f210ac0d07efc7ed5ce845a197f61dd4dab37c35ad6f0f47cefc09c9d SHA512 13c1fb901fe577d91f2734f8a0ae5e51083e1307e7fc32a4388a1be48f2c46cd3d121432fa7450d6f9b439285d3ad5819b123631f41bb347e8d75ce683d24a7e
+DIST vault-1.4.2-webui.tar.xz 1208924 BLAKE2B 5177afc91e7bc774b7d78e5e344d7c8310a13a592c57768ac6a0c8e12ef6e7ac8b6dbc975e5e9131888478a7fb18ad9ef1ee9b1da43c2899fcf636e99d049078 SHA512 ab462bebfa38102e354938e9b8c6990b6bb19b29dd0da96d65f290394a987d89063800247c1d751a8f7ba7c3fa6645aab9383a5455444244adb5f40528408b17
+DIST vault-1.4.2.tar.gz 33158384 BLAKE2B 263f20419c210b83448907b1e95464fb139f52f4f7347eb01803b5aa487797c191f1e61a9fb77321f776ea70feb83a741f10c79400fdd471b790fe37a6404a9c SHA512 d4f2a426a4c0531cca0d3812c2e29ebc5ebbd6da2897d3ee57fe57d4dfde0395f30713cfe21600b4dd51fdc90bf2a10527957b04c8215bd185bd502267f93503

diff --git a/app-admin/vault/vault-1.4.2.ebuild b/app-admin/vault/vault-1.4.2.ebuild
new file mode 100644
index 00000000000..4a81ecf016a
--- /dev/null
+++ b/app-admin/vault/vault-1.4.2.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps go-module systemd
+
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/"
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+SRC_URI="https://github.com/hashicorp/vault/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	webui? (
+		https://dev.gentoo.org/~zmedico/dist/${VAULT_WEBUI_ARCHIVE}
+	)"
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+webui"
+
+BDEPEND="dev-go/gox"
+COMMON_DEPEND="acct-group/vault
+	acct-user/vault"
+	DEPEND="${COMMON_DEPEND}"
+	RDEPEND="${COMMON_DEPEND}"
+
+FILECAPS=(
+	-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+RESTRICT+=" test"
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+		-i scripts/build.sh || die
+	sed -e "/hooks/d" \
+		-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
+		-i Makefile || die
+	if [[ -f "${WORKDIR}/http/bindata_assetfs.go" ]]; then
+		mv "${WORKDIR}/http/bindata_assetfs.go" "${S}/http" ||
+			die "mv failed"
+	fi
+}
+
+src_compile() {
+	mkdir "${T}"/bin || die
+	BUILD_TAGS="$(usex webui ui '')" \
+	GOFLAGS="-mod=vendor" \
+	GOPATH="${T}" \
+	XC_ARCH=$(go env GOARCH) \
+	XC_OS=$(go env GOOS) \
+	XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+	emake
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md
+	insinto /etc/${PN}.d
+	doins "${FILESDIR}/"*.json.example
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}