[gentoo-commits] repo/gentoo:master commit in: net-misc/freerdp/

["Mike Gilbert" <floppym@gentoo.org>]

commit:     6e16902b1bc82dbf1ab92da463b16007e03881f5
Author:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
AuthorDate: Sat May  9 04:14:13 2020 +0000
Commit:     Mike Gilbert <floppym <AT> gentoo <DOT> org>
CommitDate: Sat May  9 04:15:50 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6e16902b

net-misc/freerdp: bump to 2.1.0

Signed-off-by: Mike Gilbert <floppym <AT> gentoo.org>

 net-misc/freerdp/Manifest             |   1 +
 net-misc/freerdp/freerdp-2.1.0.ebuild | 122 ++++++++++++++++++++++++++++++++++
 2 files changed, 123 insertions(+)

diff --git a/net-misc/freerdp/Manifest b/net-misc/freerdp/Manifest
index 09477f890a1..3fd51796e61 100644
--- a/net-misc/freerdp/Manifest
+++ b/net-misc/freerdp/Manifest
@@ -2,3 +2,4 @@ DIST freerdp-2.0.0-rc4-fix-NTLM-AvPair-lists.patch 20553 BLAKE2B 17ba83ba2dc05f2
 DIST freerdp-2.0.0-rc4.tar.gz 6662044 BLAKE2B 50bc72336841e421b8fd89ce4f2be6a0b1a9f052933c4cd5bad33261689e6a6b54bc5563fb1ace8cc7a2271990c0ff4c7fe239243f5d75140af497ee6ff9bcd6 SHA512 63cf89aecc6d7ac55db8c7aca60f4ba29cfa54ad70d0fa87fdab011cd16500a3d184659119cd08b7596b7236346db3b61b46282c5325d7f0ca6da09b42d0df20
 DIST freerdp-2.0.0.tar.gz 6857730 BLAKE2B 2873a228b82874d3efae3ea922c83c7d32692ae17da2b7b85a9dd570d8d3f4df7f4943920474cb6711c32c6e8863429a165a6f4b65c834fda1320bcb804b38db SHA512 4babb7b3a5e7b39b89c4e1dbcd5a58b5fbfb8d48083dbafc2c6455d8b739f4c444715286cc10f2f7446f96053d3f5ff4ac2cff1af9708cbc48ef07a6fee5bee6
 DIST freerdp-2.0.0_rc4_p1129.tar.gz 6774330 BLAKE2B 728a4d0f0d7ee4a6cf8a7d0d4ed6f2e0f13a76ceb1c16e7cb48ad0f3d6b6f36194839129bd57e73e02d2a6ae89a83d9d571f515ab2f46cb26f611424dd5b23b5 SHA512 407b06ca7607e01d52b7b89337dbcd5dc15633de197ea91443825672963cbb6d966a187dee022afb5f9979e8d08577ee62b681f37419e5b986f9c2f5e8a3e285
+DIST freerdp-2.1.0.tar.gz 21772624 BLAKE2B d3491cb9f08a34fd5b2a5b00b46494e4e0524715d73ad46e92812578fbe9843504d937dc634f1597a7f0785494fd2c68f964125b438328105e4db41191eeb166 SHA512 c0abecf3d52bf8388538f0bb60a0852b6f92c9172feda06efa96eb49a354913c7a10b9852efb0de6e545658043d0d3568cb79a54fc1d324a14e8ed2c9c9e6e3b

diff --git a/net-misc/freerdp/freerdp-2.1.0.ebuild b/net-misc/freerdp/freerdp-2.1.0.ebuild
new file mode 100644
index 00000000000..b541ab6af7c
--- /dev/null
+++ b/net-misc/freerdp/freerdp-2.1.0.ebuild
@@ -0,0 +1,122 @@
+# Copyright 2011-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/FreeRDP/FreeRDP.git"
+	case ${PV} in
+		2.*) EGIT_BRANCH="stable-2.0";;
+	esac
+else
+	MY_P=${P/_/-}
+	S="${WORKDIR}/${MY_P}"
+	SRC_URI="https://pub.freerdp.com/releases/${MY_P}.tar.gz"
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+fi
+
+DESCRIPTION="Free implementation of the Remote Desktop Protocol"
+HOMEPAGE="http://www.freerdp.com/"
+
+LICENSE="Apache-2.0"
+SLOT="0/2"
+IUSE="alsa +client cpu_flags_arm_neon cups debug doc +ffmpeg gstreamer jpeg libressl openh264 pulseaudio server smartcard systemd test usb wayland X xinerama xv"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	!libressl? ( dev-libs/openssl:0= )
+	libressl? ( dev-libs/libressl:0= )
+	sys-libs/zlib:0
+	alsa? ( media-libs/alsa-lib )
+	cups? ( net-print/cups )
+	client? (
+		usb? (
+			virtual/libudev:0=
+			sys-apps/util-linux:0=
+			dev-libs/dbus-glib:0=
+			virtual/libusb:1=
+		)
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXext
+			x11-libs/libXi
+			x11-libs/libXrender
+			xinerama? ( x11-libs/libXinerama )
+			xv? ( x11-libs/libXv )
+		)
+	)
+	ffmpeg? ( media-video/ffmpeg:0= )
+	!ffmpeg? (
+		x11-libs/cairo:0=
+	)
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+		x11-libs/libXrandr
+	)
+	jpeg? ( virtual/jpeg:0 )
+	openh264? ( media-libs/openh264 )
+	pulseaudio? ( media-sound/pulseaudio )
+	server? (
+		X? (
+			x11-libs/libXcursor
+			x11-libs/libXdamage
+			x11-libs/libXext
+			x11-libs/libXfixes
+			x11-libs/libXrandr
+			x11-libs/libXtst
+			xinerama? ( x11-libs/libXinerama )
+		)
+	)
+	smartcard? ( sys-apps/pcsc-lite )
+	systemd? ( sys-apps/systemd:0= )
+	wayland? (
+		dev-libs/wayland
+		x11-libs/libxkbcommon
+	)
+	X? (
+		x11-libs/libX11
+		x11-libs/libxkbfile
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	client? ( X? ( doc? (
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/xmlto
+	) ) )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING=$(usex test ON OFF)
+		-DCHANNEL_URBDRC=$(usex usb ON OFF)
+		-DWITH_ALSA=$(usex alsa ON OFF)
+		-DWITH_CCACHE=OFF
+		-DWITH_CLIENT=$(usex client ON OFF)
+		-DWITH_CUPS=$(usex cups ON OFF)
+		-DWITH_DEBUG_ALL=$(usex debug ON OFF)
+		-DWITH_MANPAGES=$(usex doc ON OFF)
+		-DWITH_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_SWSCALE=$(usex ffmpeg ON OFF)
+		-DWITH_CAIRO=$(usex ffmpeg OFF ON)
+		-DWITH_DSP_FFMPEG=$(usex ffmpeg ON OFF)
+		-DWITH_GSTREAMER_1_0=$(usex gstreamer ON OFF)
+		-DWITH_JPEG=$(usex jpeg ON OFF)
+		-DWITH_NEON=$(usex cpu_flags_arm_neon ON OFF)
+		-DWITH_OPENH264=$(usex openh264 ON OFF)
+		-DWITH_PULSE=$(usex pulseaudio ON OFF)
+		-DWITH_SERVER=$(usex server ON OFF)
+		-DWITH_PCSC=$(usex smartcard ON OFF)
+		-DWITH_LIBSYSTEMD=$(usex systemd ON OFF)
+		-DWITH_X11=$(usex X ON OFF)
+		-DWITH_XINERAMA=$(usex xinerama ON OFF)
+		-DWITH_XV=$(usex xv ON OFF)
+		-DWITH_WAYLAND=$(usex wayland ON OFF)
+	)
+	cmake_src_configure
+}