[gentoo-commits] repo/gentoo:master commit in: app-emacs/pymacs/

["Ulrich Müller" <ulm@gentoo.org>]

commit:     f290e6b53c2707d45bd6079c373ea99d7a896896
Author:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 19 13:37:44 2020 +0000
Commit:     Ulrich Müller <ulm <AT> gentoo <DOT> org>
CommitDate: Sun Apr 19 13:38:44 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f290e6b5

app-emacs/pymacs: Add python 3.7 and 3.8 support.

Don't remove the version in pymacs-python-command.
Build PDF documentation with USE=doc (which was commented out).

Closes: https://bugs.gentoo.org/718206
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Ulrich Müller <ulm <AT> gentoo.org>

 app-emacs/pymacs/pymacs-0.26-r1.ebuild | 47 ++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/app-emacs/pymacs/pymacs-0.26-r1.ebuild b/app-emacs/pymacs/pymacs-0.26-r1.ebuild
new file mode 100644
index 00000000000..0ff10a4675c
--- /dev/null
+++ b/app-emacs/pymacs/pymacs-0.26-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{6,7,8} )
+
+inherit elisp distutils-r1
+
+DESCRIPTION="A tool that allows both-side communication beetween Python and Emacs Lisp"
+HOMEPAGE="https://www.emacswiki.org/emacs/PyMacs"
+SRC_URI="https://github.com/dgentry/${PN^}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~s390 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos"
+IUSE="doc"
+
+BDEPEND="doc? (
+		>=dev-python/docutils-0.7
+		virtual/latex-base
+	)"
+
+S="${WORKDIR}/${P^}"
+DISTUTILS_IN_SOURCE_BUILD=1
+DISTUTILS_USE_SETUPTOOLS="no"
+SITEFILE="50${PN}-gentoo.el"
+
+# called by distutils-r1 for every python implementation
+python_configure() {
+	# pre-process the files but don't run distutils
+	emake PYSETUP=: PYTHON=${EPYTHON}
+}
+
+# called once
+python_compile_all() {
+	elisp_src_compile
+	if use doc; then
+		VARTEXFONTS="${T}"/fonts emake RST2LATEX=rst2latex.py pymacs.pdf
+	fi
+}
+
+python_install_all() {
+	elisp_src_install
+	distutils-r1_python_install_all
+	dodoc pymacs.rst
+	use doc && dodoc pymacs.pdf
+}