[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-session/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     5ad6462d6c4ed7d8385f92d885ef904c224ae7ca
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar 15 12:51:31 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar 15 17:37:43 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=5ad6462d

gnome-base/gnome-session: bump to 3.34.2

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-base/gnome-session/Manifest                  |   2 +
 .../gnome-session/gnome-session-3.34.2.ebuild      | 131 +++++++++++++++++++++
 2 files changed, 133 insertions(+)

diff --git a/gnome-base/gnome-session/Manifest b/gnome-base/gnome-session/Manifest
index 0a70b5b6a2c..3f5eb2bdf54 100644
--- a/gnome-base/gnome-session/Manifest
+++ b/gnome-base/gnome-session/Manifest
@@ -1 +1,3 @@
 DIST gnome-session-3.32.0.tar.xz 485916 BLAKE2B f9c36fbc56adb5c18b674be31ebfc0236f4a0e125d82fb1ddf8277d599eada2b57bbb06d9e538dc3b101d942472628fe80e10f57be1cbf326ff7acc24cd445f2 SHA512 53d5f84ba8ddbac5cfe0e4e3115c76008a3571779cad62a5fe064a409a507497a9ab93a46d6ba7ee4238ac0efb2f2c1379647855ac8058a945350c88400daf34
+DIST gnome-session-3.34.2-patchset.tar.xz 10196 BLAKE2B f79331c554b3004dc92d6b9d78ecb9575ad9ff071ef443ba4dca47e358e1c9bc2ecad3a43298bec7ad9e33aa85cb3fbc400f0a8739e6b1b1ebcfe3b8fd590ee5 SHA512 50d0d99bc594abdd05b2351c00db7f170282459360aaac0148a224d7e30e99283588596e84ff82bffab647cfd6a01a306a5c951da77d68e50ad8e146d3aae62a
+DIST gnome-session-3.34.2.tar.xz 474692 BLAKE2B 5b928a4632966bc12ff94ae76079cd39352dc7008e9a1044ccc63e1ba588d26a6a5812a69a995f86cef6f9f2f18ae2865793dd28335218308ada85969966fb75 SHA512 23388420ee117596b73ac057d2376857db726fb727fdeff4e4f420e7742622e81baef439adb04d8659a6979e5b7043c72ea334c1179974950476489a8c397182

diff --git a/gnome-base/gnome-session/gnome-session-3.34.2.ebuild b/gnome-base/gnome-session/gnome-session-3.34.2.ebuild
new file mode 100644
index 00000000000..b977b8be0ba
--- /dev/null
+++ b/gnome-base/gnome-session/gnome-session-3.34.2.ebuild
@@ -0,0 +1,131 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="Gnome session manager"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-session"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${PF}-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
+IUSE="consolekit doc elogind systemd"
+# There is a null backend available, thus ?? not ^^
+# consolekit can be enabled alone, or together with a logind provider; in latter case CK is used as fallback
+REQUIRED_USE="?? ( elogind systemd )"
+
+DEPEND="
+	>=dev-libs/glib-2.46.0:2
+	>=x11-libs/gtk+-3.18.0:3
+	x11-libs/libICE
+	x11-libs/libSM
+	x11-libs/libX11
+	>=gnome-base/gnome-desktop-3.34.2:3=
+	>=dev-libs/json-glib-0.10
+	media-libs/mesa[egl,gles2,X(+)]
+	media-libs/libepoxy
+	x11-libs/libXcomposite
+
+	systemd? ( >=sys-apps/systemd-183:0= )
+	elogind? ( >=sys-auth/elogind-239.4 )
+	consolekit? ( >=dev-libs/dbus-glib-0.76 )
+"
+
+# Pure-runtime deps from the session files should *NOT* be added here.
+# gnome-settings-daemon is assumed to be >=3.33.90, but this is about
+# removed components, so no need to strictly require it (older just
+# won't have those daemons loaded by gnome-session).
+# x11-misc/xdg-user-dirs{,-gtk} are needed to create the various XDG_*_DIRs, and
+# create .config/user-dirs.dirs which is read by glib to get G_USER_DIRECTORY_*
+# xdg-user-dirs-update is run during login (see 10-user-dirs-update-gnome below).
+# sys-apps/dbus[X] is needed for session management.
+# Our 90-xcursor-theme-gnome reads a setting from gsettings-desktop-schemas.
+RDEPEND="${DEPEND}
+	>=gnome-base/gnome-settings-daemon-3.23.2
+	>=gnome-base/gsettings-desktop-schemas-0.1.7
+	sys-apps/dbus[X]
+	consolekit? ( sys-auth/consolekit )
+
+	x11-misc/xdg-user-dirs
+	x11-misc/xdg-user-dirs-gtk
+"
+BDEPEND="
+	dev-libs/libxslt
+	dev-util/gdbus-codegen
+	>=sys-devel/gettext-0.19.8
+	x11-libs/xtrans
+	virtual/pkgconfig
+	doc? ( app-text/xmlto
+		app-text/docbook-xml-dtd:4.1.2 )
+"
+
+PATCHES=(
+	# Various patches from other downstreams + elogind support
+	"${WORKDIR}"/patches/
+)
+
+src_prepare() {
+	xdg_src_prepare
+	# Install USE=doc in $PF if enabled
+	sed -i -e "s:meson\.project_name(), 'dbus':'${PF}', 'dbus':" doc/dbus/meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Ddeprecation_flags=false
+		$(meson_use elogind)
+		-Dsession_selector=true # gnome-custom-session
+		$(meson_use systemd)
+		-Dsystemd_session=$(usex systemd default disable)
+		$(meson_use systemd systemd_journal)
+		$(meson_use consolekit)
+		$(meson_use doc docbook)
+		-Dman=true
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	dodir /etc/X11/Sessions
+	exeinto /etc/X11/Sessions
+	doexe "${FILESDIR}/Gnome"
+
+	insinto /usr/share/applications
+	newins "${FILESDIR}/defaults.list-r4" gnome-mimeapps.list
+
+	dodir /etc/X11/xinit/xinitrc.d/
+	exeinto /etc/X11/xinit/xinitrc.d/
+	newexe "${FILESDIR}/15-xdg-data-gnome-r1" 15-xdg-data-gnome
+
+	# This should be done here as discussed in bug #270852
+	newexe "${FILESDIR}/10-user-dirs-update-gnome-r1" 10-user-dirs-update-gnome
+
+	# Set XCURSOR_THEME from current dconf setting instead of installing
+	# default cursor symlink globally and affecting other DEs (bug #543488)
+	# https://bugzilla.gnome.org/show_bug.cgi?id=711703
+	newexe "${FILESDIR}/90-xcursor-theme-gnome" 90-xcursor-theme-gnome
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	if ! has_version gnome-base/gdm && ! has_version x11-misc/sddm; then
+		ewarn "If you use a custom .xinitrc for your X session,"
+		ewarn "make sure that the commands in the xinitrc.d scripts are run."
+	fi
+
+	if ! use systemd && ! use elogind && ! use consolekit; then
+		ewarn "You are building without systemd, elogind and/or consolekit support."
+		ewarn "gnome-session won't be able to correctly track and manage your session."
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}