From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1135052-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id A8A08138335
for <garchives@archives.gentoo.org>; Tue, 31 Dec 2019 15:13:53 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 9CE48E0B83;
Tue, 31 Dec 2019 15:13:52 +0000 (UTC)
Received: from smtp.gentoo.org (mail.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 6F34EE0B83
for <gentoo-commits@lists.gentoo.org>; Tue, 31 Dec 2019 15:13:52 +0000 (UTC)
Received: from oystercatcher.gentoo.org (oystercatcher.gentoo.org [148.251.78.52])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 3725634DB98
for <gentoo-commits@lists.gentoo.org>; Tue, 31 Dec 2019 15:13:51 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 99B7A7C
for <gentoo-commits@lists.gentoo.org>; Tue, 31 Dec 2019 15:13:48 +0000 (UTC)
From: "Sven Wegener" <swegener@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Sven Wegener" <swegener@gentoo.org>
Message-ID: <1577805206.b151de6f5ea2bb92bc151968c8dd947c192d8179.swegener@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: sci-libs/libsigrok/
X-VCS-Repository: repo/gentoo
X-VCS-Files: sci-libs/libsigrok/Manifest sci-libs/libsigrok/libsigrok-0.5.2.ebuild
X-VCS-Directories: sci-libs/libsigrok/
X-VCS-Committer: swegener
X-VCS-Committer-Name: Sven Wegener
X-VCS-Revision: b151de6f5ea2bb92bc151968c8dd947c192d8179
X-VCS-Branch: master
Date: Tue, 31 Dec 2019 15:13:48 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 03c7f000-b3c5-469c-b4de-cdafb5b2fddc
X-Archives-Hash: 01d8289edf02c66922c687f5af5f11c3
commit: b151de6f5ea2bb92bc151968c8dd947c192d8179
Author: Sven Wegener <swegener <AT> gentoo <DOT> org>
AuthorDate: Tue Dec 31 15:07:50 2019 +0000
Commit: Sven Wegener <swegener <AT> gentoo <DOT> org>
CommitDate: Tue Dec 31 15:13:26 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b151de6f
sci-libs/libsigrok: Version bump to 0.5.2
Package-Manager: Portage-2.3.79, Repoman-2.3.16
Signed-off-by: Sven Wegener <swegener <AT> gentoo.org>
sci-libs/libsigrok/Manifest | 1 +
sci-libs/libsigrok/libsigrok-0.5.2.ebuild | 156 ++++++++++++++++++++++++++++++
2 files changed, 157 insertions(+)
diff --git a/sci-libs/libsigrok/Manifest b/sci-libs/libsigrok/Manifest
index db935b04490..5bd8440632e 100644
--- a/sci-libs/libsigrok/Manifest
+++ b/sci-libs/libsigrok/Manifest
@@ -1,3 +1,4 @@
DIST libsigrok-0.3.0.tar.gz 924503 BLAKE2B 132cc952b7314e11034100973f1086d17515fb7b1eb3792506569211fe05e9f35b113fceaff7c0468ad9be0bbcac0251ae63ae856f1393c51e743983e60886df SHA512 b94e8a8da1346f9ab267fd693975411243f2cb016e48ec05f4ad88a8a1dfe5ed6f5ad4ac4bf0e94dc551dc92cd70d2719983e21abaa4811693fb28a27bf74550
DIST libsigrok-0.4.0.tar.gz 1387329 BLAKE2B 8d1578c1f84c84af54f0e6c97bcdcec6d183a80170d0b19aa44c4015dac3c418e1a1e304b42b12be3f905a3887f95d2ecc9644aeb2a81a961e09438e380ec70b SHA512 5963c1a44cf351a38d9434f89a15b20d36c7196a78464c302c65ab262bcdb2f26274c7fabf01174757e1f9a367497b9721578ebf802f75ef97ee71ff3dade1e0
DIST libsigrok-0.5.1.tar.gz 1664813 BLAKE2B b5765e1057ee4411ef2f83fa73473429bc8f84653f1c7761af3c1280decc2fcb1d3c68d8f92f7e77b85f1fcda74cf6066e5bf56c0da2de4b28148b920b94e0da SHA512 48337fc4625dc0abc162ae54e04ce091047835aa1e49ba1ab84542805008d1ff5646b143fde57e317f3b34514c0e6d4dcb7b1c5944f3f16bdef1a7169edc3517
+DIST libsigrok-0.5.2.tar.gz 1779465 BLAKE2B fc6fdde1054e9ac50bc42249c34b3dbfff1e89d77f0db5a8762e52fcf2ea5ea69b2defcf1cde4ed7b1edd1e21770002ed661a470c8d666904daa48a84a2bbfc5 SHA512 cf673dad6280302d69050c29490621f66c6d6a73932d019a53ec3501316d3f2e23e7667a04f866dbe6ed73f86a63de73d2173e2b6cea563631d705e06f887092
diff --git a/sci-libs/libsigrok/libsigrok-0.5.2.ebuild b/sci-libs/libsigrok/libsigrok-0.5.2.ebuild
new file mode 100644
index 00000000000..6613025d515
--- /dev/null
+++ b/sci-libs/libsigrok/libsigrok-0.5.2.ebuild
@@ -0,0 +1,156 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+USE_RUBY="ruby26 ruby25 ruby24"
+RUBY_OPTIONAL="yes"
+
+inherit eutils gnome2-utils python-r1 java-pkg-opt-2 ruby-ng udev xdg-utils
+
+if [[ ${PV} == "9999" ]]; then
+ EGIT_REPO_URI="git://sigrok.org/${PN}"
+ inherit git-r3 autotools
+else
+ SRC_URI="https://sigrok.org/download/source/${PN}/${P}.tar.gz"
+ KEYWORDS="~amd64 ~x86"
+fi
+
+DESCRIPTION="basic hardware drivers for logic analyzers and input/output file format support"
+HOMEPAGE="https://sigrok.org/wiki/Libsigrok"
+
+LICENSE="GPL-3"
+SLOT="0/4"
+IUSE="cxx ftdi java parport python ruby serial static-libs +udev test usb"
+RESTRICT="!test? ( test )"
+REQUIRED_USE="java? ( cxx ) python? ( cxx ${PYTHON_REQUIRED_USE} ) ruby? ( cxx || ( $(ruby_get_use_targets) ) )"
+
+# We also support librevisa, but that isn't in the tree ...
+LIB_DEPEND=">=dev-libs/glib-2.32.0[static-libs(+)]
+ >=dev-libs/libzip-0.8:=[static-libs(+)]
+ cxx? ( dev-cpp/glibmm:2[static-libs(+)] )
+ python? ( ${PYTHON_DEPS} >=dev-python/pygobject-3.0.0[${PYTHON_USEDEP}] )
+ ruby? ( $(ruby_implementations_depend) )
+ ftdi? ( >=dev-embedded/libftdi-0.16:=[static-libs(+)] )
+ parport? ( sys-libs/libieee1284[static-libs(+)] )
+ serial? ( >=dev-libs/libserialport-0.1.1[static-libs(+)] )
+ usb? ( virtual/libusb:1[static-libs(+)] )"
+RDEPEND="!static-libs? ( ${LIB_DEPEND//\[static-libs(+)]} )
+ static-libs? ( ${LIB_DEPEND} )
+ java? ( >=virtual/jre-1.4 )"
+DEPEND="${LIB_DEPEND//\[static-libs(+)]}
+ test? ( >=dev-libs/check-0.9.4 )
+ cxx? ( app-doc/doxygen )
+ java? (
+ >=dev-lang/swig-3.0.6
+ >=virtual/jdk-1.4
+ )
+ python? (
+ dev-python/setuptools[${PYTHON_USEDEP}]
+ dev-python/numpy[${PYTHON_USEDEP}]
+ >=dev-lang/swig-3.0.6
+ )
+ ruby? ( >=dev-lang/swig-3.0.8 )
+ virtual/pkgconfig"
+
+S="${WORKDIR}"/${P}
+
+pkg_setup() {
+ use ruby && ruby-ng_pkg_setup
+ java-pkg-opt-2_pkg_setup
+}
+
+src_unpack() {
+ [[ ${PV} == "9999" ]] && git-r3_src_unpack || default
+}
+
+sigrok_src_prepare() {
+ [[ ${PV} == "9999" ]] && eautoreconf
+}
+
+each_ruby_prepare() {
+ sigrok_src_prepare
+}
+
+src_prepare() {
+ use ruby && cp -rl "${S}" "${WORKDIR}"/all && ruby-ng_src_prepare
+ sigrok_src_prepare
+ eapply_user
+ use python && python_copy_sources
+}
+
+sigrok_src_configure() {
+ econf \
+ $(use_with ftdi libftdi) \
+ $(use_with parport libieee1284) \
+ $(use_with serial libserialport) \
+ $(use_with usb libusb) \
+ $(use_enable cxx) \
+ $(use_enable java) \
+ $(use_enable static-libs static) \
+ "${@}"
+}
+
+each_ruby_configure() {
+ RUBY="${RUBY}" sigrok_src_configure --enable-ruby --disable-python
+}
+
+each_python_configure() {
+ cd "${BUILD_DIR}"
+ sigrok_src_configure --disable-ruby --enable-python
+}
+
+src_configure() {
+ python_setup
+ sigrok_src_configure --disable-ruby --disable-python
+ use ruby && ruby-ng_src_configure
+ use python && python_foreach_impl each_python_configure
+}
+
+each_ruby_compile() {
+ emake ruby-build
+}
+
+each_python_compile() {
+ cd "${BUILD_DIR}"
+ emake python-build
+}
+
+src_compile() {
+ default
+ use ruby && ruby-ng_src_compile
+ use python && python_foreach_impl each_python_compile
+}
+
+src_test() {
+ emake check
+}
+
+each_ruby_install() {
+ emake ruby-install DESTDIR="${D}"
+}
+
+each_python_install() {
+ cd "${BUILD_DIR}"
+ emake python-install DESTDIR="${D}"
+ python_optimize
+}
+
+src_install() {
+ default
+ use python && python_foreach_impl each_python_install
+ use ruby && ruby-ng_src_install
+ use udev && udev_dorules contrib/*.rules
+ prune_libtool_files
+}
+
+pkg_postinst() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+ gnome2_icon_cache_update
+ xdg_mimeinfo_database_update
+}