[gentoo-commits] repo/gentoo:master commit in: net-libs/libaccounts-glib/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     f34eb93c0c51a77db376721915dd2872c0aa7b0f
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Apr 16 18:35:49 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Apr 16 18:36:11 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f34eb93c

net-libs/libaccounts-glib: 1.25 version bump, python3_8

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 net-libs/libaccounts-glib/Manifest                 |  1 +
 .../libaccounts-glib/libaccounts-glib-1.25.ebuild  | 61 ++++++++++++++++++++++
 2 files changed, 62 insertions(+)

diff --git a/net-libs/libaccounts-glib/Manifest b/net-libs/libaccounts-glib/Manifest
index be260dd06ff..06bac4c4694 100644
--- a/net-libs/libaccounts-glib/Manifest
+++ b/net-libs/libaccounts-glib/Manifest
@@ -1 +1,2 @@
 DIST libaccounts-glib-1.24.tar.gz 116578 BLAKE2B d3569ee9d4b92f285f20ab7bc285c62c9817a16f632ad9da83a86ab69e7e3ded74afbcb1307deee788a74796372c0011563ecd293cba4b0e81d15252eae4cf50 SHA512 d4e6906f642c7a196cb42172f31345f58037d528950bee3af2b8cb388aea386056cbaa22f0e7c604a4e00038b231e9ee455f6a1d48f82344cfc0037ad7251b7c
+DIST libaccounts-glib-1.25.tar.gz 117337 BLAKE2B 72e6e15b63eea4d5b2a3e994779a4636bee859c6d395c8c9f65120cfee1c25a5708971b438010f668eefee20735b01e9f9f4e1ac4cb55495a06143d20198e422 SHA512 cc8b493d246f99300ee614fed93258378ecdbe9c518a958a59827ee8f74559b1ee3683acfb85f59aa91390275497fb35041da2be47f27f24f96e1efd5d6d2e20

diff --git a/net-libs/libaccounts-glib/libaccounts-glib-1.25.ebuild b/net-libs/libaccounts-glib/libaccounts-glib-1.25.ebuild
new file mode 100644
index 00000000000..95098596ca1
--- /dev/null
+++ b/net-libs/libaccounts-glib/libaccounts-glib-1.25.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8} )
+inherit meson python-r1 vala
+
+DESCRIPTION="Accounts SSO (Single Sign-On) management library for GLib applications"
+HOMEPAGE="https://gitlab.com/accounts-sso/libaccounts-glib"
+SRC_URI="https://gitlab.com/accounts-sso/${PN}/-/archive/VERSION_${PV}/${PN}-VERSION_${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0/1"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+IUSE="doc"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-db/sqlite:3
+	dev-libs/glib:2
+	dev-libs/gobject-introspection:=
+	dev-libs/libxml2
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	$(vala_depend)
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	dev-libs/check
+	doc? ( dev-util/gtk-doc )
+"
+
+# fails
+RESTRICT="test"
+
+S="${WORKDIR}/${PN}-VERSION_${PV}"
+
+src_prepare() {
+	default
+
+	vala_src_prepare --ignore-use
+
+	use doc || sed -e "/^subdir('docs')$/d" -i meson.build || die
+}
+
+src_configure() {
+	python_foreach_impl run_in_build_dir meson_src_configure
+}
+
+src_compile() {
+	python_foreach_impl run_in_build_dir meson_src_compile
+}
+
+src_install() {
+	einstalldocs
+	python_foreach_impl run_in_build_dir meson_src_install
+	python_foreach_impl python_optimize
+}