[gentoo-commits] repo/gentoo:master commit in: media-libs/clutter-gst/

["Matt Turner" <mattst88@gentoo.org>]

commit:     448f1c59b7c9458da5535d4cb651175a714ebd11
Author:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Sat Feb  8 19:20:54 2020 +0000
Commit:     Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Sat Feb  8 19:25:39 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=448f1c59

media-libs/clutter-gst: Remove unnecessary python dep

configure.ac detects Python and sets HAVE_PYTHON, but the build system
never uses that. Above that block in configure.ac is a comment that says

	check for python (pso2h.py needs it)

but pso2h.py is not used during the build or installed.

Closes: https://bugs.gentoo.org/706440
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>

 .../clutter-gst/clutter-gst-3.0.27-r1.ebuild       | 55 ++++++++++++++++++++++
 1 file changed, 55 insertions(+)

diff --git a/media-libs/clutter-gst/clutter-gst-3.0.27-r1.ebuild b/media-libs/clutter-gst/clutter-gst-3.0.27-r1.ebuild
new file mode 100644
index 00000000000..42615b32a54
--- /dev/null
+++ b/media-libs/clutter-gst/clutter-gst-3.0.27-r1.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+GNOME2_LA_PUNT="yes"
+
+inherit gnome2
+
+HOMEPAGE="https://blogs.gnome.org/clutter/"
+DESCRIPTION="GStreamer integration library for Clutter"
+
+LICENSE="LGPL-2.1+"
+SLOT="3.0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="X debug examples +introspection udev"
+
+# >=cogl-1.18 provides cogl-2.0-experimental
+COMMON_DEPEND="
+	>=dev-libs/glib-2.20:2
+	>=media-libs/clutter-1.20:1.0=[X=,introspection?]
+	>=media-libs/cogl-1.18:1.0=[introspection?]
+	>=media-libs/gstreamer-1.4:1.0[introspection?]
+	>=media-libs/gst-plugins-bad-1.4:1.0
+	>=media-libs/gst-plugins-base-1.4:1.0[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-0.6.8:= )
+	udev? ( dev-libs/libgudev )
+"
+# uses goom from gst-plugins-good
+RDEPEND="${COMMON_DEPEND}
+	>=media-libs/gst-plugins-good-1.4:1.0
+	!udev? ( media-plugins/gst-plugins-v4l2 )
+"
+DEPEND="${COMMON_DEPEND}
+	dev-util/glib-utils
+	>=dev-util/gtk-doc-am-1.11
+	virtual/pkgconfig
+"
+
+src_configure() {
+	# --enable-gl-texture-upload is experimental
+	gnome2_src_configure \
+		--disable-maintainer-flags \
+		--enable-debug=$(usex debug yes minimum) \
+		$(use_enable introspection) \
+		$(use_enable udev)
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use examples; then
+		insinto /usr/share/doc/"${PF}"/examples
+		doins examples/{*.c,*.png,README}
+	fi
+}