[gentoo-commits] repo/gentoo:master commit in: dev-util/sysprof-capture/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     2de6ef5f0375eb9ac7ef795a5185782e7da2b2f9
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  2 19:19:05 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Mon Mar  2 19:19:05 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2de6ef5f

dev-util/sysprof-capture: Ship org.gnome.Sysprof3.Profiler.xml here

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 .../sysprof-capture-3.34.1-r1.ebuild               | 50 ++++++++++++++++++++++
 1 file changed, 50 insertions(+)

diff --git a/dev-util/sysprof-capture/sysprof-capture-3.34.1-r1.ebuild b/dev-util/sysprof-capture/sysprof-capture-3.34.1-r1.ebuild
new file mode 100644
index 00000000000..7e76591dccd
--- /dev/null
+++ b/dev-util/sysprof-capture/sysprof-capture-3.34.1-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+GNOME_ORG_MODULE="sysprof"
+
+inherit gnome.org meson systemd
+
+DESCRIPTION="Static library for sysprof capture data generation"
+HOMEPAGE="http://sysprof.com/"
+
+LICENSE="GPL-3+ GPL-2+"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+RDEPEND=">=dev-libs/glib-2.61.3:2
+	!=dev-util/sysprof-3.34.1-r0"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/gdbus-codegen
+	>=sys-kernel/linux-headers-2.6.32
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	default
+	# In 3.34.1 -Dlibsysprof=false still installs various data files related with it;
+	# some of these seem fixed by 3.36
+	sed -i -e '/subdir.*data/d' meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable_gtk=false
+		-Dlibsysprof=false
+		-Dwith_sysprofd=none
+		-Dsystemdunitdir=$(systemd_get_systemunitdir)
+		# -Ddebugdir
+		-Dhelp=false
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	# In 3.36 these shouldn't be needed with with_sysprofd=none
+	rm "${ED}"/usr/share/dbus-1/interfaces/org.gnome.Sysprof2.xml || die
+	rm "${ED}"/usr/share/dbus-1/interfaces/org.gnome.Sysprof3.Service.xml || die
+}