[gentoo-commits] repo/gentoo:master commit in: games-util/pyfa/

["Joonas Niilola" <juippis@gentoo.org>]

commit:     ec0981a2772f9677cdf81eb8dd918354e429dcca
Author:     Andreas Zuber <a.zuber <AT> gmx <DOT> ch>
AuthorDate: Sat May 25 00:33:38 2019 +0000
Commit:     Joonas Niilola <juippis <AT> gentoo <DOT> org>
CommitDate: Fri Nov  1 06:06:15 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ec0981a2

games-util/pyfa: fix live ebuild

Closes: https://bugs.gentoo.org/673820
Package-Manager: Portage-2.3.66, Repoman-2.3.11
Signed-off-by: Andreas Zuber <a.zuber <AT> gmx.ch>
Closes: https://github.com/gentoo/gentoo/pull/12102
Signed-off-by: Joonas Niilola <juippis <AT> gentoo.org>

 games-util/pyfa/pyfa-9999.ebuild | 76 ++++++++++++++++++++--------------------
 1 file changed, 38 insertions(+), 38 deletions(-)

diff --git a/games-util/pyfa/pyfa-9999.ebuild b/games-util/pyfa/pyfa-9999.ebuild
index 32200ccbee1..2f7b3917e18 100644
--- a/games-util/pyfa/pyfa-9999.ebuild
+++ b/games-util/pyfa/pyfa-9999.ebuild
@@ -1,11 +1,11 @@
-# Copyright 1999-2018 Gentoo Foundation
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI="6"
-PYTHON_COMPAT=( python2_7 )
+EAPI="7"
+PYTHON_COMPAT=( python3_6 )
 PYTHON_REQ_USE="sqlite,threads"
 
-inherit desktop eutils gnome2-utils python-r1
+inherit desktop eutils python-single-r1 xdg-utils
 
 DESCRIPTION="Python Fitting Assistant - a ship fitting application for EVE Online"
 HOMEPAGE="https://github.com/pyfa-org/Pyfa"
@@ -16,64 +16,64 @@ SLOT="0"
 if [[ ${PV} = 9999 ]]; then
 	EGIT_REPO_URI="https://github.com/pyfa-org/Pyfa.git"
 	inherit git-r3
-	KEYWORDS=""
 else
 	SRC_URI="https://github.com/pyfa-org/Pyfa/archive/v${PV}.tar.gz -> ${P}.tar.gz"
 	KEYWORDS="~amd64 ~x86"
+	S=${WORKDIR}/Pyfa-${PV}
 fi
 IUSE="+graph"
 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
 
-RDEPEND="
+DEPEND="
+	>=dev-python/cryptography-2.3[${PYTHON_USEDEP}]
 	>=dev-python/logbook-1.0.0[${PYTHON_USEDEP}]
+	>=dev-python/pyyaml-5.1[${PYTHON_USEDEP}]
+	>=dev-python/sqlalchemy-1.3.0[${PYTHON_USEDEP}]
+	>=dev-python/wxpython-4.0.4[webkit,${PYTHON_USEDEP}]"
+RDEPEND="${DEPEND}
+	>=dev-python/beautifulsoup-4.6.0[${PYTHON_USEDEP}]
+	>=dev-python/markdown2-2.3.0[${PYTHON_USEDEP}]
+	>=dev-python/packaging-16.8[${PYTHON_USEDEP}]
 	dev-python/python-dateutil[${PYTHON_USEDEP}]
-	dev-python/requests[${PYTHON_USEDEP}]
-	>=dev-python/sqlalchemy-1.0.5[${PYTHON_USEDEP}]
-	dev-python/wxpython:3.0[${PYTHON_USEDEP}]
+	>=dev-python/requests-2.0.0[${PYTHON_USEDEP}]
+	>=dev-python/roman-2.0.0[${PYTHON_USEDEP}]
 	graph? (
-		dev-python/matplotlib[wxwidgets,${PYTHON_USEDEP}]
+		>=dev-python/matplotlib-2.0.0[wxwidgets,${PYTHON_USEDEP}]
 		dev-python/numpy[${PYTHON_USEDEP}] )
 	${PYTHON_DEPS}"
-DEPEND="app-arch/zip"
+BDEPEND="app-arch/zip"
 
-[[ ${PV} = 9999 ]] || S=${WORKDIR}/Pyfa-${PV}
+PATCHES=(
+	# fix import path in the main script for systemwide installation
+	"${FILESDIR}/${PN}-2.9.3-import-pyfa.patch"
+	)
 
 src_prepare() {
 	# get rid of CRLF line endings introduced in 1.1.10 so patches work
-	edos2unix config.py pyfa.py gui/bitmapLoader.py service/settings.py
-
-	# load gameDB and images from separate staticdata directory
-	eapply "${FILESDIR}/${PN}-1.33.1-staticdata.patch"
+	edos2unix config.py pyfa.py gui/bitmap_loader.py service/settings.py
 
-	# fix import path in the main script for systemwide installation
-	eapply "${FILESDIR}/${PN}-1.33.1-import-pyfa.patch"
-
-	eapply_user
+	default
 
 	# make python recognize pyfa as a package
 	touch __init__.py || die
 
-	pyfa_make_configforced() {
-		mkdir -p "${BUILD_DIR}" || die
-		sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
-			-e "s:%%EPREFIX%%:${EPREFIX}:" \
-			"${FILESDIR}/configforced-1.15.1.py" > "${BUILD_DIR}/configforced.py" || die
-		sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
-			pyfa.py > "${BUILD_DIR}/pyfa" || die
-	}
-	python_foreach_impl pyfa_make_configforced
+	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
+		-e "s:%%EPREFIX%%:${EPREFIX}:" \
+		"${FILESDIR}/configforced-1.15.1.py" > configforced.py || die
+	sed -e "s:%%SITEDIR%%:$(python_get_sitedir):" \
+		pyfa.py > pyfa || die
 }
 
 src_install() {
-	pyfa_py_install() {
-		python_moduleinto ${PN}
-		python_domodule eos gui service utils config*.py __init__.py
-		python_domodule "${BUILD_DIR}/configforced.py"
-		python_doscript "${BUILD_DIR}/pyfa"
-	}
-	python_foreach_impl pyfa_py_install
+	python_moduleinto ${PN}
+	python_domodule eos gui service utils graphs
+	python_domodule config*.py __init__.py version.yml configforced.py db_update.py
+	python_doscript pyfa
 
 	insinto /usr/share/${PN}
+
+	einfo "Creating database ..."
+	python ./db_update.py || die
 	doins eve.db
 
 	einfo "Compressing images ..."
@@ -89,9 +89,9 @@ src_install() {
 }
 
 pkg_postinst() {
-	gnome2_icon_cache_update
+	xdg_icon_cache_update
 }
 
 pkg_postrm() {
-	gnome2_icon_cache_update
+	xdg_icon_cache_update
 }