[gentoo-commits] repo/gentoo:master commit in: dev-libs/libdazzle/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     0ee742c63edf6379cebe8f5b20633b00fc4b0aed
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Mar  1 09:06:43 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Mar  1 16:17:34 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=0ee742c6

dev-libs/libdazzle: bump to 3.34.1

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-libs/libdazzle/Manifest                |  1 +
 dev-libs/libdazzle/libdazzle-3.34.1.ebuild | 60 ++++++++++++++++++++++++++++++
 2 files changed, 61 insertions(+)

diff --git a/dev-libs/libdazzle/Manifest b/dev-libs/libdazzle/Manifest
index 4f52308191e..55c85315362 100644
--- a/dev-libs/libdazzle/Manifest
+++ b/dev-libs/libdazzle/Manifest
@@ -1 +1,2 @@
 DIST libdazzle-3.32.3.tar.xz 439492 BLAKE2B 7a8cf5a4ad29ca11b489553785e66d49a2ba7998f6791bb392ca37740441ff0e72f59ced192dc681ab20da79cb9183621a7d73baf57c9f045ae917fc993d1205 SHA512 e82d5f04706ec2003db27ece490255264828334d1e1c2076485660539664fd382c1289b9d8d4a6cc2dc31c65db270207e7d51105ffd1cadb7c384cd91199ceaa
+DIST libdazzle-3.34.1.tar.xz 440496 BLAKE2B 88321e82f1961ffffc46c2e484b39a80e201498c1f5aaf3beabe59f9d24c21b446485aeb1e70821868d207d222e9a4c9c06353f3add28a1c12ba84f90f79e640 SHA512 bb55c21c8d15406e4f09514c36e3e633d13c0cdb6b30b40a7da7e1cb5e307f371c905dbd8ee5e56d04e225df4c1c8eb9cd273df76814a4cec6ea1328b998d95e

diff --git a/dev-libs/libdazzle/libdazzle-3.34.1.ebuild b/dev-libs/libdazzle/libdazzle-3.34.1.ebuild
new file mode 100644
index 00000000000..680a282a3a0
--- /dev/null
+++ b/dev-libs/libdazzle/libdazzle-3.34.1.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org meson xdg vala virtualx
+
+DESCRIPTION="Experimental new features for GTK+ and GLib"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/libdazzle"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~sparc ~x86"
+
+IUSE="gtk-doc +introspection test +vala"
+REQUIRED_USE="vala? ( introspection )"
+RESTRICT="!test? ( test )"
+
+# We keep newer glib/gtk+ deps to avoid GtkEventControllerMotion backports gettings used
+RDEPEND="
+	>=dev-libs/glib-2.56.0:2
+	>=x11-libs/gtk+-3.24.0:3[introspection?]
+	introspection? ( dev-libs/gobject-introspection:= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources; glib-utils for glib-mkenums
+BDEPEND="
+	>=dev-util/meson-0.49.0
+	vala? ( $(vala_depend) )
+	dev-libs/libxml2:2
+	dev-util/glib-utils
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	xdg_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		-Denable_tracing=false # extra trace debugging that would make things slower
+		-Denable_profiling=false # -pg passing
+		# On linux it'll always use a vdso based implementation that is even faster
+		# than rdtscp insn, thus never build with rdtscp until we don't support non-linux
+		# as the rdtscp using function will never get called anyways.
+		-Denable_rdtscp=false
+		-Denable_tools=true # /usr/bin/dazzle-list-counters
+		$(meson_use introspection with_introspection)
+		$(meson_use vala with_vapi)
+		$(meson_use gtk-doc enable_gtk_doc)
+		$(meson_use test enable_tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}