[gentoo-commits] repo/gentoo:master commit in: dev-libs/ppl/

["Sergei Trofimovich" <slyfox@gentoo.org>]

commit:     745eacdcb368d7b4ddbe12fd00e6f97161b0db42
Author:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
AuthorDate: Sun Nov 10 20:54:39 2019 +0000
Commit:     Sergei Trofimovich <slyfox <AT> gentoo <DOT> org>
CommitDate: Sun Nov 10 20:54:59 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=745eacdc

dev-libs/ppl: bump up to EAPI=7

Package-Manager: Portage-2.3.79, Repoman-2.3.18
Signed-off-by: Sergei Trofimovich <slyfox <AT> gentoo.org>

 dev-libs/ppl/ppl-1.2-r1.ebuild | 47 ++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/dev-libs/ppl/ppl-1.2-r1.ebuild b/dev-libs/ppl/ppl-1.2-r1.ebuild
new file mode 100644
index 00000000000..f522c2384bc
--- /dev/null
+++ b/dev-libs/ppl/ppl-1.2-r1.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+
+DESCRIPTION="The Parma Polyhedra Library for numerical analysis of complex systems"
+HOMEPAGE="http://bugseng.com/products/ppl"
+SRC_URI="http://bugseng.com/products/ppl/download/ftp/releases/${PV}/${P}.tar.xz"
+
+LICENSE="GPL-3"
+SLOT="0/4.14" # SONAMEs
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~sparc-solaris"
+IUSE="+cxx doc lpsol pch static-libs test"
+
+RDEPEND=">=dev-libs/gmp-6[cxx]
+	lpsol? ( sci-mathematics/glpk )"
+DEPEND="${RDEPEND}
+	app-arch/xz-utils
+	sys-devel/m4"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local interfaces=( c )
+	use cxx && interfaces+=( cxx )
+	econf \
+		--docdir="${EPREFIX}"/usr/share/doc/${PF} \
+		--disable-debugging \
+		--disable-optimization \
+		$(use_enable doc documentation) \
+		$(use_enable lpsol ppl_lpsol) \
+		$(use_enable pch) \
+		$(use_enable static-libs static) \
+		--enable-interfaces="${interfaces[*]}" \
+		$(use test && echo --enable-check=quick)
+}
+
+src_install() {
+	default
+	use static-libs || find "${ED}"/usr -name 'libppl*.la' -delete
+
+	pushd "${ED}/usr/share/doc/${PF}" >/dev/null || die
+	rm gpl* fdl* || die
+	if ! use doc ; then
+		rm -r *-html/ *.ps.gz *.pdf || die
+	fi
+}