[gentoo-commits] repo/gentoo:master commit in: media-plugins/audacious-plugins/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     8717a2fe16d0b1ad1a028a8616d77ef20b71c027
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sat Mar 21 22:36:41 2020 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sat Mar 21 22:40:44 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=8717a2fe

media-plugins/audacious-plugins: 4.0 version bump

Package-Manager: Portage-2.3.94, Repoman-2.3.21
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 media-plugins/audacious-plugins/Manifest           |   1 +
 .../audacious-plugins/audacious-plugins-4.0.ebuild | 166 +++++++++++++++++++++
 2 files changed, 167 insertions(+)

diff --git a/media-plugins/audacious-plugins/Manifest b/media-plugins/audacious-plugins/Manifest
index a41ee5793eb..9f81424abf9 100644
--- a/media-plugins/audacious-plugins/Manifest
+++ b/media-plugins/audacious-plugins/Manifest
@@ -1,3 +1,4 @@
 DIST audacious-plugins-3.10.1.tar.bz2 1715477 BLAKE2B fda3940e6c06aadd93a3e1538be747083fcc969cf3118cf3e942787906b9ee0a13bd3c30d15ba19cb713559cdf8f7b71d7b961173b1619f0aafbdea5deb75ac3 SHA512 454e9ce4061e92a0ecda40f562d4cc7453fc0019fd76b25dbe9e319319fa37c22f9785cb29563e8074de8a88e6130106aca1e431790297e1b4636dc974fde565
 DIST audacious-plugins-3.9-gtk3.tar.bz2 1842950 BLAKE2B 55f373be204a9b4c9cff41d41d43c4776f680ab203643e90e5d338bec2e7f8a4c60cda9caa08e461089a475f3ec1bc237538f781718eb0d26a4365743337e977 SHA512 e2529af761bc97e589cac08689b16db657096b1bbfcc802789726ae1b472746025bec1b492de52eef755d7b50574d09b9250761bf701b1ca37f8a0e8db0f207b
 DIST audacious-plugins-4.0-beta1.tar.bz2 1731865 BLAKE2B 0187137f25b19f672fe580c13ab0050d1968fc95886fa66e42a83ff674e37463f19fc29a0603afc1a0f25b54ae535b12089c44b6c7a45f23022dc71f5a366062 SHA512 4d365967478c926db3c71b68b8c4bf0333da551f1581b01f860d0846162d6f6d1564a9fc627ce3cfcea4e47c02133dbd37407dedc283d9945e60c4f472e9dd41
+DIST audacious-plugins-4.0.tar.bz2 1741569 BLAKE2B 2be0bd0d48cda51788286385a1c75d9f9d5701fff325dab7fe0f63560051690f023d8e27d24d33b87aefeaa0d54cc5e6240736511d9b547aad9d260da0e9f471 SHA512 f9f7d249ff5b8337729ce59b24ec249b96842ed9986a6a42a4de179bed44a431316537311a5514d652c0f847d7e849afd18e0bb2a2a5628d24cc6d449c52095c

diff --git a/media-plugins/audacious-plugins/audacious-plugins-4.0.ebuild b/media-plugins/audacious-plugins/audacious-plugins-4.0.ebuild
new file mode 100644
index 00000000000..85423550a52
--- /dev/null
+++ b/media-plugins/audacious-plugins/audacious-plugins-4.0.ebuild
@@ -0,0 +1,166 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+MY_P="${P/_/-}"
+
+if [[ ${PV} == *9999 ]]; then
+	inherit autotools git-r3
+	EGIT_REPO_URI="https://github.com/audacious-media-player/audacious-plugins.git"
+else
+	SRC_URI="https://distfiles.audacious-media-player.org/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~x86"
+fi
+DESCRIPTION="Lightweight and versatile audio player"
+HOMEPAGE="https://audacious-media-player.org/"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="aac +alsa ampache bs2b cdda cue ffmpeg flac fluidsynth http gme
+	jack lame libav libnotify libsamplerate lirc mms modplug mp3 nls opengl
+	pulseaudio qtmedia scrobbler sdl sid sndfile soxr speedpitch streamtuner
+	vorbis wavpack"
+REQUIRED_USE="
+	|| ( alsa jack pulseaudio qtmedia sdl )
+	ampache? ( http )"
+
+# The following plugins REQUIRE a GUI build of audacious, because non-GUI
+# builds do NOT install the libaudgui library & headers.
+# Plugins without a configure option:
+#   alarm
+#   albumart
+#   delete-files
+#   ladspa
+#   playlist-manager
+#   search-tool
+#   skins
+#   vtx
+# Plugins with a configure option:
+#   glspectrum
+#   gtkui
+#   hotkey
+#   notify
+#   statusicon
+BDEPEND="
+	dev-util/gdbus-codegen
+	virtual/pkgconfig
+	nls? ( dev-util/intltool )
+"
+DEPEND="
+	app-arch/unzip
+	dev-libs/dbus-glib
+	dev-libs/glib
+	dev-libs/libxml2:2
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtwidgets:5
+	~media-sound/audacious-${PV}
+	aac? ( >=media-libs/faad2-2.7 )
+	alsa? ( >=media-libs/alsa-lib-1.0.16 )
+	ampache? ( =media-libs/ampache_browser-1* )
+	bs2b? ( media-libs/libbs2b )
+	cdda? (
+		dev-libs/libcdio:=
+		dev-libs/libcdio-paranoia:=
+		>=media-libs/libcddb-1.2.1
+	)
+	cue? ( media-libs/libcue:= )
+	ffmpeg? ( >=virtual/ffmpeg-0.7.3 )
+	flac? (
+		>=media-libs/flac-1.2.1-r1
+		>=media-libs/libvorbis-1.0
+	)
+	fluidsynth? ( media-sound/fluidsynth:= )
+	http? ( >=net-libs/neon-0.26.4 )
+	jack? (
+		>=media-libs/bio2jack-0.4
+		virtual/jack
+	)
+	lame? ( media-sound/lame )
+	libnotify? ( x11-libs/libnotify )
+	libsamplerate? ( media-libs/libsamplerate:= )
+	lirc? ( app-misc/lirc )
+	mms? ( >=media-libs/libmms-0.3 )
+	modplug? ( media-libs/libmodplug )
+	mp3? ( >=media-sound/mpg123-1.12.1 )
+	pulseaudio? ( >=media-sound/pulseaudio-0.9.3 )
+	opengl? ( dev-qt/qtopengl:5 )
+	qtmedia? ( dev-qt/qtmultimedia:5 )
+	scrobbler? ( net-misc/curl )
+	sdl? ( media-libs/libsdl2[sound] )
+	sid? ( >=media-libs/libsidplayfp-1.0.0 )
+	sndfile? ( >=media-libs/libsndfile-1.0.17-r1 )
+	soxr? ( media-libs/soxr )
+	speedpitch? ( media-libs/libsamplerate:= )
+	streamtuner? ( dev-qt/qtnetwork:5 )
+	vorbis? (
+		>=media-libs/libogg-1.1.3
+		>=media-libs/libvorbis-1.2.0
+	)
+	wavpack? ( >=media-sound/wavpack-4.50.1-r1 )
+"
+RDEPEND="${DEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+pkg_setup() {
+	use mp3 || ewarn "MP3 support is optional, you may want to enable the mp3 USE-flag"
+}
+
+src_prepare() {
+	default
+	if ! use nls; then
+		sed -e "/SUBDIRS/s/ po//" -i Makefile || die # bug #512698
+	fi
+	[[ ${PV} == *9999 ]] && eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--enable-mpris2
+		--enable-qt
+		--enable-songchange
+		--disable-adplug # not packaged
+		--disable-gtk
+		--disable-openmpt # not packaged
+		--disable-oss4
+		--disable-coreaudio
+		--disable-sndio
+		$(use_enable aac)
+		$(use_enable alsa)
+		$(use_enable ampache)
+		$(use_enable bs2b)
+		$(use_enable cdda cdaudio)
+		$(use_enable cue)
+		$(use_enable flac)
+		$(use_enable flac filewriter)
+		$(use_enable fluidsynth amidiplug)
+		$(use_enable gme console)
+		$(use_enable http neon)
+		$(use_enable jack)
+		$(use_enable lame filewriter_mp3)
+		$(use_enable libnotify notify)
+		$(use_enable libsamplerate resample)
+		$(use_enable lirc)
+		$(use_enable mms)
+		$(use_enable modplug)
+		$(use_enable mp3 mpg123)
+		$(use_enable nls)
+		$(use_enable opengl qtglspectrum)
+		$(use_enable pulseaudio pulse)
+		$(use_enable qtmedia qtaudio)
+		$(use_enable scrobbler scrobbler2)
+		$(use_enable sdl sdlout)
+		$(use_enable sid)
+		$(use_enable sndfile)
+		$(use_enable soxr)
+		$(use_enable speedpitch)
+		$(use_enable streamtuner)
+		$(use_enable vorbis)
+		$(use_enable wavpack)
+		$(use_with ffmpeg ffmpeg $(usex libav libav ffmpeg))
+	)
+
+	econf "${myeconfargs[@]}"
+}