[gentoo-commits] repo/gentoo:master commit in: app-office/planner/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     4d4acaf3d8cb6e61e0765dab4601f5d6d5ba29a0
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 15 17:01:14 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 15 17:37:44 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=4d4acaf3

app-office/planner: drop python2 support

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 .../planner/planner-0.14.6_p20130520-r2.ebuild     | 66 ++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/app-office/planner/planner-0.14.6_p20130520-r2.ebuild b/app-office/planner/planner-0.14.6_p20130520-r2.ebuild
new file mode 100644
index 00000000000..b0fe576b0d1
--- /dev/null
+++ b/app-office/planner/planner-0.14.6_p20130520-r2.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+DESCRIPTION="Project manager for Gnome"
+HOMEPAGE="https://wiki.gnome.org/Apps/Planner"
+SRC_URI="https://dev.gentoo.org/~eva/distfiles/${PN}/${P}.tar.xz"
+
+SLOT="0"
+LICENSE="GPL-2"
+KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86"
+
+IUSE="eds examples"
+
+RDEPEND="
+	>=dev-libs/glib-2.6:2
+	>=x11-libs/gtk+-2.24:2
+	>=gnome-base/libgnomecanvas-2.10
+	>=gnome-base/libglade-2.4:2.0
+	>=gnome-base/gconf-2.10:2
+	>=dev-libs/libxml2-2.6.27:2
+	>=dev-libs/libxslt-1.1.23
+	eds? (
+		>=gnome-extra/evolution-data-server-3.6:=
+		>=mail-client/evolution-3.6 )
+"
+DEPEND="${RDEPEND}
+	app-text/rarian
+	dev-util/gtk-doc-am
+	>=dev-util/intltool-0.35.5
+	gnome-base/gnome-common
+	virtual/pkgconfig
+"
+
+S="${WORKDIR}/${PN}-0.14.6"
+
+src_configure() {
+	# FIXME: disable eds backend for now, it fails, upstream bug #654005
+	# We need to set compile-warnings to a different value as it doesn't use
+	# standard macro: https://bugzilla.gnome.org/703067
+	gnome2_src_configure \
+		--disable-python \
+		--disable-python-plugin \
+		$(use_enable eds) \
+		--disable-eds-backend \
+		--with-database=no \
+		--disable-update-mimedb \
+		--enable-compile-warnings=yes
+		#$(use_enable eds eds-backend)
+}
+
+src_install() {
+	# error: relink `libstorage-mrproject-1.la' with the above command before installing it
+	# Try to drop workaround on next snapshot or bump
+	MAKEOPTS="${MAKEOPTS} -j1" gnome2_src_install \
+		sqldocdir="\$(datadir)/doc/${PF}" \
+		sampledir="\$(datadir)/doc/${PF}/examples"
+
+	if ! use examples; then
+		rm -rf "${D}/usr/share/doc/${PF}/examples"
+	fi
+}