[gentoo-commits] repo/gentoo:master commit in: dev-util/dogtail/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     d39a52a5e44680de88055bf0a9b1d535ddba48f6
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Apr 18 16:44:48 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Apr 18 17:09:09 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d39a52a5

dev-util/dogtail: bump to 0.9.11, enable py3.7

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-util/dogtail/Manifest              |  1 +
 dev-util/dogtail/dogtail-0.9.11.ebuild | 48 ++++++++++++++++++++++++++++++++++
 2 files changed, 49 insertions(+)

diff --git a/dev-util/dogtail/Manifest b/dev-util/dogtail/Manifest
index f2edb547d45..4ab8d205daf 100644
--- a/dev-util/dogtail/Manifest
+++ b/dev-util/dogtail/Manifest
@@ -1 +1,2 @@
 DIST dogtail-0.9.10.tar.gz 125995 BLAKE2B e28e9a6330cefc8746b850501a5beba07e18f1e5d5f935ce182103a9ea4ffc95483b3530a705565cbfae1bff24da57839f7e7b6939f42821e31b287150e33b4d SHA512 08ce4ad6e5e492ab04be9964cc6583d96d2d8a707a49721c1bca9248e5c56702fe5d0d84dd992023f731fe87016c88e21929319baff561aa113c6e101343fc3e
+DIST dogtail-0.9.11.tar.gz 132832 BLAKE2B 9004216a3d96714e9bd524e6ffaad7892a3630c97b61293d9784bc04df353f3c09e6226f92329103768a38c55b7eecc5f23a1aec0e6cd4baf8012892bb7d5cb7 SHA512 b5880386d9952b3aceac95d8b7a4f5e8293b29a629019e7cc3aa57e13b35a9cfbd0fd2a9db5fed80b2ebf7225a1a05c7388a67da91b310434833b4c6efd02278

diff --git a/dev-util/dogtail/dogtail-0.9.11.ebuild b/dev-util/dogtail/dogtail-0.9.11.ebuild
new file mode 100644
index 00000000000..b457e48c7e3
--- /dev/null
+++ b/dev-util/dogtail/dogtail-0.9.11.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7} )
+
+inherit distutils-r1 gnome2-utils xdg
+
+DESCRIPTION="GUI test tool and automation framework using accessibility framework"
+HOMEPAGE="https://gitlab.com/dogtail/dogtail/commits/master"
+SRC_URI="https://gitlab.com/${PN}/${PN}/raw/released/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE=""
+
+RDEPEND="
+	dev-libs/gobject-introspection
+	dev-python/pyatspi[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/pillow[${PYTHON_USEDEP}]
+	x11-libs/gdk-pixbuf:2[introspection]
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libwnck:3[introspection]
+	x11-base/xorg-server[xvfb]
+	x11-apps/xinit
+"
+DEPEND=""
+BDEPEND=""
+
+# Tests require org.gnome.desktop.interface toolkit-accessibility
+#distutils_enable_tests nose
+
+src_prepare() {
+	# Install docs in one place
+	sed "s:doc/${PN}:doc/${PF}:" -i setup.py || die
+
+	# Upstream loads resources relative to __file__, which doesn't work with
+	# gentoo's dev-lang/python-exec. So we need to add hard-coded paths.
+	eapply "${FILESDIR}"/${PN}-0.9.10-gentoo-paths.patch
+	sed -e "s:@EPREFIX_USR@:'${EPREFIX}/usr':" -i sniff/sniff || die "sed failed"
+
+	xdg_src_prepare
+	distutils-r1_src_prepare
+}