[gentoo-commits] repo/gentoo:master commit in: net-p2p/qbittorrent/

["Mikle Kolyada" <zlogene@gentoo.org>]

commit:     88e3111208d89a1a6ac46f744234d5bd98ef4eee
Author:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 27 08:00:23 2020 +0000
Commit:     Mikle Kolyada <zlogene <AT> gentoo <DOT> org>
CommitDate: Fri Mar 27 08:00:23 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=88e31112

net-p2p/qbittorrent: Version bump (v4.2.2)

Package-Manager: Portage-2.3.89, Repoman-2.3.20
Signed-off-by: Mikle Kolyada <zlogene <AT> gentoo.org>

 net-p2p/qbittorrent/Manifest                 |  1 +
 net-p2p/qbittorrent/qbittorrent-4.2.2.ebuild | 69 ++++++++++++++++++++++++++++
 2 files changed, 70 insertions(+)

diff --git a/net-p2p/qbittorrent/Manifest b/net-p2p/qbittorrent/Manifest
index af16d9489ff..3636dca1693 100644
--- a/net-p2p/qbittorrent/Manifest
+++ b/net-p2p/qbittorrent/Manifest
@@ -1 +1,2 @@
 DIST qbittorrent-4.2.1.tar.gz 7824636 BLAKE2B 06aa493b4e59f8e064955c604846cd4e4d404988819aa4f0b7a555cd3d8c74f42d4b40b581bc5c2360e5b75f0ce33f77882051360453176a9540d03d4d5de82d SHA512 345c702a49d284fe28b45e52719a79195a784ba07339ea49c340d10d387482d3ba59335b2e41616de97e3813531e808c41239e597ef4b710fcebceb0c837483c
+DIST qbittorrent-4.2.2.tar.gz 7947231 BLAKE2B 3c089cd70850c29b8a3131c887eac1bcab4ac5f5a1e792668018b62e04ef2d2a5ed8dfa4b2667cd81b9623c2bc92141de94212dfbd18ce9da1ea1a07b8e8ac6c SHA512 a6df94183597609c517c85ae45076a9885e67be4b261a79221021a398b92860c6925738593bb9ae33b270a5a906331ed76287f685aadc97906c8fb8094876ed2

diff --git a/net-p2p/qbittorrent/qbittorrent-4.2.2.ebuild b/net-p2p/qbittorrent/qbittorrent-4.2.2.ebuild
new file mode 100644
index 00000000000..3244261dacc
--- /dev/null
+++ b/net-p2p/qbittorrent/qbittorrent-4.2.2.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit xdg-utils
+
+DESCRIPTION="BitTorrent client in C++ and Qt"
+HOMEPAGE="https://www.qbittorrent.org
+	  https://github.com/qbittorrent"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/${PN}/qBittorrent.git"
+else
+	SRC_URI="https://github.com/qbittorrent/qBittorrent/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~ppc64 ~x86"
+	S="${WORKDIR}/qBittorrent-release-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+dbus debug webui +X"
+REQUIRED_USE="dbus? ( X )"
+
+RDEPEND="
+	>=dev-libs/boost-1.62.0-r1:=
+	dev-qt/qtcore:5
+	dev-qt/qtnetwork:5[ssl]
+	>=dev-qt/qtsingleapplication-2.6.1_p20130904-r1[qt5(+),X?]
+	dev-qt/qtxml:5
+	>=net-libs/libtorrent-rasterbar-1.2.0:0=
+	sys-libs/zlib
+	dbus? ( dev-qt/qtdbus:5 )
+	X? (
+		dev-libs/geoip
+		dev-qt/qtgui:5
+		dev-qt/qtsvg:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}
+	dev-qt/linguist-tools:5"
+
+BDEPEND="virtual/pkgconfig"
+
+DOCS=( AUTHORS Changelog CONTRIBUTING.md README.md TODO )
+
+src_configure() {
+	econf \
+	$(use_enable dbus qt-dbus) \
+	$(use_enable debug) \
+	$(use_enable webui) \
+	$(use_enable X gui)
+}
+
+src_install() {
+	emake STRIP="/bin/false" INSTALL_ROOT="${D}" install
+	einstalldocs
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_desktop_database_update
+}