[gentoo-commits] repo/gentoo:master commit in: dev-libs/efl/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     74b855cd3b8ee0ec09bca06b26e44ddee5b5ec5c
Author:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
AuthorDate: Fri Nov  1 12:40:09 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Nov  1 12:40:09 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=74b855cd

dev-libs/efl: bump to 1.23.2

Package-Manager: Portage-2.3.78, Repoman-2.3.17
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 dev-libs/efl/Manifest          |   1 +
 dev-libs/efl/efl-1.23.2.ebuild | 293 +++++++++++++++++++++++++++++++++++++++++
 2 files changed, 294 insertions(+)

diff --git a/dev-libs/efl/Manifest b/dev-libs/efl/Manifest
index bdc69d0b4f6..f258e9ff1a0 100644
--- a/dev-libs/efl/Manifest
+++ b/dev-libs/efl/Manifest
@@ -1,3 +1,4 @@
 DIST efl-1.22.2.tar.xz 71320272 BLAKE2B b1eb66228ec5a92f5d89bf38d95439f9bfb0b09a074e418094474d7c7d0de6a4ae998321a02273a5c9bbcfcba260a7ff3d8cef0af445293869c82c57dec2cca0 SHA512 7385b1fdeee0a4565a0765fedbe5cecca81b86b306ee95a703b3064a88427ab0b4967f6f075a92f5c1d5911cefc56a9c2d45c7347572480169e3f53348321734
 DIST efl-1.22.6.tar.xz 70641848 BLAKE2B a6644f25934d3c9776b06edd7a9ffc321da42ee039b703c1af317d14e757b489c6d42add281febde5e81b48e38fbfa31f5b201ade4d27cd50cc70d16b9028fdd SHA512 adf2b9275c295b61928134ce1af53d8830b46815d8ba09d221c7659b8a2aed6e4593b35919a98f0e33ec9b7930c5b09de8e6680536cccb21c551908b25158f56
 DIST efl-1.23.1.tar.xz 77466768 BLAKE2B a8507777f84ee356bb53982d2b102eb6413ab274ce98dbd87b62a11b6a89eb7d12e0d858b5dfcbbe3da0e1bcc753c338d4c4b7060c569ee621e71afa2477397d SHA512 9c81f28bb0d87e1a3e5d2204c0e2401d9b3f6dcc34f47cb2b41711ef033b3134f4cd283e87a216a0ce4ee903f721a1f8c2f003577444c5781e7f47ce827201e6
+DIST efl-1.23.2.tar.xz 77492124 BLAKE2B cfd77a9fa75baa12d1e6aeb9b08168ebe13ed720830bd86572d5deb3c72dbb76a51ecf32fb4dddafe0dea56266cb09a3d24cbbfa27cd98618a912e341d3b409f SHA512 59e9bedd9402c204c511a88bc6a697551dd552ddab9bc5e8a30ce1e2095d7452bca1606929693e9e706809e28bc19f039858253b1690ecd1fd2a229aa5b1b3ed

diff --git a/dev-libs/efl/efl-1.23.2.ebuild b/dev-libs/efl/efl-1.23.2.ebuild
new file mode 100644
index 00000000000..14721b4005e
--- /dev/null
+++ b/dev-libs/efl/efl-1.23.2.ebuild
@@ -0,0 +1,293 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit meson xdg-utils
+
+DESCRIPTION="Enlightenment Foundation Libraries all-in-one package"
+HOMEPAGE="https://www.enlightenment.org"
+SRC_URI="https://download.enlightenment.org/rel/libs/${PN}/${P}.tar.xz"
+
+LICENSE="BSD-2 GPL-2 LGPL-2.1 ZLIB"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~hppa ~x86"
+IUSE="X bmp connman dds debug doc +drm +eet elogind examples fbcon fontconfig
+	fribidi gif gles2 gnutls glib +gstreamer harfbuzz hyphen ibus ico libressl
+	lua +luajit jpeg2k json nls mono opengl +pdf physics pmaps postscript psd
+	pulseaudio raw scim sdl +sound +ssl static-libs +svg +system-lz4 systemd
+	tga tgv tiff tslib unwind v4l vlc vnc wayland webp xcf xim xine xpm
+	xpresent zeroconf"
+
+REQUIRED_USE="
+	?? ( elogind systemd )
+	?? ( gles2 opengl )
+	^^ ( lua luajit )
+	ssl
+	gles2? ( || ( wayland X ) )
+	pulseaudio? ( sound )
+	wayland? ( gles2 !opengl )
+	xim? ( X )
+	xpresent? ( X )
+"
+
+# Requires everything to be enabled unconditionally.
+RESTRICT="test"
+
+RDEPEND="
+	dev-libs/check
+	net-misc/curl
+	media-libs/giflib:=
+	media-libs/libpng:0=
+	sys-apps/dbus
+	sys-libs/zlib
+	virtual/jpeg:0=
+	X? (
+		media-libs/freetype
+		x11-libs/libX11
+		x11-libs/libXcomposite
+		x11-libs/libXcursor
+		x11-libs/libXdamage
+		x11-libs/libXdmcp
+		x11-libs/libXext
+		x11-libs/libXfixes
+		x11-libs/libXi
+		x11-libs/libXinerama
+		x11-libs/libXrandr
+		x11-libs/libXrender
+		x11-libs/libXtst
+		x11-libs/libXScrnSaver
+		wayland? ( x11-libs/libxkbcommon[X] )
+	)
+	connman? ( net-misc/connman )
+	drm? (
+		dev-libs/libinput
+		dev-libs/wayland
+		media-libs/mesa[gbm]
+		x11-libs/libdrm
+		x11-libs/libxkbcommon
+	)
+	elogind? (
+		sys-auth/elogind
+		virtual/libudev
+	)
+	fontconfig? ( media-libs/fontconfig )
+	fribidi? ( dev-libs/fribidi )
+	gles2? (
+		media-libs/mesa[egl,gles2]
+		virtual/opengl
+	)
+	glib? ( dev-libs/glib:2 )
+	gstreamer? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	hyphen? ( dev-libs/hyphen )
+	ibus? ( app-i18n/ibus )
+	jpeg2k? ( media-libs/openjpeg:= )
+	json? ( >=media-libs/rlottie-0.0.1_pre20191101 )
+	lua? ( dev-lang/lua:* )
+	luajit? ( dev-lang/luajit:* )
+	mono? ( dev-lang/mono )
+	opengl? ( virtual/opengl )
+	pdf? ( app-text/poppler:=[cxx] )
+	physics? ( sci-physics/bullet:= )
+	postscript? ( app-text/libspectre )
+	pulseaudio? ( media-sound/pulseaudio )
+	raw? ( media-libs/libraw:= )
+	scim? ( app-i18n/scim )
+	sdl? ( media-libs/libsdl2 )
+	sound? ( media-libs/libsndfile )
+	ssl? (
+		gnutls? ( net-libs/gnutls:= )
+		!gnutls? (
+			!libressl? ( dev-libs/openssl:0= )
+			libressl? ( dev-libs/libressl:= )
+		)
+	)
+	svg? ( gnome-base/librsvg )
+	system-lz4? ( app-arch/lz4 )
+	systemd? ( sys-apps/systemd:= )
+	tiff? ( media-libs/tiff:0= )
+	tslib? ( x11-libs/tslib:= )
+	unwind? ( sys-libs/libunwind )
+	v4l? ( media-libs/libv4l )
+	vlc? ( media-video/vlc )
+	vnc? ( net-libs/libvncserver )
+	wayland? (
+		dev-libs/wayland
+		media-libs/mesa[gles2,wayland]
+		x11-libs/libxkbcommon
+	)
+	webp? ( media-libs/libwebp:= )
+	xine? ( media-libs/xine-lib )
+	xpm? ( x11-libs/libXpm )
+	xpresent? ( x11-libs/libXpresent )
+	zeroconf? ( net-dns/avahi )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	nls? ( sys-devel/gettext )"
+
+src_configure() {
+	local emesonargs=(
+		--buildtype=release
+
+		-D buffer=false
+		-D cocoa=false
+		-D drm-deprecated=false
+		-D g-mainloop=false
+		-D install-eo-files=false
+		-D mono-beta=false
+		-D pixman=false
+		-D wl-deprecated=false
+		-D xgesture=false
+
+		-D edje-sound-and-video=true
+		-D eeze=true
+		-D libmount=true
+		-D native-arch-optimization=true
+		-D xinput2=true
+		-D xinput22=true
+
+		$(meson_use X x11)
+		$(meson_use debug debug-threads)
+		$(meson_use drm)
+		$(meson_use elogind)
+		$(meson_use examples build-examples)
+		$(meson_use fbcon fb)
+		$(meson_use fontconfig)
+		$(meson_use fribidi)
+		$(meson_use glib)
+		$(meson_use gstreamer)
+		$(meson_use harfbuzz)
+		$(meson_use hyphen)
+		$(meson_use luajit elua)
+		$(meson_use nls)
+		$(meson_use physics)
+		$(meson_use pulseaudio)
+		$(meson_use sdl)
+		$(meson_use sound audio)
+		$(meson_use systemd)
+		$(meson_use tslib)
+		$(meson_use v4l v4l2)
+		$(meson_use vnc vnc-server)
+		$(meson_use wayland wl)
+		$(meson_use xpresent)
+		$(meson_use zeroconf avahi)
+
+		$(meson_use !system-lz4 embedded-lz4)
+	)
+
+	if use opengl; then
+		emesonargs+=( -D opengl=full )
+	elif use gles2; then
+		emesonargs+=( -D opengl=es-egl )
+	else
+		emesonargs+=( -D opengl=none )
+	fi
+
+	if use gnutls; then
+		emesonargs+=( -D crypto=gnutls )
+	else
+		emesonargs+=( -D crypto=openssl )
+	fi
+
+	if use connman; then
+		emesonargs+=( -D network-backend=connman )
+	else
+		emesonargs+=( -D network-backend=none )
+	fi
+
+	if use static-libs; then
+		emesonargs+=( -D evas-modules=static )
+	else
+		emesonargs+=( -D evas-modules=shared )
+	fi
+
+	local disabledEvasLoaders=""
+	! use bmp && disabledEvasLoaders+="bmp,wbmp,"
+	! use dds && disabledEvasLoaders+="dds,"
+	! use eet && disabledEvasLoaders+="eet,"
+	! use gstreamer && disabledEvasLoaders+="gst,"
+	! use ico && disabledEvasLoaders+="ico,"
+	! use jpeg2k && disabledEvasLoaders+="jp2k,"
+	! use json && disabledEvasLoaders+="json,"
+	! use pdf && disabledEvasLoaders+="pdf,"
+	! use pmaps && disabledEvasLoaders+="pmaps,"
+	! use postscript && disabledEvasLoaders+="ps,"
+	! use psd && disabledEvasLoaders+="psd,"
+	! use raw && disabledEvasLoaders+="raw,"
+	! use svg && disabledEvasLoaders+="rsvg,svg,"
+	! use tga && disabledEvasLoaders+="tga,"
+	! use tgv && disabledEvasLoaders+="tgv,"
+	! use tiff && disabledEvasLoaders+="tiff,"
+	! use webp && disabledEvasLoaders+="webp,"
+	! use xcf && disabledEvasLoaders+="xcf,"
+	! use xpm && disabledEvasLoaders+="xpm,"
+	[[ ! -z "$disabledEvasLoaders" ]] && disabledEvasLoaders=${disabledEvasLoaders::-1}
+	emesonargs+=( -D evas-loaders-disabler="${disabledEvasLoaders}" )
+
+	local disabledImfLoaders=""
+	! use ibus && disabledImfLoaders+="ibus,"
+	! use scim && disabledImfLoaders+="scim,"
+	! use xim && disabledImfLoaders+="xim,"
+	[[ ! -z "$disabledImfLoaders" ]] && disabledImfLoaders=${disabledImfLoaders::-1}
+	emesonargs+=( -D ecore-imf-loaders-disabler="${disabledImfLoaders}" )
+
+	local disabledEmotionLoaders="gstreamer,"
+	! use gstreamer && disabledEmotionLoaders+="gstreamer1,"
+	! use vlc && disabledEmotionLoaders+="libvlc,"
+	! use xine && disabledEmotionLoaders+="xine,"
+	disabledEmotionLoaders=${disabledEmotionLoaders::-1}
+	emesonargs+=( -D emotion-loaders-disabler="${disabledEmotionLoaders}" )
+
+	local disabledGenericEmotionLoaders=""
+	! use vlc && disabledGenericEmotionLoaders+="vlc"
+	emesonargs+=( -D emotion-generic-loaders-disabler="${disabledGenericEmotionLoaders}" )
+
+	local bindingsList="cxx,"
+	use luajit && bindingsList+="luajit,"
+	use mono && bindingsList+="mono,"
+	[[ ! -z "$bindingsList" ]] && bindingsList=${bindingsList::-1}
+	emesonargs+=( -D bindings="${bindingsList}" )
+
+	local luaChoice=""
+	if use luajit; then
+		luaChoice+="luajit"
+	else
+		luaChoice+="lua"
+	fi
+	emesonargs+=( -D lua-interpreter="${luaChoice}" )
+
+	meson_src_configure
+}
+
+src_compile() {
+	meson_src_compile
+
+	if use doc; then
+		cd doc/ || die "Failed to switch into doc/ dir."
+		doxygen . || die "Doxygen failed to run."
+	fi
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( "${S}"/doc/html/. )
+	meson_src_install
+
+	if use examples; then
+		dodoc -r "${BUILD_DIR}"/src/examples/
+	fi
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+	xdg_mimeinfo_database_update
+}