[gentoo-commits] repo/gentoo:master commit in: net-misc/rygel/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     dae9cae6bda0949a6bfec5570d04d19fdb8c127e
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Feb 21 18:35:11 2020 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Feb 21 20:56:36 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=dae9cae6

net-misc/rygel: bump to 0.38.3

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 net-misc/rygel/Manifest            |  1 +
 net-misc/rygel/rygel-0.38.3.ebuild | 81 ++++++++++++++++++++++++++++++++++++++
 2 files changed, 82 insertions(+)

diff --git a/net-misc/rygel/Manifest b/net-misc/rygel/Manifest
index e6d45a3dc1d..3fa3336295f 100644
--- a/net-misc/rygel/Manifest
+++ b/net-misc/rygel/Manifest
@@ -1 +1,2 @@
 DIST rygel-0.36.2.tar.xz 4057356 BLAKE2B 3ff1a0df12cdda694ded3a9a5c6d1495eaf0dff7133cbc84b73ad6bc767cd3a5e31ff8b579aff9c0de455f149e49dc972f7d93d64424d25501b02f2a02f66552 SHA512 8c079f83a00c9ad237b634e6274d27acc94a91adfa2829f0336b2485aa801e6898c30ec7268352247f1d12232d9ab3cb7a6f8215370f03aaff5323c4a8fdff7f
+DIST rygel-0.38.3.tar.xz 4106460 BLAKE2B 38547cd28b0039440cf5e4a7381914c606479c1f26f91eb8af14276a6aa7d6267f0fba5b2af374ca3f0b933c683d569e26cbcec8cbdd15d620d57bd1ecf32c48 SHA512 787508f809e473dccc8461128c1b3b9d71b118008fa13660144f32ccb4b1ad02f41866ddf00343e102ed6f13552d34278917e14cf50c57ea3ffb6cf474f0ce58

diff --git a/net-misc/rygel/rygel-0.38.3.ebuild b/net-misc/rygel/rygel-0.38.3.ebuild
new file mode 100644
index 00000000000..bc8e745a945
--- /dev/null
+++ b/net-misc/rygel/rygel-0.38.3.ebuild
@@ -0,0 +1,81 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2 systemd virtualx
+
+DESCRIPTION="Rygel is an open source UPnP/DLNA MediaServer"
+HOMEPAGE="https://wiki.gnome.org/Projects/Rygel"
+
+LICENSE="LGPL-2.1+ CC-BY-SA-3.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="X +introspection +sqlite tracker test transcode"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgee-0.8:0.8
+	>=dev-libs/libxml2-2.7:2
+	>=media-libs/gupnp-dlna-0.9.4:2.0
+	>=media-libs/gstreamer-1.12:1.0
+	>=media-libs/gst-plugins-base-1.12:1.0
+	>=media-libs/libmediaart-0.7:2.0
+	media-plugins/gst-plugins-soup:1.0
+	>=net-libs/gssdp-1.1.0:0=
+	>=net-libs/gupnp-1.1.0:0=
+	>=net-libs/gupnp-av-0.12.8
+	>=net-libs/libsoup-2.44:2.4
+	>=sys-apps/util-linux-2.20
+	x11-misc/shared-mime-info
+	introspection? ( >=dev-libs/gobject-introspection-1.33.4:= )
+	sqlite? (
+		>=dev-db/sqlite-3.5:3
+		dev-libs/libunistring:=
+		x11-libs/gdk-pixbuf:2
+	)
+	tracker? ( app-misc/tracker:= )
+	transcode? (
+		media-libs/gst-plugins-bad:1.0
+		media-plugins/gst-plugins-twolame:1.0
+		media-plugins/gst-plugins-libav:1.0
+	)
+	X? ( >=x11-libs/gtk+-3.22:3 )
+"
+DEPEND="${RDEPEND}
+	dev-util/gtk-doc-am
+	>=sys-devel/gettext-0.19.7
+	virtual/pkgconfig
+"
+# Maintainer only
+#   app-text/docbook-xsl-stylesheets
+#	>=dev-lang/vala-0.36
+#   dev-libs/libxslt
+
+src_prepare() {
+	# Disable test triggering call to gst-plugins-scanner which causes
+	# sandbox issues when plugins such as clutter are installed
+	sed -e 's/return rygel_playbin_renderer_test_main (argv, argc);/return 0;/' \
+		-i tests/rygel-playbin-renderer-test.c || die
+
+	gnome2_src_prepare
+}
+
+src_configure() {
+	# We set xsltproc because man pages are provided by upstream
+	# and we do not want to regenerate them automagically.
+	gnome2_src_configure \
+		XSLTPROC=$(type -P false) \
+		--enable-gst-launch-plugin \
+		--with-media-engine=gstreamer \
+		--enable-nls \
+		--with-systemduserunitdir=$(systemd_get_userunitdir) \
+		$(use_enable introspection) \
+		$(use_enable sqlite media-export-plugin) \
+		$(use_enable sqlite lms-plugin) \
+		$(use_enable test tests) \
+		$(use_enable tracker tracker-plugin) \
+		$(use_with X ui)
+}