[gentoo-commits] repo/gentoo:master commit in: dev-util/lldb/

["Michał Górny" <mgorny@gentoo.org>]

commit:     cb6403762dfad45f6e4e10d8b0be0aecf565b340
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Fri Sep 20 09:33:29 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Fri Sep 20 22:11:56 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=cb640376

dev-util/lldb: Bump to 9.0.0

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-util/lldb/Manifest          |   2 +
 dev-util/lldb/lldb-9.0.0.ebuild | 112 ++++++++++++++++++++++++++++++++++++++++
 2 files changed, 114 insertions(+)

diff --git a/dev-util/lldb/Manifest b/dev-util/lldb/Manifest
index f6369dee292..8d90851ef1b 100644
--- a/dev-util/lldb/Manifest
+++ b/dev-util/lldb/Manifest
@@ -1,6 +1,8 @@
 DIST lldb-7.1.0.src.tar.xz 19384976 BLAKE2B a1d5afea255f06221516e21e80120cb35d870ec447aff774d8c610c889c8f28228c7c8e93eec160fc5424736666fcaac8ed42d9181373d266202c9f8aa4c3061 SHA512 773f79939c540f349f1c85d6b1d89fa312488c4c70f100f05cb6250f62e8d6a05832d57c02750439ede905fa69e1380a73ddde0d3ad2f99a0910acd1011559df
 DIST lldb-8.0.0.src.tar.xz 19602332 BLAKE2B 85a51b3ccae8fd0074b0f5b54e35d2eb020770246b13a0ec52a4647d30f23a6620ce410af7e49604947ff60f789ecab0bfeddfc3598642c9096cf3362d88b5bf SHA512 5192d6d6d1759db28569de929ba8db2a80283000f1bf8453d9cf172ac85574c8eacc13f9fe64ecabea0533bfc49c0f58ea8fb29b1f4d88c065d905d553f2e60c
 DIST lldb-8.0.1.src.tar.xz 19586288 BLAKE2B afb20a8303dcbdaf76ef1d78aa3165f87713f1c16121905d7a5f71e770ceafdff40d9d19e0a983d9290da2d4eb3acd0987d50607bea17efdb7dc0127d7f5cf8a SHA512 eb031985ad4d08226ec47a90fe32c1e6d070948971ca5235fd431cf7d5b7ea20f5d5131237bf83a6419773d18c339590bf9672e7b4f884304497e63c1030988f
+DIST lldb-9.0.0.src.tar.xz 9846624 BLAKE2B b6bf819c72686cba9e2b0e6a49206b90908bfe7c834e1e50e15be1c53dc8003cc6ed8ad4c83eef662b775997395bdb7e70835f94eca3768288fcbfeece68356b SHA512 86455d9d9866cde75e8d9bee7ddeb2680088dbc671e7d0c7bfff4c68ac963bc293bcaaf1a595db2b5529ddeee0dd0057ece37c90ee4ea194ac5e3fdb3122de01
 DIST llvm-7.1.0.src.tar.xz 28313784 BLAKE2B b78d9a7fc5ef6e352e77d339e5c4eef5ccedf67c05e7abd949e72619aa8a5ed65e7e5e2008354be8e7916d75581719b99f34227838fcc86c5d0080913c2fb22c SHA512 a7dbd5693d1f2dae6b6e52893a100f9349cbfcfb25c5fdcad46364acbff0dbd3573f8fbc026c68eb9fd56335198aa94b866cc3dd7ea0cbd2cbfb5f8fe3444a7a
 DIST llvm-8.0.0.src.tar.xz 30503732 BLAKE2B d89bdeb0ec7d885e49cfe5ae025da84f00502d409710c0807a3cdd58dbd47c50cf6a635593569483150f7f2ecb0de0310bd6785cb7625219bf9f6224a0d68e1c SHA512 1602343b451b964f5d8c2d6b0654d89384c80d45883498c5f0e2f4196168dd4a1ed2a4dadb752076020243df42ffe46cb31d82ffc145d8e5874163cbb9686a1f
 DIST llvm-8.0.1.src.tar.xz 30477608 BLAKE2B 4319c837b36111401e3b0f9659b8d875c89463bcc7816df1aefe1e3ff989860bbaa92504718f8e15416cfd9f3491c13777cd5cb661877b237b342b0e515b93f5 SHA512 82e120be5cabdfd5111aebbea68a663fe229c8861d73802d6ab09a3bf48f60de333e07e61f8fb61beaa14ac2bea24fcd74fa6f761acaf62469f536b79fcb1e16
+DIST llvm-9.0.0.src.tar.xz 32994768 BLAKE2B 7f09bff9bcada95ab9c920c78aef92b57e665d9188bab39c734084ceb03a801c942fed48ea77fabeeb6110c648cb69363c659a6ce93ebf67dbba5c187219b13b SHA512 1bb3341e1d231559b948f1505b33c2e2e03989f9b8bbfef0e0cdaff5ac43f85574c9ec5ac53399b914f497d6899425d861411024e8d7e1d1a338c1c6951ac658

diff --git a/dev-util/lldb/lldb-9.0.0.ebuild b/dev-util/lldb/lldb-9.0.0.ebuild
new file mode 100644
index 00000000000..2657b0d4abf
--- /dev/null
+++ b/dev-util/lldb/lldb-9.0.0.ebuild
@@ -0,0 +1,112 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+: ${CMAKE_MAKEFILE_GENERATOR:=ninja}
+# (needed due to CMAKE_BUILD_TYPE != Gentoo)
+CMAKE_MIN_VERSION=3.7.0-r1
+PYTHON_COMPAT=( python{2_7,3_{5,6,7}} )
+
+inherit cmake-utils llvm multiprocessing python-single-r1 \
+	toolchain-funcs
+
+MY_P=${P/_/}.src
+LLVM_P=llvm-${PV/_/}.src
+
+DESCRIPTION="The LLVM debugger"
+HOMEPAGE="https://llvm.org/"
+SRC_URI="https://releases.llvm.org/${PV}/${MY_P}.tar.xz
+	test? ( https://releases.llvm.org/${PV}/${LLVM_P}.tar.xz )"
+
+LICENSE="Apache-2.0-with-LLVM-exceptions UoI-NCSA"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+IUSE="libedit ncurses +python test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	libedit? ( dev-libs/libedit:0= )
+	ncurses? ( >=sys-libs/ncurses-5.9-r3:0= )
+	python? ( dev-python/six[${PYTHON_USEDEP}]
+		${PYTHON_DEPS} )
+	~sys-devel/clang-${PV}[xml]
+	~sys-devel/llvm-${PV}
+	!<sys-devel/llvm-4.0"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	python? ( >=dev-lang/swig-3.0.11 )
+	test? (
+		~dev-python/lit-${PV}[${PYTHON_USEDEP}]
+		sys-devel/lld )
+	${PYTHON_DEPS}"
+
+REQUIRED_USE=${PYTHON_REQUIRED_USE}
+
+S=${WORKDIR}/${MY_P}
+
+# least intrusive of all
+CMAKE_BUILD_TYPE=RelWithDebInfo
+
+pkg_setup() {
+	LLVM_MAX_SLOT=${PV%%.*} llvm_pkg_setup
+	python-single-r1_pkg_setup
+}
+
+src_unpack() {
+	einfo "Unpacking ${MY_P}.tar.xz ..."
+	tar -xf "${DISTDIR}/${MY_P}.tar.xz" || die
+
+	if use test; then
+		einfo "Unpacking parts of ${LLVM_P}.tar.xz ..."
+		tar -xf "${DISTDIR}/${LLVM_P}.tar.xz" \
+			"${LLVM_P}"/{lib/Testing/Support,utils/unittest} || die
+		mv "${LLVM_P}" llvm || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DLLDB_DISABLE_CURSES=$(usex !ncurses)
+		-DLLDB_DISABLE_LIBEDIT=$(usex !libedit)
+		-DLLDB_DISABLE_PYTHON=$(usex !python)
+		-DLLDB_USE_SYSTEM_SIX=1
+		-DLLVM_ENABLE_TERMINFO=$(usex ncurses)
+
+		-DLLDB_INCLUDE_TESTS=$(usex test)
+
+		# TODO: fix upstream to detect this properly
+		-DHAVE_LIBDL=ON
+		-DHAVE_LIBPTHREAD=ON
+
+		# normally we'd have to set LLVM_ENABLE_TERMINFO, HAVE_TERMINFO
+		# and TERMINFO_LIBS... so just force FindCurses.cmake to use
+		# ncurses with complete library set (including autodetection
+		# of -ltinfo)
+		-DCURSES_NEED_NCURSES=ON
+	)
+	use test && mycmakeargs+=(
+		-DLLVM_BUILD_TESTS=$(usex test)
+		# compilers for lit tests
+		-DLLDB_TEST_C_COMPILER="$(type -P clang)"
+		-DLLDB_TEST_CXX_COMPILER="$(type -P clang++)"
+
+		-DLLVM_MAIN_SRC_DIR="${WORKDIR}/llvm"
+		-DLLVM_EXTERNAL_LIT="${EPREFIX}/usr/bin/lit"
+		-DLLVM_LIT_ARGS="-vv;-j;${LIT_JOBS:-$(makeopts_jobs "${MAKEOPTS}" "$(get_nproc)")}"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_test() {
+	local -x LIT_PRESERVES_TMP=1
+	cmake-utils_src_make check-lldb-lit
+	use python && cmake-utils_src_make check-lldb
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use python && python_optimize
+}