[gentoo-commits] repo/gentoo:master commit in: media-plugins/audacious-plugins/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     80ff8d8a989b951d86bb8e294e810adf2e804017
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 16 19:46:31 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Apr 16 19:54:39 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=80ff8d8a

media-plugins/audacious-plugins: 4.0.2 version bump

Thanks-to: Etienne d'Hautefeuille <bdouxx-git <AT> yahoo.fr>
Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-plugins/audacious-plugins/Manifest           |   1 +
 .../audacious-plugins-4.0.2.ebuild                 | 166 +++++++++++++++++++++
 2 files changed, 167 insertions(+)

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index 801ea0015f3..802bc293a7b 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1,2 +1,3 @@
 DIST audacious-plugins-3.10.1.tar.bz2 1715477 BLAKE2B fda3940e6c06aadd93a3e1538be747083fcc969cf3118cf3e942787906b9ee0a13bd3c30d15ba19cb713559cdf8f7b71d7b961173b1619f0aafbdea5deb75ac3 SHA512 454e9ce4061e92a0ecda40f562d4cc7453fc0019fd76b25dbe9e319319fa37c22f9785cb29563e8074de8a88e6130106aca1e431790297e1b4636dc974fde565
+DIST audacious-plugins-4.0.2.tar.bz2 1752042 BLAKE2B 73a7c72517e1f897885d0d73797e0b47fe4c25625f317dd6ea6179de997d10f2e6b829bc35411794c1b526eb671e07220bc7056214668d2cd5b53d2e754a7041 SHA512 0d3aa46f6ad75e6d541de7b7f24de2cc169a8856c5a204688231b6233131a1ce55feb9bb126eed89d05a8ee21e3a441449a1e11fd20b4fc10724afebb4318118
 DIST audacious-plugins-4.0.tar.bz2 1741569 BLAKE2B 2be0bd0d48cda51788286385a1c75d9f9d5701fff325dab7fe0f63560051690f023d8e27d24d33b87aefeaa0d54cc5e6240736511d9b547aad9d260da0e9f471 SHA512 f9f7d249ff5b8337729ce59b24ec249b96842ed9986a6a42a4de179bed44a431316537311a5514d652c0f847d7e849afd18e0bb2a2a5628d24cc6d449c52095c

diff --git a/media-plugins/audacious-plugins/audacious-plugins-4.0.2.ebuild b/media-plugins/audacious-plugins/audacious-plugins-4.0.2.ebuild
new file mode 100644
index 00000000000..9344bbc0468
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-4.0.2.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
+else
+	SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth gme http jack
+	lame libav libnotify libsamplerate lirc mms modplug mp3 nls opengl
+	pulseaudio qtmedia scrobbler sdl sid sndfile soxr speedpitch streamtuner
+	vorbis wavpack"
+REQUIRED_USE="
+	|| ( alsa jack pulseaudio qtmedia sdl )
+	ampache? ( http ) streamtuner? ( http )"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )
+"
+DEPEND="
+	app-arch/unzip
+	dev-libs/dbus-glib
+	dev-libs/glib
+	dev-libs/libxml2:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	~media-sound/audacious-${PV}
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	ampache? ( =media-libs/ampache_browser-1* )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia:=
+		>=media-libs/libcddb-1.2.1
+	)
+	cue? ( media-libs/libcue:= )
+	ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
+	flac? (
+		>=media-libs/flac-1.2.1-r1
+		>=media-libs/libvorbis-1.0
+	)
+	fluidsynth? ( media-sound/fluidsynth:= )
+	http? ( >=net-libs/neon-0.26.4 )
+	jack? (
+		>=media-libs/bio2jack-0.4
+		virtual/jack
+	)
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	libsamplerate? ( media-libs/libsamplerate:= )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	opengl? ( dev-qt/qtopengl:5 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl2[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	soxr? ( media-libs/soxr )
+	speedpitch? ( media-libs/libsamplerate:= )
+	streamtuner? ( dev-qt/qtnetwork:5 )
+	vorbis? (
+		>=media-libs/libogg-1.1.3
+		>=media-libs/libvorbis-1.2.0
+	)
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+}
+
+src_prepare() {
+	default
+	if ! use nls; then
+		sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+	fi
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-mpris2
+		--enable-qt
+		--enable-songchange
+		--disable-adplug # not packaged
+		--disable-gtk
+		--disable-openmpt # not packaged
+		--disable-oss4
+		--disable-coreaudio
+		--disable-sndio
+		$(use_enable aac)
+		$(use_enable alsa)
+		$(use_enable ampache)
+		$(use_enable bs2b)
+		$(use_enable cdda cdaudio)
+		$(use_enable cue)
+		$(use_enable flac)
+		$(use_enable flac filewriter)
+		$(use_enable fluidsynth amidiplug)
+		$(use_enable gme console)
+		$(use_enable http neon)
+		$(use_enable jack)
+		$(use_enable lame filewriter_mp3)
+		$(use_enable libnotify notify)
+		$(use_enable libsamplerate resample)
+		$(use_enable lirc)
+		$(use_enable mms)
+		$(use_enable modplug)
+		$(use_enable mp3 mpg123)
+		$(use_enable nls)
+		$(use_enable opengl qtglspectrum)
+		$(use_enable pulseaudio pulse)
+		$(use_enable qtmedia qtaudio)
+		$(use_enable scrobbler scrobbler2)
+		$(use_enable sdl sdlout)
+		$(use_enable sid)
+		$(use_enable sndfile)
+		$(use_enable soxr)
+		$(use_enable speedpitch)
+		$(use_enable streamtuner)
+		$(use_enable vorbis)
+		$(use_enable wavpack)
+		$(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
+	)
+
+	econf "${myeconfargs[@]}"
+}