[gentoo-commits] repo/gentoo:master commit in: sys-apps/fwupd/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     36ce6969cabb9d70d94e47c91ed41c9d1fd5eac1
Author:     Bernardo Meurer <meurerbernardo <AT> gmail <DOT> com>
AuthorDate: Sun Oct 13 03:00:57 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Wed Oct 16 13:09:21 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=36ce6969

sys-apps/fwupd: add 1.3.2

Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Bernardo Meurer <bernardo <AT> standard.ai>
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 sys-apps/fwupd/Manifest           |   1 +
 sys-apps/fwupd/fwupd-1.3.2.ebuild | 154 ++++++++++++++++++++++++++++++++++++++
 sys-apps/fwupd/metadata.xml       |   6 +-
 3 files changed, 159 insertions(+), 2 deletions(-)

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index baf4b77e5e5..0e0342cde6e 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,3 +1,4 @@
 DIST fwupd-1.2.10.tar.gz 1943920 BLAKE2B 5aec740c777d8749901ee35915f3510998b7477d2964ea4adc7079d12702e971a4eb0c4eef1b5c0fec0b34ba5e3fc82c25d7df7800b5bc0aa3d10229370a958e SHA512 4d311d2ed5fbe06e1a8fb22d77e67823f58debd3465dc973945c98746ae00f137d15a0e46e93fa3529b4d8a157558339295f82cacdab9d79c83514300b3b6a22
 DIST fwupd-1.2.8.tar.gz 1911999 BLAKE2B 61a24ce24f778b96f7ad23496890f7a1d20c09e6bbd707f29d154992668d5c0a25cfd31b5d0d11519740e086c098cbdfd440fe9f5cab4dde0ac43fe6b438e911 SHA512 d603f9f4e5a4c0fc6abb0b75f7d884eff47fb8a16285aa545f7140fe98ce781d127ff3769f9c206bb3bfd084bbc5bf6abf9424f70e727ff79162416fe7881154
 DIST fwupd-1.2.9.tar.gz 1938008 BLAKE2B 6a16c8e3a2c94dfbe9485d3ed57f3908fa2d7bcd95ac122d4b08e9a869706c01483132015f06cfa3076c861fec903740bed83b7ef763ac9b20147673a25a54a1 SHA512 942c6bad822dc65846d1984850798bec677b6a312100c6f5971fc9d5906c182267182ef29e0834bbd2b83fe72b11c3b6e50855d90388d2bf85e8a3b95d0a5a68
+DIST fwupd-1.3.2.tar.gz 2100817 BLAKE2B 49441603ac0934a10b730b82b4f86cbdac03c3ab9de6051af6ca0c5f3d610cda1a619b7f0af9de61de3bd926175cf37523f47cf3fe2743ae54e5327d5ae8a518 SHA512 5b302d0ba1eb10f3ec440ed1a5ad25b5a9398c7601dc2e058d0df57e16a2e3b65ab3b7e93a07300e3db21789909fc2a72feebab0271fa0669dd792f290506c1b

diff --git a/sys-apps/fwupd/fwupd-1.3.2.ebuild b/sys-apps/fwupd/fwupd-1.3.2.ebuild
new file mode 100644
index 00000000000..1f68b54f836
--- /dev/null
+++ b/sys-apps/fwupd/fwupd-1.3.2.ebuild
@@ -0,0 +1,154 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit linux-info meson python-single-r1 vala xdg
+
+DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
+HOMEPAGE="https://fwupd.org"
+SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~x86"
+IUSE="agent amt consolekit dell gtk-doc elogind +gpg introspection +man nvme pkcs7 redfish synaptics systemd test thunderbolt uefi"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}
+	^^ ( consolekit elogind systemd )
+	dell? ( uefi )
+"
+RESTRICT="!test? ( test )"
+
+BDEPEND="$(vala_depend)
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	introspection? ( dev-libs/gobject-introspection )
+	man? (
+		app-text/docbook-sgml-utils
+		sys-apps/help2man
+	)
+	test? (
+		thunderbolt? ( dev-util/umockdev )
+		net-libs/gnutls[tools]
+	)
+"
+DEPEND="${PYTHON_DEPS}
+	>=app-arch/gcab-1.0
+	app-arch/libarchive:=
+	dev-db/sqlite
+	>=dev-libs/glib-2.45.8:2
+	dev-libs/json-glib
+	dev-libs/libgpg-error
+	>=dev-libs/libgusb-0.2.9[introspection]
+	>=dev-libs/libxmlb-0.1.7
+	dev-python/pillow[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
+	>=net-libs/libsoup-2.51.92:2.4[introspection]
+	>=sys-auth/polkit-0.103
+	virtual/libelf:0=
+	virtual/libgudev:=
+	virtual/udev
+	consolekit? ( >=sys-auth/consolekit-1.0.0 )
+	dell? (
+		sys-libs/efivar
+		>=sys-libs/libsmbios-2.4.0
+	)
+	elogind? ( sys-auth/elogind )
+	gpg? (
+		app-crypt/gpgme
+		dev-libs/libgpg-error
+	)
+	nvme? ( sys-libs/efivar )
+	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
+	redfish? ( sys-libs/efivar )
+	systemd? ( >=sys-apps/systemd-211 )
+	thunderbolt? (
+		sys-apps/thunderbolt-software-user-space
+	)
+	uefi? (
+		app-crypt/tpm2-tss
+		media-libs/fontconfig
+		media-libs/freetype
+		sys-boot/gnu-efi
+		sys-boot/efibootmgr
+		>=sys-libs/efivar-33
+		x11-libs/cairo
+	)
+"
+RDEPEND="
+	${DEPEND}
+	sys-apps/dbus
+"
+
+pkg_setup() {
+	if use nvme; then
+		kernel_is -ge 4 4 || die "NVMe support requires kernel >= 4.4"
+	fi
+}
+
+src_prepare() {
+	default
+	sed -e "s/'--create'/'--absolute-name', '--create'/" \
+		-i data/tests/builder/meson.build || die
+	sed -e "/'-Werror',/d" \
+		-i plugins/uefi/efi/meson.build || die
+	# c.f. https://github.com/fwupd/fwupd/issues/1414
+	sed -e "/test('thunderbolt-self-test', e, env: test_env, timeout : 120)/d" \
+		-i plugins/thunderbolt/meson.build || die
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		--localstatedir "${EPREFIX}"/var
+		$(meson_use agent)
+		$(meson_use amt plugin_amt)
+		$(meson_use consolekit)
+		$(meson_use dell plugin_dell)
+		$(meson_use elogind)
+		$(meson_use gpg)
+		$(meson_use gtk-doc gtkdoc)
+		$(meson_use man)
+		$(meson_use nvme plugin_nvme)
+		$(meson_use pkcs7)
+		$(meson_use redfish plugin_redfish)
+		$(meson_use synaptics plugin_synaptics)
+		$(meson_use systemd)
+		$(meson_use test tests)
+		$(meson_use thunderbolt plugin_thunderbolt)
+		$(meson_use uefi plugin_uefi)
+		# Requires libflashrom which our sys-apps/flashrom
+		# package does not provide
+		-Dplugin_flashrom="false"
+		# Dependencies are not available (yet?)
+		-Dplugin_modem_manager="false"
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	sed "s@%SEAT_MANAGER%@$(usex elogind elogind consolekit)@" \
+		"${FILESDIR}"/${PN}-r1 \
+		> "${T}"/${PN} || die
+	doinitd "${T}"/${PN}
+
+	if ! use systemd ; then
+		# Don't timeout when fwupd is running (#673140)
+		sed '/^IdleTimeout=/s@=[[:digit:]]\+@=0@' \
+			-i "${ED}"/etc/${PN}/daemon.conf || die
+	fi
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	elog "In case you are using openrc as init system"
+	elog "and you're upgrading from <fwupd-1.1.0, you"
+	elog "need to start the fwupd daemon via the openrc"
+	elog "init script that comes with this package."
+}

diff --git a/sys-apps/fwupd/metadata.xml b/sys-apps/fwupd/metadata.xml
index d749d5ca31b..2ee7155081a 100644
--- a/sys-apps/fwupd/metadata.xml
+++ b/sys-apps/fwupd/metadata.xml
@@ -7,15 +7,17 @@
   </maintainer>
   <use>
     <flag name="agent">Enable update notification agent</flag>
+    <flag name="amt">Build and install Intel AMT plugin</flag>
     <flag name="colorhug">Enable ColorHug support through<pkg>x11-misc/colord</pkg> package</flag>
     <flag name="consolekit">Use <pkg>sys-auth/consolekit</pkg> for session tracking</flag>
     <flag name="dell">Enable Dell-specific support.</flag>
     <flag name="gpg">Enable GPG support.</flag>
     <flag name="man">Build and install man pages</flag>
-    <flag name="nvme">Build and install nvme plugin</flag>
+    <flag name="nvme">Build and install NVMe plugin</flag>
     <flag name="pkcs7">Enable PKCS7 verification support via <pkg>net-libs/gnutls</pkg></flag>
     <flag name="redfish">Install redfish plugin</flag>
-    <flag name="thunderbolt">Install thunderbolt plugin</flag>
+    <flag name="synaptics">Install synaptics plugin</flag>
+    <flag name="thunderbolt">Install Thunderbolt plugin</flag>
     <flag name="uefi">Enable UEFI support</flag>
   </use>
   <upstream>