[gentoo-commits] repo/gentoo:master commit in: games-board/gnome-chess/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     2a00bc8e0a151382af296a5f538cc44a8e5cc2fe
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Oct 13 18:07:22 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Oct 13 18:18:47 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=2a00bc8e

games-board/gnome-chess: bump to 3.34.0

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 games-board/gnome-chess/Manifest                  |  1 +
 games-board/gnome-chess/gnome-chess-3.34.0.ebuild | 55 +++++++++++++++++++++++
 2 files changed, 56 insertions(+)

diff --git a/games-board/gnome-chess/Manifest b/games-board/gnome-chess/Manifest
index 25aad69b9de..db2b1dbd514 100644
--- a/games-board/gnome-chess/Manifest
+++ b/games-board/gnome-chess/Manifest
@@ -1 +1,2 @@
 DIST gnome-chess-3.30.1.tar.xz 1699668 BLAKE2B 5cb445248f3e223354f5145ee6e652b05d2ced44cbe63705fd54514d7848b5932b3aced35e3e6b72944f0e1e2c2b73ff8b9ad2b0c38fa0e90de5e59bf1da36e5 SHA512 ddf1b62b189adb01e9874606fa45b77b00bb5ca52609db60c58b6c0bca5340786f37a8ef813bb82213c8f7335117d2b896420826cae131db13e77d72e8ad5804
+DIST gnome-chess-3.34.0.tar.xz 648464 BLAKE2B c06474fbdaeb9dfc26fbadaa6f5dc83179cdc6d09b8007b2dfcd88a4af4a6113913cffa8f00ada7a788585d723c5917f7ad7944bf466411119e7979545f40f29 SHA512 dcd4c2cfb0ebb5d3481bb6f722ac847cb8976e31352286a245457a62291445f50ad86ce26a37c222112801dc807bb567ed4d71d2d6ccb1628c2cab0767445012

diff --git a/games-board/gnome-chess/gnome-chess-3.34.0.ebuild b/games-board/gnome-chess/gnome-chess-3.34.0.ebuild
new file mode 100644
index 00000000000..d8a04a7cdbf
--- /dev/null
+++ b/games-board/gnome-chess/gnome-chess-3.34.0.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+VALA_MIN_API_VERSION="0.40"
+
+inherit gnome.org gnome2-utils meson readme.gentoo-r1 vala xdg
+
+DESCRIPTION="Play the classic two-player boardgame of chess"
+HOMEPAGE="https://wiki.gnome.org/Apps/Chess"
+
+LICENSE="GPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE=""
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	>=x11-libs/gtk+-3.20.0:3
+	>=gnome-base/librsvg-2.32.0:2
+"
+DEPEND="${RDEPEND}
+	gnome-base/librsvg:2[vala]
+"
+BDEPEND="
+	$(vala_depend)
+	dev-util/itstool
+	dev-libs/appstream-glib
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+DOC_CONTENTS="To be able to play against a computer you will need
+to install a chess engine package, for example games-board/gnuchess"
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+	readme.gentoo_print_elog
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}