[gentoo-commits] repo/gentoo:master commit in: app-text/cherrytree/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     1fe26fad623252aae3888e2ff908c7922ff5cd01
Author:     Yury Martynov <email <AT> linxon <DOT> ru>
AuthorDate: Fri Apr 10 09:51:17 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat May 23 17:59:10 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1fe26fad

app-text/cherrytree: bump to 0.99.0_p20200523 and drop 0.39.2 (C++ version)

Closes: https://bugs.gentoo.org/716874
Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Yury Martynov <email <AT> linxon.ru>
Closes: https://github.com/gentoo/gentoo/pull/15285
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 app-text/cherrytree/Manifest                       |  2 +-
 app-text/cherrytree/cherrytree-0.39.2.ebuild       | 96 ---------------------
 .../cherrytree/cherrytree-0.99.0_p20200523.ebuild  | 97 ++++++++++++++++++++++
 app-text/cherrytree/cherrytree-9999.ebuild         | 97 ++++++++++++++++++++++
 4 files changed, 195 insertions(+), 97 deletions(-)

diff --git a/app-text/cherrytree/Manifest b/app-text/cherrytree/Manifest
index 9b9b8ef3fbf..762a81d7baf 100644
--- a/app-text/cherrytree/Manifest
+++ b/app-text/cherrytree/Manifest
@@ -1,3 +1,3 @@
 DIST cherrytree-0.37.0.tar.gz 8888703 BLAKE2B 737c0c247c581086e23e4c3e5fba0b18459788b385078ec8092af8b7352d77c8b273c939f702178d0ae59c8633bf996a7a7e5223e22da703ced3c8bf1d7cbde3 SHA512 a1aaf92657c58c70430a45adaa771050b43476bc2a33dc929b108842d5ef46aa83c4fa4cfe8c4f54a9a3656fc0d30046fae34cbac5aa9fe3f32aa539058636f5
 DIST cherrytree-0.38.9.tar.gz 9928805 BLAKE2B 4de4187ae7e650090d82de5e8b1b7f85c4af6dbb2c9b2bc67f10b074db4c08c4b4593c4769708bfaf584958eefe083a3626f7e9c4d7736bc53d143528c754e09 SHA512 40c1c26fa1a6868b447d31625c14b10cf712185289cf97b71881c253d2f72c58f51b974a1615fca5b532099c4741c56f8419df2d02e4ca821b2a1b909152e56b
-DIST cherrytree-0.39.2.tar.gz 10044337 BLAKE2B 352b6b709e62487015eccf817c4aec799586f64b9e07e38f1eab5e1491b36d8e2ae2f62f55f32248ca1f5cc0c0f610282493de2f3d4cf4e128ecb66acb895668 SHA512 46a02753f02f17e9696e21510ad93222843734a8be271e3a20d7a038856ad99ff2c8316d559e56567e877e419324fe3b254882bb1578a3c8d85c902169cb0e26
+DIST cherrytree-0.99.0_p20200523.tar.gz 10452221 BLAKE2B cbac9b5b1c4fc1454d229a56784a59f1622b134d640db720e496cc0f1b4f95ee097343572f33d8b0626903f58ae188e8b85065144fcad8c647732e7eddadd0b9 SHA512 4eb142368bd1d3838879669d5bf1742689b02f08f50edd51a6fa6f22fef83d0f1871147aca3c346e9fcd1193c3f494e112cdc9e10eda4b3124587f605f89cc54

diff --git a/app-text/cherrytree/cherrytree-0.39.2.ebuild b/app-text/cherrytree/cherrytree-0.39.2.ebuild
deleted file mode 100644
index 0c4f473d9b8..00000000000
--- a/app-text/cherrytree/cherrytree-0.39.2.ebuild
+++ /dev/null
@@ -1,96 +0,0 @@
-# Copyright 1999-2020 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{6,7,8} )
-
-inherit autotools desktop python-any-r1 xdg-utils
-
-DESCRIPTION="A hierarchical note taking application"
-HOMEPAGE="https://www.giuspen.com/cherrytree"
-SRC_URI="https://github.com/giuspen/cherrytree/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-3"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="nls test"
-
-RESTRICT="!test? ( test )"
-
-RDEPEND="
-	dev-cpp/gtkmm:3.0
-	dev-cpp/gtksourceviewmm:3.0
-	dev-cpp/libxmlpp:2.6
-	dev-cpp/pangomm
-	dev-db/sqlite:3
-	dev-libs/libxml2:2"
-DEPEND="${RDEPEND}"
-BDEPEND="${PYTHON_DEPS}
-	dev-util/intltool
-	virtual/pkgconfig
-	nls? ( sys-devel/gettext )
-	test? ( dev-util/cpputest )"
-
-S="${S}/future"
-
-pkg_setup() {
-	python-any-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	python_fix_shebang "${S}"
-
-	sed -i \
-		-e "s|\(CT_VERSION.*{\)\(.*\)\(};\)$|\1\"${PV}\"\3|" \
-		src/ct/ct_const.cc || die
-
-	if ! use test; then
-		sed -i \
-			-e '/^PKG_CHECK_MODULES/s|\(\[.*\)cpputest\(.*\]\)|\1\2|' \
-			configure.ac || die
-	fi
-
-	eautoreconf
-}
-
-src_configure() {
-	econf $(use_enable nls)
-}
-
-src_install() {
-	default
-	pushd ../ >/dev/null || die
-
-	insinto /usr/share/mime/packages
-	doins linux/cherrytree.xml
-
-	insinto /usr/share/mime-info
-	doins linux/cherrytree.{mime,keys}
-
-	insinto /usr/share/metainfo
-	doins linux/cherrytree.appdata.xml
-
-	insinto /usr/share/application-registry
-	doins linux/cherrytree.applications
-
-	doicon -s scalable future/icons/cherrytree.svg
-	domenu linux/cherrytree.desktop
-	doman linux/cherrytree.1
-
-	popd >/dev/null || die
-}
-
-pkg_postinst() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-}
-
-pkg_postrm() {
-	xdg_icon_cache_update
-	xdg_mimeinfo_database_update
-	xdg_desktop_database_update
-}

diff --git a/app-text/cherrytree/cherrytree-0.99.0_p20200523.ebuild b/app-text/cherrytree/cherrytree-0.99.0_p20200523.ebuild
new file mode 100644
index 00000000000..9599c94f496
--- /dev/null
+++ b/app-text/cherrytree/cherrytree-0.99.0_p20200523.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+
+inherit cmake python-any-r1 xdg-utils
+
+DESCRIPTION="A hierarchical note taking application (C++ version)"
+HOMEPAGE="https://www.giuspen.com/cherrytree https://github.com/giuspen/cherrytree"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/giuspen/cherrytree"
+	S="${WORKDIR}/${P}/future"
+else
+	COMMIT="074a09ce3c1130ec60f5f5a3b8be958337b6d5ab" # 20200523
+	SRC_URI="https://github.com/giuspen/cherrytree/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${COMMIT}/future"
+fi
+
+# GPL-3 — future/src/ct (CherryTree)
+# LGPL-2.1 — future/src/7za (7zip)
+# MIT — future/src/fmt (libfmt)
+LICENSE="GPL-3 LGPL-2.1 MIT"
+SLOT="0"
+IUSE="nls test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/gspell:=
+	dev-libs/glib:2
+	>=dev-cpp/glibmm-2.64.2:2
+	dev-cpp/gtkmm:3.0
+	dev-cpp/gtksourceviewmm:3.0
+	dev-libs/libxml2:2
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/pangomm
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+	test? ( dev-util/cpputest )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	# disable compress man pages
+	sed -i -e \
+		'/install(FILES/s|${MANFILE_FULL_GZ}|${CMAKE_SOURCE_DIR}/data/cherrytree.1|' \
+		CMakeLists.txt || die
+
+	if [[ ${PV} != *9999 ]]; then
+		sed -i \
+			-e "/^set(CT_VERSION/s|\"\(.*\)\"|\"${PV}\"|" \
+			CMakeLists.txt || die
+	fi
+
+	python_fix_shebang .
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXEC="${PYTHON}"
+		-DUSE_NLS=$(usex nls)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}

diff --git a/app-text/cherrytree/cherrytree-9999.ebuild b/app-text/cherrytree/cherrytree-9999.ebuild
new file mode 100644
index 00000000000..9599c94f496
--- /dev/null
+++ b/app-text/cherrytree/cherrytree-9999.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6..8} )
+
+inherit cmake python-any-r1 xdg-utils
+
+DESCRIPTION="A hierarchical note taking application (C++ version)"
+HOMEPAGE="https://www.giuspen.com/cherrytree https://github.com/giuspen/cherrytree"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/giuspen/cherrytree"
+	S="${WORKDIR}/${P}/future"
+else
+	COMMIT="074a09ce3c1130ec60f5f5a3b8be958337b6d5ab" # 20200523
+	SRC_URI="https://github.com/giuspen/cherrytree/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${COMMIT}/future"
+fi
+
+# GPL-3 — future/src/ct (CherryTree)
+# LGPL-2.1 — future/src/7za (7zip)
+# MIT — future/src/fmt (libfmt)
+LICENSE="GPL-3 LGPL-2.1 MIT"
+SLOT="0"
+IUSE="nls test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	app-text/gspell:=
+	dev-libs/glib:2
+	>=dev-cpp/glibmm-2.64.2:2
+	dev-cpp/gtkmm:3.0
+	dev-cpp/gtksourceviewmm:3.0
+	dev-libs/libxml2:2
+	dev-cpp/libxmlpp:2.6
+	dev-cpp/pangomm
+	dev-db/sqlite:3"
+DEPEND="${RDEPEND}
+	$(python_gen_any_dep 'dev-python/lxml[${PYTHON_USEDEP}]')"
+BDEPEND="${PYTHON_DEPS}
+	virtual/pkgconfig
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+	test? ( dev-util/cpputest )"
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+python_check_deps() {
+	has_version "dev-python/lxml[${PYTHON_USEDEP}]"
+}
+
+src_prepare() {
+	# disable compress man pages
+	sed -i -e \
+		'/install(FILES/s|${MANFILE_FULL_GZ}|${CMAKE_SOURCE_DIR}/data/cherrytree.1|' \
+		CMakeLists.txt || die
+
+	if [[ ${PV} != *9999 ]]; then
+		sed -i \
+			-e "/^set(CT_VERSION/s|\"\(.*\)\"|\"${PV}\"|" \
+			CMakeLists.txt || die
+	fi
+
+	python_fix_shebang .
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DPYTHON_EXEC="${PYTHON}"
+		-DUSE_NLS=$(usex nls)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+	xdg_desktop_database_update
+}