[gentoo-commits] repo/gentoo:master commit in: app-misc/tracker/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     d7c9fff65908c39d11c49ade06d5b42b8f8bfd6a
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Wed Aug 28 12:44:52 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Wed Aug 28 12:48:27 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=d7c9fff6

app-misc/tracker: bump to 2.2.2

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 app-misc/tracker/Manifest             |  1 +
 app-misc/tracker/tracker-2.2.2.ebuild | 91 +++++++++++++++++++++++++++++++++++
 2 files changed, 92 insertions(+)

diff --git a/app-misc/tracker/Manifest b/app-misc/tracker/Manifest
index fc0292881c9..c7abcb9f105 100644
--- a/app-misc/tracker/Manifest
+++ b/app-misc/tracker/Manifest
@@ -1 +1,2 @@
 DIST tracker-2.1.8.tar.xz 2585924 BLAKE2B 8548f6a615c3357eb2f1a1656d81f50816cef2f59e23fe7bd2111eeade8b3e5c0a33abf1bc830a0baa9c1c1d74ee92d3e44da00cd6f65ab853ef04eb2f57a69e SHA512 447e519699bbb0c9802230629667a87ce39ec3f6bb9c605063319d5e6a019c95a76762fdc889b1a11280be08b8520f22f097f9c9779dcd7a6c7cf239b4da2696
+DIST tracker-2.2.2.tar.xz 2792104 BLAKE2B 654dd5a6e4d8ea8a47d209f747e0dd4e02b7f6c862c4dedd92edf271cf3645b2a7d3f956f6aba5bf104df9972bc287b49a40d77892cb9a65e40c1007f5e3ca6c SHA512 2c18c324d4d98fb62bbf21eac8f647bd34463cee4d9f71d411e22d695fc28cc0c5334e2d41517875a5741213d9405e768f3efae6a8a4a8e72d01563c335f47a7

diff --git a/app-misc/tracker/tracker-2.2.2.ebuild b/app-misc/tracker/tracker-2.2.2.ebuild
new file mode 100644
index 00000000000..70fd7b4efe8
--- /dev/null
+++ b/app-misc/tracker/tracker-2.2.2.ebuild
@@ -0,0 +1,91 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit bash-completion-r1 gnome.org linux-info meson python-any-r1 systemd vala xdg
+
+DESCRIPTION="A tagging metadata database, search tool and indexer"
+HOMEPAGE="https://wiki.gnome.org/Projects/Tracker"
+
+LICENSE="GPL-2+ LGPL-2.1+"
+SLOT="0/2.0"
+IUSE="gtk-doc +miners networkmanager stemmer"
+
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+#RESTRICT="!test? ( test )"
+
+PV_SERIES=$(ver_cut 1-2)
+
+# In 2.2.0 util-linux should only be necessary if glib is older than 2.52 at compile-time
+RDEPEND="
+	>=dev-libs/glib-2.46:2
+	>=sys-apps/dbus-1.3.2
+	>=dev-libs/gobject-introspection-1.54:=
+	>=dev-libs/icu-4.8.1.2:=
+	>=dev-libs/json-glib-1.0
+	>=net-libs/libsoup-2.40.1:2.4
+	>=dev-libs/libxml2-2.7
+	>=dev-db/sqlite-3.20.0
+	networkmanager? ( >=net-misc/networkmanager-0.8 )
+	stemmer? ( dev-libs/snowball-stemmer )
+	sys-apps/util-linux
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-util/glib-utils
+	$(vala_depend)
+	gtk-doc? ( >=dev-util/gtk-doc-1.8
+		app-text/docbook-xml-dtd:4.1.2
+		app-text/docbook-xml-dtd:4.5 )
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	${PYTHON_DEPS}
+"
+PDEPEND="miners? ( >=app-misc/tracker-miners-${PV_SERIES} )"
+
+function inotify_enabled() {
+	if linux_config_exists; then
+		if ! linux_chkconfig_present INOTIFY_USER; then
+			ewarn "You should enable the INOTIFY support in your kernel."
+			ewarn "Check the 'Inotify support for userland' under the 'File systems'"
+			ewarn "option. It is marked as CONFIG_INOTIFY_USER in the config"
+			die 'missing CONFIG_INOTIFY'
+		fi
+	else
+		einfo "Could not check for INOTIFY support in your kernel."
+	fi
+}
+
+pkg_setup() {
+	linux-info_pkg_setup
+	inotify_enabled
+
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	xdg_src_prepare
+	vala_src_prepare
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc docs)
+		-Dfts=true
+		-Dfunctional_tests=false # many fail in 2.2; retry with 2.3
+		#$(meson_use test functional_tests)
+		-Dman=true
+		$(meson_feature networkmanager network_manager)
+		$(meson_feature stemmer)
+		-Dunicode_support=icu
+		-Dbash_completion="$(get_bashcompdir)"
+		-Dsystemd_user_services="$(systemd_get_userunitdir)"
+	)
+	meson_src_configure
+}
+
+src_test() {
+	dbus-run-session meson test -C "${BUILD_DIR}" || die 'tests failed'
+}