[gentoo-commits] repo/gentoo:master commit in: media-sound/gnome-music/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     1561d6f0f4f58aa5336bd328f440f5cf624cddab
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Tue Jun  2 21:52:09 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Tue Jun  2 21:52:22 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1561d6f0

media-sound/gnome-music: bump to 3.34.6

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 media-sound/gnome-music/Manifest                  |  1 +
 media-sound/gnome-music/gnome-music-3.34.6.ebuild | 81 +++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/media-sound/gnome-music/Manifest b/media-sound/gnome-music/Manifest
index 349017d8738..0fe574ee6eb 100644
--- a/media-sound/gnome-music/Manifest
+++ b/media-sound/gnome-music/Manifest
@@ -1 +1,2 @@
 DIST gnome-music-3.34.5.tar.xz 1415240 BLAKE2B 3545541171b023da116ebee5d28a2b69b6b45677cde26c833ea0992ba9bc41d4792375dbf3617105da53f0e98d21576e166980e896527a60d47c92690b343a27 SHA512 c4f3c8cd7e8a6d24d3766672acfe3abc340d0cd305ba0d3d0a87c02b5a5f9e8c47bee9d8284e76ad28c51eeebe56e3163f4e5c34c89e294801d0047b8476f80f
+DIST gnome-music-3.34.6.tar.xz 1415360 BLAKE2B 0b8f3a2b17242f41f3a77a9eeb60cf1f10cac57d983de6e7f44ba1a243526e0831ee2ad5baec17b726bbbe9df52e26b79dedc2b2abe4dba87c59cc4fcd4a083f SHA512 76561adf8c6ce4342825eb976de11c98c2aa66cb08075dbe46d8c7787daf7fc77763d55c2fe475dd9c75536adc98f8afbdd90bfb2b64791d05cdf11e3ed00b03

diff --git a/media-sound/gnome-music/gnome-music-3.34.6.ebuild b/media-sound/gnome-music/gnome-music-3.34.6.ebuild
new file mode 100644
index 00000000000..fde8cf28852
--- /dev/null
+++ b/media-sound/gnome-music/gnome-music-3.34.6.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit gnome.org gnome2-utils meson python-single-r1 xdg
+
+DESCRIPTION="Music management for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Music"
+
+LICENSE="GPL-2+"
+SLOT="0"
+IUSE=""
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+KEYWORDS="~amd64 ~arm64 ~x86"
+
+DEPEND="${PYTHON_DEPS}
+	>=dev-libs/glib-2.50:2
+	net-libs/gnome-online-accounts[introspection]
+	>=dev-libs/gobject-introspection-1.54:=
+	>=x11-libs/gtk+-3.24.7:3[introspection]
+	>=dev-libs/libdazzle-3.28.0[introspection]
+	>=media-libs/libmediaart-1.9.1:2.0[introspection]
+	net-libs/libsoup:2.4[introspection]
+	>=app-misc/tracker-2.2.0:=[introspection(+)]
+	$(python_gen_cond_dep '
+		>=dev-python/pygobject-3.29.1:3[cairo,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pycairo-1.14.0[${PYTHON_MULTI_USEDEP}]
+	')
+	>=media-libs/grilo-0.3.9:0.3[introspection]
+	>=media-plugins/grilo-plugins-0.3.9:0.3
+"
+# xdg-user-dirs-update needs to be there to create needed dirs
+# https://bugzilla.gnome.org/show_bug.cgi?id=731613
+RDEPEND="${DEPEND}
+	|| (
+		>=app-misc/tracker-miners-2.2.0[gstreamer]
+		>=app-misc/tracker-miners-2.2.0[ffmpeg]
+	)
+	x11-libs/libnotify[introspection]
+	media-libs/gstreamer:1.0[introspection]
+	media-libs/gst-plugins-base:1.0[introspection]
+	media-plugins/gst-plugins-meta:1.0
+	media-plugins/grilo-plugins:0.3[tracker]
+	x11-misc/xdg-user-dirs
+"
+BDEPEND="
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+RESTRICT="test" # only does desktop and appdata validation, and latter needs network to validate screenshot from https
+
+pkg_setup() {
+	python_setup
+}
+
+src_prepare() {
+	sed -e '/sys.path.insert/d' -i "${S}"/gnome-music.in || die "python fixup sed failed"
+	xdg_src_prepare
+}
+
+src_install() {
+	meson_src_install
+	python_fix_shebang "${D}"/usr/bin/gnome-music
+	python_optimize
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}