[gentoo-commits] repo/gentoo:master commit in: app-accessibility/orca/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     ec54df0fe7433be15f704980130809e215058374
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Apr 19 08:14:52 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Apr 19 08:15:16 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec54df0f

app-accessibility/orca: support py3.7

Revbump because -r0 is under ongoing stabilization and stable
dev-libs/liblouis doesn't have py3.7 support, so it would block
the 3.34 stabilization efforts, and liblouis py3.7 support can't
go stable yet.

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-accessibility/orca/orca-3.34.2-r1.ebuild | 64 ++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)

diff --git a/app-accessibility/orca/orca-3.34.2-r1.ebuild b/app-accessibility/orca/orca-3.34.2-r1.ebuild
new file mode 100644
index 00000000000..b1742e8a23c
--- /dev/null
+++ b/app-accessibility/orca/orca-3.34.2-r1.ebuild
@@ -0,0 +1,64 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+PYTHON_COMPAT=( python3_{6,7} )
+PYTHON_REQ_USE="threads(+)"
+
+inherit gnome2 python-single-r1
+
+DESCRIPTION="Extensible screen reader that provides access to the desktop"
+HOMEPAGE="https://wiki.gnome.org/Projects/Orca"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="+braille"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+COMMON_DEPEND="${PYTHON_DEPS}
+	>=app-accessibility/at-spi2-atk-2.32:2
+	>=app-accessibility/at-spi2-core-2.32:2[introspection]
+	>=dev-libs/atk-2.32
+	>=dev-libs/glib-2.28:2
+	media-libs/gstreamer:1.0[introspection]
+	>=x11-libs/gtk+-3.6.2:3[introspection]
+	$(python_gen_cond_dep '
+		dev-python/gst-python:1.0[${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pygobject-3.18:3[${PYTHON_MULTI_USEDEP}]
+	')
+	braille? (
+		$(python_gen_cond_dep '
+			>=app-accessibility/brltty-5.0-r3[python,${PYTHON_MULTI_USEDEP}]
+			dev-libs/liblouis[python,${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+RDEPEND="${COMMON_DEPEND}
+	dev-libs/atk[introspection]
+	$(python_gen_cond_dep '
+		>=app-accessibility/speech-dispatcher-0.8[python,${PYTHON_MULTI_USEDEP}]
+		>=dev-python/pyatspi-2.32[${PYTHON_MULTI_USEDEP}]
+		dev-python/setproctitle[${PYTHON_MULTI_USEDEP}]
+	')
+	x11-libs/libwnck:3[introspection]
+	x11-libs/pango[introspection]
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+#	app-text/yelp-tools
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_with braille liblouis)
+}
+
+src_install() {
+	gnome2_src_install
+	python_optimize
+}