[gentoo-commits] repo/gentoo:master commit in: app-text/ansifilter/

["Michael Palimaka" <kensington@gentoo.org>]

commit:     9049673ab6a9869320cb35958bd68013ca4912d4
Author:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
AuthorDate: Mon Nov 25 10:18:36 2019 +0000
Commit:     Michael Palimaka <kensington <AT> gentoo <DOT> org>
CommitDate: Mon Nov 25 10:19:15 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=9049673a

app-text/ansifilter: version bump 2.15

Package-Manager: Portage-2.3.76, Repoman-2.3.18
Signed-off-by: Michael Palimaka <kensington <AT> gentoo.org>

 app-text/ansifilter/Manifest               |  1 +
 app-text/ansifilter/ansifilter-2.15.ebuild | 57 ++++++++++++++++++++++++++++++
 2 files changed, 58 insertions(+)

diff --git a/app-text/ansifilter/Manifest b/app-text/ansifilter/Manifest
index 7ce54604f3c..e29d60842a0 100644
--- a/app-text/ansifilter/Manifest
+++ b/app-text/ansifilter/Manifest
@@ -1 +1,2 @@
 DIST ansifilter-2.14.tar.bz2 441884 BLAKE2B 90b3b0330866da11c00b105aa79164178aebecf39131f5c8d8e373091f53d2d8bbced54472c975a61857d594a9fa92ce08d018523f471fde445d4548d48b949b SHA512 a0b7f12ea5b9ef9b5845a03484a2e238a9f60e0e49f8eddca8bf24b47faba48aa0b55f922678b3bf1b3f08857bbe9a8285b3f318f2adec84673bc502e21b6802
+DIST ansifilter-2.15.tar.bz2 441381 BLAKE2B db55f8a21aada3aa851a099e5a19a3f3bbf81b8ce5d75b31600cbc47f409306e74f57ff51c52266212fa3c59730fac0d416e99f1fefe8a7009bd357ea216b0cd SHA512 4c30ea11665ce0876664c77fbe69c377d5e692508a54b4629e9b6363c1f223b65ac91d20fd61d6d8cf719d1b391ca6d94d69dabbacde7c2dc460330d530a09af

diff --git a/app-text/ansifilter/ansifilter-2.15.ebuild b/app-text/ansifilter/ansifilter-2.15.ebuild
new file mode 100644
index 00000000000..e993d7be98a
--- /dev/null
+++ b/app-text/ansifilter/ansifilter-2.15.ebuild
@@ -0,0 +1,57 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs qmake-utils
+
+DESCRIPTION="Handles text files containing ANSI terminal escape codes"
+HOMEPAGE="http://www.andre-simon.de/"
+SRC_URI="http://www.andre-simon.de/zip/${P}.tar.bz2"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc64 ~x86"
+IUSE="qt5"
+
+RDEPEND="
+	qt5? (
+		dev-qt/qtcore:5
+		dev-qt/qtgui:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	default
+
+	# bug 431452
+	rm src/qt-gui/moc_mydialog.cpp || die
+}
+
+src_configure() {
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		eqmake5
+		popd > /dev/null || die
+	fi
+}
+
+src_compile() {
+	emake -f makefile CC="$(tc-getCXX)" CXXFLAGS="${CXXFLAGS} -DNDEBUG -std=c++11"
+
+	if use qt5 ; then
+		pushd src/qt-gui > /dev/null || die
+		emake
+		popd > /dev/null || die
+	fi
+}
+
+src_install() {
+	dobin src/${PN}
+	use qt5 && dobin src/qt-gui/${PN}-gui
+
+	gunzip man/${PN}.1.gz
+	doman man/${PN}.1
+	einstalldocs
+}