[gentoo-commits] repo/gentoo:master commit in: gnome-extra/gnome-color-manager/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     6a13a154d0e499577a2622dfae4e33c1bb42b631
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Sep 18 05:59:44 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Sep 18 20:40:21 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=6a13a154

gnome-extra/gnome-color-manager: bump to 3.32.0

Package-Manager: Portage-2.3.69, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-extra/gnome-color-manager/Manifest           |  1 +
 .../gnome-color-manager-3.32.0.ebuild              | 80 ++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/gnome-extra/gnome-color-manager/Manifest b/gnome-extra/gnome-color-manager/Manifest
index 183c5f24b11..eed6ae03ccb 100644
--- a/gnome-extra/gnome-color-manager/Manifest
+++ b/gnome-extra/gnome-color-manager/Manifest
@@ -1 +1,2 @@
 DIST gnome-color-manager-3.30.0.tar.xz 2611088 BLAKE2B 2bbed2184d2c7afa9c4c4cd88470df3350f7deb2d776863dcd18ad6253538f1daee5f6397c598af8bdf1ce720980ede9280891139a9366edaffde3672d64b47a SHA512 ec28179f1089317b5a1920757e81b6126ab42a087831a92cd47174ddfbe6093fa868747c2a1d1d70c23f3fb87bc1b839627160407bf85c936ab0a3b125932ccc
+DIST gnome-color-manager-3.32.0.tar.xz 2602104 BLAKE2B 6219c3b7dd31ba49c671ef1f330d8ce561b7d8716a5cf5ef393dcf827c6bbc4e82b95c082e9297a27be7652d958a92c397fbafa8bd68f2c48b32533a3fe14483 SHA512 e5b0c6a39f9202fde79af1e966be65ef3d770fe4de777a281398ee68feef6c57dee95a1fcba496512f163bf561528ece840480b3c8612b5c3af2b7f550335f38

diff --git a/gnome-extra/gnome-color-manager/gnome-color-manager-3.32.0.ebuild b/gnome-extra/gnome-color-manager/gnome-color-manager-3.32.0.ebuild
new file mode 100644
index 00000000000..49d9ce3beab
--- /dev/null
+++ b/gnome-extra/gnome-color-manager/gnome-color-manager-3.32.0.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit gnome.org meson virtualx xdg
+
+DESCRIPTION="GNOME color profile tools"
+HOMEPAGE="https://gitlab.gnome.org/GNOME/gnome-color-manager/"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="packagekit raw test"
+
+# Need gtk+-3.3.8 for https://bugzilla.gnome.org/show_bug.cgi?id=673331
+# vte could be made optional
+RDEPEND="
+	>=dev-libs/glib-2.31.10:2
+	>=media-libs/lcms-2.2:2
+	>=media-libs/libcanberra-0.10[gtk3]
+	media-libs/libexif
+	media-libs/tiff:0=
+
+	>=x11-libs/gtk+-3.3.8:3
+	>=x11-libs/vte-0.25.1:2.91
+	>=x11-misc/colord-1.3.1:0=
+	>=x11-libs/colord-gtk-0.1.20
+
+	packagekit? ( app-admin/packagekit-base )
+	raw? ( media-gfx/exiv2:0= )
+"
+# docbook-sgml-{utils,dtd:4.1} needed to generate man pages
+DEPEND="${RDEPEND}
+	app-text/docbook-sgml-dtd:4.1
+	app-text/docbook-sgml-utils
+	dev-libs/appstream-glib
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# https://bugzilla.gnome.org/show_bug.cgi?id=796428
+	"${FILESDIR}"/3.28-remove-unwvanted-check.patch
+)
+
+src_prepare() {
+	xdg_src_prepare
+
+	# Fix hard-coded package name
+	# https://gitlab.gnome.org/GNOME/gnome-color-manager/issues/3
+	sed 's:argyllcms:media-gfx/argyllcms:' -i src/gcm-utils.h || die
+}
+
+src_configure() {
+	# Always enable tests since they are check_PROGRAMS anyway
+	local emesonargs=(
+		$(meson_use raw exiv)
+		$(meson_use packagekit)
+		$(meson_use test tests)
+	)
+	meson_src_configure
+}
+
+src_test() {
+	virtx meson_src_test
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+
+	if ! has_version media-gfx/argyllcms ; then
+		elog "If you want to do display or scanner calibration, you will need to"
+		elog "install media-gfx/argyllcms"
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+}