[gentoo-commits] repo/gentoo:master commit in: app-admin/vault/

["William Hubbs" <williamh@gentoo.org>]

commit:     1a79a29158f9eb792183183e828fe14f2c0ef1e8
Author:     William Hubbs <williamh <AT> gentoo <DOT> org>
AuthorDate: Mon Apr 20 16:56:41 2020 +0000
Commit:     William Hubbs <williamh <AT> gentoo <DOT> org>
CommitDate: Mon Apr 20 17:31:24 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1a79a291

app-admin/vault: 1.4.0 bump

Signed-off-by: William Hubbs <williamh <AT> gentoo.org>

 app-admin/vault/Manifest           |  2 ++
 app-admin/vault/vault-1.4.0.ebuild | 72 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 74 insertions(+)

diff --git a/app-admin/vault/Manifest b/app-admin/vault/Manifest
index 0e922eec48a..91cb6562d84 100644
--- a/app-admin/vault/Manifest
+++ b/app-admin/vault/Manifest
@@ -4,3 +4,5 @@ DIST vault-1.2.4-webui.tar.xz 1919024 BLAKE2B c1fc1460d70f33695ce9f7571a701035b0
 DIST vault-1.2.4.tar.gz 27778766 BLAKE2B 536dd114c0268f91eb6b5c13cc30d22cdb9d1085c1378c6e39a6fcffeb4d5313363d225c85073a4da124962d6f7de8e4800a6648e392909a9595341ac178d94a SHA512 35a91088ac6949863e2de651edac19d73586acc2f42d14e48d3b41236d9458c95e60f8ec2285b3846ff04ebe59a4d4b308686151d758b5af8caad711441e2ee4
 DIST vault-1.3.0-webui.tar.xz 2004176 BLAKE2B f17b51346e694e13cb51779f158116cd1e241ba1a90c5e384b40fafc916386fd12ae7e09e11b083f1ff8cb8aa89a94f811029edc10fceec2a08cbe8e65b1bac4 SHA512 2f3695134ffd9af478568b08fc66b593d00c0990178af2f3d0e8b27c53afeed1f7926d97afa688b21cca931665b435e85c036a9970f71355977815f214c66c0c
 DIST vault-1.3.0.tar.gz 31098388 BLAKE2B 81ac68f47eed4a9e0187774558d38701f4e1481b07bd8a6f310741741a112dcf8e8344e156b6cef2a05e115da998fafab9627d62e261ffb8995ebdd2468f770a SHA512 4011706c2d418e4e13369f5afa5541af8296d6731c12aa670ed0fce66cc4d950edb76a0d24722be6b63538dc3479dcf68bb89ce7d9f37437062635feb6432165
+DIST vault-1.4.0-webui.tar.xz 1211468 BLAKE2B 5a7b221f2339ca451f6bc2df7b1a4611a9f7786305ec0631d0e7130fb0287f764553d8a8a99ade5d28a2ae39fca1028b5a3c7299a5049acff0d1a3c1e9b8124f SHA512 3b17221e189f9e5fa73afbae3496e4d1105401a94ce5f99ff1c6975ca25b20485a05dc7f0b0c469d29d896524370d8fa23157d401d28e2e92a71a4813a4d9ba6
+DIST vault-1.4.0.tar.gz 33097110 BLAKE2B 837f23a50128b0fab6542fc6a596d911267a1e14453091f22171db2ccf6a1a3d0aacdb3f210ac0d07efc7ed5ce845a197f61dd4dab37c35ad6f0f47cefc09c9d SHA512 13c1fb901fe577d91f2734f8a0ae5e51083e1307e7fc32a4388a1be48f2c46cd3d121432fa7450d6f9b439285d3ad5819b123631f41bb347e8d75ce683d24a7e

diff --git a/app-admin/vault/vault-1.4.0.ebuild b/app-admin/vault/vault-1.4.0.ebuild
new file mode 100644
index 00000000000..08f205087d1
--- /dev/null
+++ b/app-admin/vault/vault-1.4.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit fcaps go-module systemd
+
+DESCRIPTION="A tool for managing secrets"
+HOMEPAGE="https://vaultproject.io/"
+VAULT_WEBUI_ARCHIVE="${P}-webui.tar.xz"
+SRC_URI="https://github.com/hashicorp/vault/archive/v${PV}.tar.gz -> ${P}.tar.gz
+	webui? (
+		https://dev.gentoo.org/~williamh/dist/${VAULT_WEBUI_ARCHIVE}
+	)"
+
+LICENSE="MPL-2.0 Apache-2.0 BSD BSD-2 CC-BY-SA-4.0 ISC MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="+webui"
+
+BDEPEND="dev-go/gox"
+COMMON_DEPEND="acct-group/vault
+	acct-user/vault"
+	DEPEND="${COMMON_DEPEND}"
+	RDEPEND="${COMMON_DEPEND}"
+
+FILECAPS=(
+	-m 755 'cap_ipc_lock=+ep' usr/bin/${PN}
+)
+
+RESTRICT+=" test"
+
+src_prepare() {
+	default
+	# Avoid the need to have a git checkout
+	sed -e 's:^\(GIT_COMMIT=\).*:\1:' \
+		-e 's:^\(GIT_DIRTY=\).*:\1:' \
+		-e s:\'\${GIT_COMMIT}\${GIT_DIRTY}\':: \
+		-i scripts/build.sh || die
+	sed -e "/hooks/d" \
+		-e 's|^\([[:space:]]*\)goimports .*)|\1true|' \
+		-i Makefile || die
+	if [[ -f "${WORKDIR}/http/bindata_assetfs.go" ]]; then
+		mv "${WORKDIR}/http/bindata_assetfs.go" "${S}/http" ||
+			die "mv failed"
+	fi
+}
+
+src_compile() {
+	mkdir "${T}"/bin || die
+	BUILD_TAGS="$(usex webui ui '')" \
+	GOFLAGS="-mod=vendor" \
+	GOPATH="${T}" \
+	XC_ARCH=$(go env GOARCH) \
+	XC_OS=$(go env GOOS) \
+	XC_OSARCH=$(go env GOOS)/$(go env GOARCH) \
+	emake
+}
+
+src_install() {
+	dobin bin/${PN}
+	dodoc CHANGELOG.md CONTRIBUTING.md README.md
+	insinto /etc/${PN}.d
+	doins "${FILESDIR}/"*.json.example
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	newinitd "${FILESDIR}/${PN}.initd" "${PN}"
+	newconfd "${FILESDIR}/${PN}.confd" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}.service"
+	keepdir /var/log/${PN}
+	fowners ${PN}:${PN} /var/log/${PN}
+}