[gentoo-commits] repo/gentoo:master commit in: dev-util/ostree/

["Zac Medico" <zmedico@gentoo.org>]

commit:     86c841b7ce888c2323672adb0377a434f37e3070
Author:     Yury Martynov <email <AT> linxon <DOT> ru>
AuthorDate: Sun Dec  1 14:58:00 2019 +0000
Commit:     Zac Medico <zmedico <AT> gentoo <DOT> org>
CommitDate: Tue Jan 21 07:47:50 2020 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=86c841b7

dev-util/ostree: bump to 2019.5

Closes: https://github.com/gentoo/gentoo/pull/13825
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Yury Martynov <email <AT> linxon.ru>
Signed-off-by: Zac Medico <zmedico <AT> gentoo.org>

 dev-util/ostree/Manifest             |  1 +
 dev-util/ostree/ostree-2019.5.ebuild | 90 ++++++++++++++++++++++++++++++++++++
 2 files changed, 91 insertions(+)

diff --git a/dev-util/ostree/Manifest b/dev-util/ostree/Manifest
index 927c10f3b0c..efa90df5b75 100644
--- a/dev-util/ostree/Manifest
+++ b/dev-util/ostree/Manifest
@@ -1 +1,2 @@
 DIST ostree-2018.9.tar.xz 1951732 BLAKE2B c6fba1321fe21bff569fe1dadd1aa649f23059a35dc906c3a0b7dcca29f7acbe8338e19541d8f7d854452bf6a6b1ac293d4350c7056a9b13b9ed1eacf358d4b3 SHA512 407b6b67add54e80a55fc35f08bde56561009db93ec202a10dd1ec1e66bd32b439c1d66c759e4e173e44fce6fbc2c162cae928a477c9d7abafbf007ed8f7bfb5
+DIST ostree-2019.5.tar.xz 1972452 BLAKE2B a8b015118855b8b0097f535ac074aeffc599c3f6f654967043e8e4de339d2a51e85ad1b4b3f3b22e18d39235e6ad9c1973334a2c4fc9b5c694f2ff40d68ae703 SHA512 27150802ed9af16e698ed163f6ad235f0f99a1410df52b4b1e266585fe665880c0b9490bf245b5593cb277007b7229d808be7403dd964c58aded6e567349c912

diff --git a/dev-util/ostree/ostree-2019.5.ebuild b/dev-util/ostree/ostree-2019.5.ebuild
new file mode 100644
index 00000000000..6c6f7f20027
--- /dev/null
+++ b/dev-util/ostree/ostree-2019.5.ebuild
@@ -0,0 +1,90 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="Operating system and container binary deployment and upgrades"
+HOMEPAGE="https://ostree.readthedocs.io/en/latest/"
+SRC_URI="https://github.com/ostreedev/ostree/releases/download/v${PV}/lib${P}.tar.xz -> ${P}.tar.xz"
+
+KEYWORDS="~amd64 ~x86"
+LICENSE="LGPL-2+"
+SLOT="0"
+
+IUSE="archive curl doc dracut gnutls grub http2 httpd introspection libmount selinux ssl soup systemd zeroconf"
+RESTRICT="test"
+REQUIRED_USE="httpd? ( || ( curl soup ) )"
+
+COMMON_DEPEND="
+	archive? ( app-arch/libarchive )
+	app-crypt/gpgme
+	app-arch/xz-utils
+	curl? ( net-misc/curl )
+	soup? ( net-libs/libsoup )
+	dev-libs/libassuan
+	dev-libs/libgpg-error
+	dev-libs/glib:2
+	dracut? ( sys-kernel/dracut )
+	grub? ( sys-boot/grub:2= )
+	introspection? ( dev-libs/gobject-introspection )
+	ssl? (
+		gnutls? ( net-libs/gnutls )
+		!gnutls? ( dev-libs/openssl:0= ) )
+	sys-fs/fuse:*
+	sys-libs/zlib
+	libmount? ( sys-apps/util-linux )
+	selinux? ( sys-libs/libselinux )
+	systemd? ( sys-apps/systemd:0= )
+	zeroconf? ( net-dns/avahi[dbus] )"
+
+DEPEND="${COMMON_DEPEND}
+	app-text/docbook-xsl-stylesheets
+	dev-libs/libxslt
+	doc? ( dev-util/gtk-doc )"
+
+RDEPEND="${COMMON_DEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	sys-devel/flex
+	sys-devel/bison
+	virtual/pkgconfig"
+
+S="${WORKDIR}/lib${P}"
+
+src_prepare() {
+	sed -Ee 's:(XSLT_STYLESHEET = ).*:\1/usr/share/sgml/docbook/xsl-stylesheets/manpages/docbook.xsl:' \
+		-i Makefile.in Makefile-man.am || die
+
+	eautoreconf
+	default
+}
+
+src_configure() {
+	local econfargs=(
+		--enable-man
+		--enable-shared
+		$(use_with archive libarchive)
+		$(use_with curl)
+		$(use_with dracut)
+		$(use_enable doc gtk-doc)
+		$(use_enable introspection)
+		$(use_enable http2)
+		$(use_enable httpd trivial-httpd-cmdline)
+		$(use_with selinux )
+		$(use_with soup)
+		$(use_with libmount)
+		$(use ssl && { use gnutls && echo --with-crypto=gnutls || echo --with-crypto=openssl; })
+		$(use_with systemd libsystemd)
+		$(use_with zeroconf avahi)
+	)
+
+	unset ${!XDG_*} #657346 g-ir-scanner sandbox violation
+	econf ${econfargs[*]}
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}