[gentoo-commits] repo/gentoo:master commit in: mail-client/geary/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     164faf3d323927dfa3a6fe8fdb09914425dcfa66
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 29 09:15:44 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 29 09:19:39 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=164faf3d

mail-client/geary: bump to 3.36.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 mail-client/geary/Manifest            |  1 +
 mail-client/geary/geary-3.36.1.ebuild | 97 +++++++++++++++++++++++++++++++++++
 2 files changed, 98 insertions(+)

diff --git a/mail-client/geary/Manifest b/mail-client/geary/Manifest
index c710e3a282f..7c4229a5ed5 100644
--- a/mail-client/geary/Manifest
+++ b/mail-client/geary/Manifest
@@ -1,2 +1,3 @@
 DIST geary-3.34.2.tar.xz 2411940 BLAKE2B 61c0f69b3327c487530180544bbe13d131e4236d6a205db90278b75e839294923176b41d423a52d18c5b36b6dda7865ddbaf4e929260c2c845a69a6527b4fae9 SHA512 d34886829e1330bfe7fe4891b5e368010f5742a5ac20ab057a902897df1f6c4145a882379d9dbe82e0c954a91db265b9758ddd2eb96b9c03c0efc0f6d8cc6ea0
 DIST geary-3.36.0.tar.xz 2393620 BLAKE2B 06b06a948c0932f24fd3cbb70727d9fa1746dc506c80b29f100524a6b8adbfccadee5c3d5b6524c98ed6f902e68bd3151d3c3246cce4c2a825d9e99efa7a9fed SHA512 aefc29e64acc8e4416eb213de8948b6d51dc12f1087b9376ddc8e4991efc171b36c35868043ab3159eef614916da82c046222c5ea6256b51cbc72bce9cfec7d6
+DIST geary-3.36.1.tar.xz 2400548 BLAKE2B 84240b7b5b80e6172e875d46554caca5d3a10f85965f65916603a4dcf3ada8ed8a23f6c1e2ceb64922e0eaa072122bd41b22bbc2f37b35b2205f703f49887a4b SHA512 7d5812ece5f5315245237a57de26475c4db58c4bdcce4399a3d304e25d60093dfbe1332764e056f94bf754b19be2279d0b4237b628746202b6f5dc5755b11ca8

diff --git a/mail-client/geary/geary-3.36.1.ebuild b/mail-client/geary/geary-3.36.1.ebuild
new file mode 100644
index 00000000000..17409d7cf55
--- /dev/null
+++ b/mail-client/geary/geary-3.36.1.ebuild
@@ -0,0 +1,97 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.44"
+
+inherit gnome.org gnome2-utils meson vala virtualx xdg
+
+DESCRIPTION="A lightweight, easy-to-use, feature-rich email client"
+HOMEPAGE="https://wiki.gnome.org/Apps/Geary"
+
+LICENSE="LGPL-2.1+ BSD-2 CC-BY-3.0 CC-BY-SA-3.0" # code is LGPL-2.1+, BSD-2 for bundled snowball-stemmer, CC licenses for some icons
+SLOT="0"
+
+IUSE="ytnef"
+
+KEYWORDS="~amd64 ~x86"
+
+# for now both enchants work, but ensuring enchant:2
+
+# >=webkit-gtk-2.26.4-r1 and >=gspell-1.7 dep to ensure all libraries used use enchant:2
+DEPEND="
+	>=dev-libs/glib-2.60.4:2
+	>=x11-libs/gtk+-3.24.7:3
+	>=net-libs/webkit-gtk-2.26.4-r1:4=
+	>=dev-libs/gmime-3.2.4:3.0
+	>=dev-db/sqlite-3.24:3
+
+	app-text/enchant:2
+	>=dev-libs/folks-0.11:0
+	>=app-crypt/gcr-3.10.1:0=
+	>=dev-libs/libgee-0.8.5:0.8=
+	net-libs/gnome-online-accounts
+	>=app-text/gspell-1.7:=
+	app-text/iso-codes
+	>=dev-libs/json-glib-1.0
+	>=gui-libs/libhandy-0.0.10:0.0=
+	>=dev-libs/libpeas-1.24.0
+	>=app-crypt/libsecret-0.11
+	>=net-libs/libsoup-2.48:2.4
+	>=sys-libs/libunwind-1.1:7
+	>=dev-libs/libxml2-2.7.8:2
+	ytnef? ( >=net-mail/ytnef-1.9.3 )
+"
+RDEPEND="${DEPEND}
+	gnome-base/gsettings-desktop-schemas
+"
+BDEPEND="
+	>=dev-libs/appstream-glib-0.7.10
+	dev-libs/libxml2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+
+	$(vala_depend)
+	x11-libs/gtk+:3[introspection]
+	net-libs/webkit-gtk:4[introspection]
+	dev-libs/gmime:3.0[vala]
+	app-crypt/gcr:0[introspection,vala]
+	dev-libs/libgee:0.8[introspection]
+	app-text/gspell[vala]
+	gui-libs/libhandy:0.0[vala]
+	app-crypt/libsecret[introspection,vala]
+	net-libs/libsoup:2.4[introspection,vala]
+"
+
+src_prepare() {
+	vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Dcontractor=false
+		-Dlibunwind_optional=false # TODO: Automagical if optional=true
+		-Dpoodle=true
+		$(meson_use ytnef tnef-support)
+		-Dvaladoc=false
+		-Dprofile=default
+	)
+
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}