[gentoo-commits] repo/gentoo:master commit in: sci-libs/dealii/

["Matthias Maier" <tamiko@gentoo.org>]

commit:     ecf7fa5aeab4429879aa0ccf03297347bf2ef2be
Author:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
AuthorDate: Mon Aug  5 06:28:32 2019 +0000
Commit:     Matthias Maier <tamiko <AT> gentoo <DOT> org>
CommitDate: Mon Aug  5 06:51:37 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ecf7fa5a

sci-libs/dealii: package migration from ::science overlay

Package-Manager: Portage-2.3.70, Repoman-2.3.16
Signed-off-by: Matthias Maier <tamiko <AT> gentoo.org>

 sci-libs/dealii/Manifest            |   2 +
 sci-libs/dealii/dealii-9.1.1.ebuild | 145 ++++++++++++++++++++++++++++++++++++
 sci-libs/dealii/dealii-9999.ebuild  | 145 ++++++++++++++++++++++++++++++++++++
 sci-libs/dealii/metadata.xml        |  45 +++++++++++
 4 files changed, 337 insertions(+)

diff --git a/sci-libs/dealii/Manifest b/sci-libs/dealii/Manifest
new file mode 100644
index 00000000000..fa22d9957ee
--- /dev/null
+++ b/sci-libs/dealii/Manifest
@@ -0,0 +1,2 @@
+DIST dealii-9.1.1-offline_documentation.tar.gz 211103151 BLAKE2B ef7cf48aa8019a2d42a38804744ff72cc7f744255fa27df852f8f93c86a02f2125458e0e525e57510bb98adc27aed933fefa27d556d8203c991dae9866c7d57a SHA512 5e2b71e9bdeb80875772356e2c873bc1f065f2a8c5c47923b74b471d464e4867c257e3a47b32341aa60af98e74e3ed2eceba8dedb4b157ab872681576ecbd5db
+DIST dealii-9.1.1.tar.gz 19911088 BLAKE2B e8488833f11339ccffd4791b9b46ab77f1982cbbdeb11fab7f6b74ca2e17c3d648a2940f4462d0ac9c68bd619b3c4f43b4d8052d2903cbb9cae2fece93d81987 SHA512 02dd91e2b0f395960f900f4cbe00bd307a4762ffbc5f3838dcc34828937e96727efbbcc66fc3d357d6b00b0dddcbc6cd7709c4c03f067d92a8f72d4631b88bf1

diff --git a/sci-libs/dealii/dealii-9.1.1.ebuild b/sci-libs/dealii/dealii-9.1.1.ebuild
new file mode 100644
index 00000000000..0da4f8ea6ed
--- /dev/null
+++ b/sci-libs/dealii/dealii-9.1.1.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils multilib
+
+# deal.II uses its own FindLAPACK.cmake file that calls into the system
+# FindLAPACK.cmake module and does additional internal setup. Do not remove
+# any of these modules:
+CMAKE_REMOVE_MODULES_LIST=""
+
+DESCRIPTION="Solving partial differential equations with the finite element method"
+HOMEPAGE="http://www.dealii.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dealii/dealii.git"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	MY_PV="${PV//0_rc/rc}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${MY_PV}/${MY_P}.tar.gz -> ${P}.tar.gz
+		doc? (
+			https://github.com/${PN}/${PN}/releases/download/v${MY_PV}/${MY_P}-offline_documentation.tar.gz
+			-> ${P}-offline_documentation.tar.gz
+			)"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="
+	adolc assimp arpack cpu_flags_x86_avx cpu_flags_x86_sse2 cuda +debug
+	doc +examples gmsh +gsl hdf5 +lapack metis mpi muparser nanoflann
+	opencascade netcdf p4est petsc scalapack slepc +sparse static-libs
+	sundials symengine +tbb trilinos
+"
+
+# TODO: add slepc use flag once slepc is packaged for gentoo-science
+REQUIRED_USE="
+	p4est? ( mpi )
+	slepc? ( petsc )
+	trilinos? ( mpi )"
+
+RDEPEND="dev-libs/boost
+	app-arch/bzip2
+	sys-libs/zlib
+	adolc? ( sci-libs/adolc )
+	arpack? ( sci-libs/arpack[mpi=] )
+	assimp? ( media-libs/assimp )
+	cuda? ( dev-util/nvidia-cuda-sdk )
+	gmsh? ( sci-libs/gmsh )
+	gsl? ( sci-libs/gsl )
+	hdf5? ( sci-libs/hdf5[mpi=] )
+	lapack? ( virtual/lapack )
+	metis? ( >=sci-libs/parmetis-4 )
+	mpi? ( virtual/mpi )
+	muparser? ( dev-cpp/muParser )
+	nanoflann? ( sci-libs/nanoflann )
+	netcdf? ( sci-libs/netcdf-cxx:0 )
+	opencascade? ( sci-libs/opencascade:* )
+	p4est? ( sci-libs/p4est[mpi] )
+	petsc? ( sci-mathematics/petsc[mpi=] )
+	scalapack? ( sci-libs/scalapack )
+	slepc? ( sci-mathematics/slepc[mpi=] )
+	sparse? ( sci-libs/umfpack )
+	sundials? ( sci-libs/sundials )
+	symengine? ( >=sci-libs/symengine-0.4:= )
+	tbb? ( dev-cpp/tbb )
+	trilinos? ( sci-libs/trilinos )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] dev-lang/perl )"
+
+src_configure() {
+	# deal.II needs a custom build type:
+	local CMAKE_BUILD_TYPE=$(usex debug DebugRelease Release)
+
+	local mycmakeargs=(
+		-DDEAL_II_PACKAGE_VERSION=9999
+		-DCMAKE_INSTALL_RPATH_USE_LINK_PATH=OFF
+		-DDEAL_II_ALLOW_AUTODETECTION=OFF
+		-DDEAL_II_ALLOW_BUNDLED=OFF
+		-DDEAL_II_ALLOW_PLATFORM_INTROSPECTION=OFF
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_DOCHTML_RELDIR="share/doc/${P}/html"
+		-DDEAL_II_DOCREADME_RELDIR="share/doc/${P}"
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_EXAMPLES_RELDIR="share/doc/${P}/examples"
+		-DDEAL_II_LIBRARY_RELDIR="$(get_libdir)"
+		-DDEAL_II_SHARE_RELDIR="share/${PN}"
+		-DDEAL_II_WITH_ZLIB=ON
+		-DDEAL_II_WITH_ADOLC="$(usex adolc)"
+		-DDEAL_II_WITH_ASSIMP="$(usex assimp)"
+		-DDEAL_II_WITH_ARPACK="$(usex arpack)"
+		-DDEAL_II_HAVE_AVX="$(usex cpu_flags_x86_avx)"
+		-DDEAL_II_WITH_CUDA="$(usex cuda)"
+		-DDEAL_II_HAVE_SSE2="$(usex cpu_flags_x86_sse2)"
+		-DDEAL_II_COMPONENT_DOCUMENTATION="$(usex doc)"
+		-DDEAL_II_COMPONENT_EXAMPLES="$(usex examples)"
+		-DDEAL_II_WITH_GMSH="$(usex gmsh)"
+		-DDEAL_II_WITH_GSL="$(usex gsl)"
+		-DDEAL_II_WITH_HDF5="$(usex hdf5)"
+		-DDEAL_II_WITH_LAPACK="$(usex lapack)"
+		-DDEAL_II_WITH_METIS="$(usex metis)"
+		-DDEAL_II_WITH_MPI="$(usex mpi)"
+		-DDEAL_II_WITH_MUPARSER="$(usex muparser)"
+		-DDEAL_II_WITH_NANOFLANN="$(usex nanoflann)"
+		-DDEAL_II_WITH_NETCDF="$(usex netcdf)"
+		-DOPENCASCADE_DIR="${CASROOT}"
+		-DDEAL_II_WITH_OPENCASCADE="$(usex opencascade)"
+		-DDEAL_II_WITH_P4EST="$(usex p4est)"
+		-DDEAL_II_WITH_PETSC="$(usex petsc)"
+		-DDEAL_II_WITH_SCALAPACK="$(usex scalapack)"
+		-DDEAL_II_WITH_SLEPC="$(usex slepc)"
+		-DDEAL_II_WITH_SUNDIALS="$(usex sundials)"
+		-DDEAL_II_WITH_SYMENGINE="$(usex symengine)"
+		-DDEAL_II_WITH_UMFPACK="$(usex sparse)"
+		-DBUILD_SHARED_LIBS="$(usex !static-libs)"
+		-DDEAL_II_PREFER_STATIC_LIBS="$(usex static-libs)"
+		-DDEAL_II_WITH_THREADS="$(usex tbb)"
+		-DDEAL_II_WITH_TRILINOS="$(usex trilinos)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	if use doc && [[ ${PV} != *9999* ]]; then
+		# copy missing images to the build directory:
+		cp -r "${WORKDIR}"/doc/doxygen/deal.II/images \
+			"${BUILD_DIR}"/doc/doxygen/deal.II || die
+		# replace links:
+		sed -i \
+			's#"http://www.dealii.org/images/steps/developer/\(step-.*\)"#"images/\1"#g' \
+			"${BUILD_DIR}"/doc/doxygen/deal.II/step_*.html || die "sed failed"
+	fi
+	cmake-utils_src_install
+
+	# decompress the installed example sources:
+	use examples && docompress -x /usr/share/doc/${PF}/examples
+}

diff --git a/sci-libs/dealii/dealii-9999.ebuild b/sci-libs/dealii/dealii-9999.ebuild
new file mode 100644
index 00000000000..0da4f8ea6ed
--- /dev/null
+++ b/sci-libs/dealii/dealii-9999.ebuild
@@ -0,0 +1,145 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils multilib
+
+# deal.II uses its own FindLAPACK.cmake file that calls into the system
+# FindLAPACK.cmake module and does additional internal setup. Do not remove
+# any of these modules:
+CMAKE_REMOVE_MODULES_LIST=""
+
+DESCRIPTION="Solving partial differential equations with the finite element method"
+HOMEPAGE="http://www.dealii.org/"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/dealii/dealii.git"
+	SRC_URI=""
+	KEYWORDS=""
+else
+	MY_PV="${PV//0_rc/rc}"
+	MY_P="${PN}-${MY_PV}"
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/v${MY_PV}/${MY_P}.tar.gz -> ${P}.tar.gz
+		doc? (
+			https://github.com/${PN}/${PN}/releases/download/v${MY_PV}/${MY_P}-offline_documentation.tar.gz
+			-> ${P}-offline_documentation.tar.gz
+			)"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="
+	adolc assimp arpack cpu_flags_x86_avx cpu_flags_x86_sse2 cuda +debug
+	doc +examples gmsh +gsl hdf5 +lapack metis mpi muparser nanoflann
+	opencascade netcdf p4est petsc scalapack slepc +sparse static-libs
+	sundials symengine +tbb trilinos
+"
+
+# TODO: add slepc use flag once slepc is packaged for gentoo-science
+REQUIRED_USE="
+	p4est? ( mpi )
+	slepc? ( petsc )
+	trilinos? ( mpi )"
+
+RDEPEND="dev-libs/boost
+	app-arch/bzip2
+	sys-libs/zlib
+	adolc? ( sci-libs/adolc )
+	arpack? ( sci-libs/arpack[mpi=] )
+	assimp? ( media-libs/assimp )
+	cuda? ( dev-util/nvidia-cuda-sdk )
+	gmsh? ( sci-libs/gmsh )
+	gsl? ( sci-libs/gsl )
+	hdf5? ( sci-libs/hdf5[mpi=] )
+	lapack? ( virtual/lapack )
+	metis? ( >=sci-libs/parmetis-4 )
+	mpi? ( virtual/mpi )
+	muparser? ( dev-cpp/muParser )
+	nanoflann? ( sci-libs/nanoflann )
+	netcdf? ( sci-libs/netcdf-cxx:0 )
+	opencascade? ( sci-libs/opencascade:* )
+	p4est? ( sci-libs/p4est[mpi] )
+	petsc? ( sci-mathematics/petsc[mpi=] )
+	scalapack? ( sci-libs/scalapack )
+	slepc? ( sci-mathematics/slepc[mpi=] )
+	sparse? ( sci-libs/umfpack )
+	sundials? ( sci-libs/sundials )
+	symengine? ( >=sci-libs/symengine-0.4:= )
+	tbb? ( dev-cpp/tbb )
+	trilinos? ( sci-libs/trilinos )"
+
+DEPEND="${RDEPEND}
+	virtual/pkgconfig
+	doc? ( app-doc/doxygen[dot] dev-lang/perl )"
+
+src_configure() {
+	# deal.II needs a custom build type:
+	local CMAKE_BUILD_TYPE=$(usex debug DebugRelease Release)
+
+	local mycmakeargs=(
+		-DDEAL_II_PACKAGE_VERSION=9999
+		-DCMAKE_INSTALL_RPATH_USE_LINK_PATH=OFF
+		-DDEAL_II_ALLOW_AUTODETECTION=OFF
+		-DDEAL_II_ALLOW_BUNDLED=OFF
+		-DDEAL_II_ALLOW_PLATFORM_INTROSPECTION=OFF
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_DOCHTML_RELDIR="share/doc/${P}/html"
+		-DDEAL_II_DOCREADME_RELDIR="share/doc/${P}"
+		-DDEAL_II_COMPILE_EXAMPLES=OFF
+		-DDEAL_II_EXAMPLES_RELDIR="share/doc/${P}/examples"
+		-DDEAL_II_LIBRARY_RELDIR="$(get_libdir)"
+		-DDEAL_II_SHARE_RELDIR="share/${PN}"
+		-DDEAL_II_WITH_ZLIB=ON
+		-DDEAL_II_WITH_ADOLC="$(usex adolc)"
+		-DDEAL_II_WITH_ASSIMP="$(usex assimp)"
+		-DDEAL_II_WITH_ARPACK="$(usex arpack)"
+		-DDEAL_II_HAVE_AVX="$(usex cpu_flags_x86_avx)"
+		-DDEAL_II_WITH_CUDA="$(usex cuda)"
+		-DDEAL_II_HAVE_SSE2="$(usex cpu_flags_x86_sse2)"
+		-DDEAL_II_COMPONENT_DOCUMENTATION="$(usex doc)"
+		-DDEAL_II_COMPONENT_EXAMPLES="$(usex examples)"
+		-DDEAL_II_WITH_GMSH="$(usex gmsh)"
+		-DDEAL_II_WITH_GSL="$(usex gsl)"
+		-DDEAL_II_WITH_HDF5="$(usex hdf5)"
+		-DDEAL_II_WITH_LAPACK="$(usex lapack)"
+		-DDEAL_II_WITH_METIS="$(usex metis)"
+		-DDEAL_II_WITH_MPI="$(usex mpi)"
+		-DDEAL_II_WITH_MUPARSER="$(usex muparser)"
+		-DDEAL_II_WITH_NANOFLANN="$(usex nanoflann)"
+		-DDEAL_II_WITH_NETCDF="$(usex netcdf)"
+		-DOPENCASCADE_DIR="${CASROOT}"
+		-DDEAL_II_WITH_OPENCASCADE="$(usex opencascade)"
+		-DDEAL_II_WITH_P4EST="$(usex p4est)"
+		-DDEAL_II_WITH_PETSC="$(usex petsc)"
+		-DDEAL_II_WITH_SCALAPACK="$(usex scalapack)"
+		-DDEAL_II_WITH_SLEPC="$(usex slepc)"
+		-DDEAL_II_WITH_SUNDIALS="$(usex sundials)"
+		-DDEAL_II_WITH_SYMENGINE="$(usex symengine)"
+		-DDEAL_II_WITH_UMFPACK="$(usex sparse)"
+		-DBUILD_SHARED_LIBS="$(usex !static-libs)"
+		-DDEAL_II_PREFER_STATIC_LIBS="$(usex static-libs)"
+		-DDEAL_II_WITH_THREADS="$(usex tbb)"
+		-DDEAL_II_WITH_TRILINOS="$(usex trilinos)"
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	if use doc && [[ ${PV} != *9999* ]]; then
+		# copy missing images to the build directory:
+		cp -r "${WORKDIR}"/doc/doxygen/deal.II/images \
+			"${BUILD_DIR}"/doc/doxygen/deal.II || die
+		# replace links:
+		sed -i \
+			's#"http://www.dealii.org/images/steps/developer/\(step-.*\)"#"images/\1"#g' \
+			"${BUILD_DIR}"/doc/doxygen/deal.II/step_*.html || die "sed failed"
+	fi
+	cmake-utils_src_install
+
+	# decompress the installed example sources:
+	use examples && docompress -x /usr/share/doc/${PF}/examples
+}

diff --git a/sci-libs/dealii/metadata.xml b/sci-libs/dealii/metadata.xml
new file mode 100644
index 00000000000..2a8319d140e
--- /dev/null
+++ b/sci-libs/dealii/metadata.xml
@@ -0,0 +1,45 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "http://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>tamiko@gentoo.org</email>
+		<name>Matthias Maier</name>
+	</maintainer>
+	<maintainer type="project">
+		<email>sci@gentoo.org</email>
+		<name>Gentoo Science Project</name>
+	</maintainer>
+	<longdescription lang="en">
+deal.II is a C++ program library targeted at the computational solution
+of partial differential equations using adaptive finite elements. It uses
+state-of-the-art programming techniques to offer you a modern interface
+to the complex data structures and algorithms required.
+</longdescription>
+	<use>
+		<flag name="adolc">Adds support for ADOL-C (<pkg>sci-libs/adolc</pkg>)</flag>
+		<flag name="arpack">Adds support for ARPACK (<pkg>sci-libs/arpack</pkg>)</flag>
+		<flag name="debug">
+Build an additional debug library with extra debug codepaths, like asserts
+and extra output. If you want to get meaningful backtraces see
+&lt;http://www.gentoo.org/proj/en/qa/backtraces.xml&gt;</flag>
+		<flag name="gmsh">Add support for gmsh (<pkg>sci-libs/gmsh</pkg>)</flag>
+		<flag name="metis">Add support for metis (<pkg>sci-libs/metis</pkg>)</flag>
+		<flag name="muparser">Add support for muparser (<pkg>dev-cpp/muParser</pkg>)</flag>
+		<flag name="nanoflann">Adds support for nanoflann (<pkg>sci-libs/nanoflann</pkg>)</flag>
+		<flag name="opencascade">Add support for opencascade (<pkg>sci-libs/opencascade</pkg>)</flag>
+		<flag name="p4est">Add support for p4est (<pkg>sci-mathematics/p4est</pkg>)</flag>
+		<flag name="petsc">Add support for petsc (<pkg>sci-mathematics/petsc</pkg>)</flag>
+		<flag name="scalapack">Add support for ScaLAPACK (<pkg>sci-libs/scalapack</pkg>)</flag>
+		<flag name="slepc">Add support for slepc (<pkg>sci-mathematics/slepc</pkg>)</flag>
+		<flag name="sparse">Add support for suitesparse (<pkg>sci-libs/suitesparse</pkg>)</flag>
+		<flag name="symengine">Add support for symengine (<pkg>sci-libs/symengine</pkg>)</flag>
+		<flag name="tbb">Add threading support with the help of the tbb library (<pkg>dev-cpp/tbb</pkg>)</flag>
+		<flag name="trilinos">Add support for trilinos (<pkg>sci-libs/trilinos</pkg>)</flag>
+		<flag name="assimp">Add support for assimp (<pkg>media-libs/assimp</pkg>)</flag>
+		<flag name="cuda">Add support for cuda assimp (<pkg>dev-util/nvidia-cuda-sdk</pkg>)</flag>
+		<flag name="sundials">Add support for sundials assimp (<pkg>sci-libs/sundials</pkg>)</flag>
+	</use>
+	<upstream>
+		<remote-id type="github">dealii/dealii</remote-id>
+	</upstream>
+</pkgmetadata>