[gentoo-commits] repo/gentoo:master commit in: dev-libs/libical/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     1c6e0593af245703205da5109eb46721cc0e542a
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Tue Sep 17 16:15:09 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Sep 18 18:13:22 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1c6e0593

dev-libs/libical: 3.0.6 version bump, add USE introspection,vala

Merge USE glib into introspection.

Bug: https://bugs.gentoo.org/689434
Closes: https://bugs.gentoo.org/694588
Package-Manager: Portage-2.3.76, Repoman-2.3.17
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 dev-libs/libical/Manifest             |  1 +
 dev-libs/libical/libical-3.0.6.ebuild | 94 +++++++++++++++++++++++++++++++++++
 2 files changed, 95 insertions(+)

diff --git a/dev-libs/libical/Manifest b/dev-libs/libical/Manifest
index d9c3d48177c..370e00b64ca 100644
--- a/dev-libs/libical/Manifest
+++ b/dev-libs/libical/Manifest
@@ -1 +1,2 @@
 DIST libical-3.0.5.tar.gz 881800 BLAKE2B 64f95950cc6f128c9ea475129e54d9c58b26d9866f8183762d34c996934a1b2bcc528c47442357a12fb6444831caa8f39772a6810d81f8c0b6596fd724f0de6c SHA512 9bf24b535864f66ea0b8d52d902d15fbfd20efbc480b5188ecd1b3d4aafdba063219763f99a8c30413964f7a024c7a902bade6bc40224bc59a438e672f65d656
+DIST libical-3.0.6.tar.gz 879939 BLAKE2B 365e16cd7011df7e9e8bcf011035aeeb904a511c5a0ff76cde5b559a7c56049646108d1c2b499cd044e2784aef7bb1370ee3dbf88c24b745a349a0ee7c312157 SHA512 d1a3397071c2989983893e3bbaeb088f7cb9a3639dca39709e9422c334dd1e9a869bba9292a250f83eb2a5b6727bd91b73c8e420bd1814422d97aff9fc6b26fc

diff --git a/dev-libs/libical/libical-3.0.6.ebuild b/dev-libs/libical/libical-3.0.6.ebuild
new file mode 100644
index 00000000000..04ea480f906
--- /dev/null
+++ b/dev-libs/libical/libical-3.0.6.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+inherit cmake-utils python-any-r1 vala
+
+DESCRIPTION="An implementation of basic iCAL protocols"
+HOMEPAGE="https://github.com/libical/libical"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${PV}/${P}.tar.gz"
+
+LICENSE="|| ( MPL-2.0 LGPL-2.1 )"
+SLOT="0/3"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
+IUSE="berkdb doc examples introspection static-libs test vala"
+REQUIRED_USE="vala? ( introspection )"
+
+BDEPEND="
+	dev-lang/perl
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen )
+	test? ( ${PYTHON_DEPS} )
+"
+DEPEND="
+	dev-libs/icu:=
+	berkdb? ( sys-libs/db:= )
+	introspection? (
+		dev-libs/glib:2
+		dev-libs/gobject-introspection:=
+		dev-libs/libxml2:2
+	)
+	vala? ( $(vala_depend) )
+"
+RDEPEND="${DEPEND}
+	sys-libs/timezone-data
+"
+
+DOCS=(
+	AUTHORS ReadMe.txt ReleaseNotes.txt TEST THANKS TODO
+	doc/{AddingOrModifyingComponents,UsingLibical}.txt
+)
+
+PATCHES=(
+	"${FILESDIR}/${PN}-3.0.4-tests.patch"
+	"${FILESDIR}/${PN}-3.0.5-pkgconfig-libdir.patch"
+)
+
+pkg_setup() {
+	use test && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	cmake-utils_src_prepare
+	use examples || cmake_comment_add_subdirectory examples
+	use vala && vala_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_find_package berkdb BDB)
+		-DICAL_BUILD_DOCS=$(usex doc)
+		-DICAL_GLIB=$(usex introspection)
+		-DGOBJECT_INTROSPECTION=$(usex introspection)
+		-DSHARED_ONLY=$(usex !static-libs)
+		-DLIBICAL_BUILD_TESTING=$(usex test)
+		-DICAL_GLIB_VAPI=$(usex vala)
+	)
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+	use doc && cmake-utils_src_compile docs
+}
+
+src_test() {
+	local myctestargs=(
+		-E "(icalrecurtest|icalrecurtest-r)" # bug 660282
+	)
+
+	cmake-utils_src_test
+}
+
+src_install() {
+	use doc && HTML_DOCS=( "${BUILD_DIR}"/apidocs/html/. )
+
+	cmake-utils_src_install
+
+	if use examples; then
+		rm examples/CMakeLists.txt || die
+		dodoc -r examples
+	fi
+}