[gentoo-commits] repo/gentoo:master commit in: media-sound/exaile/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     1b2119d632b28785876cf713eb9528dc466e0333
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sun Aug  4 11:37:45 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sun Aug  4 11:56:12 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1b2119d6

media-sound/exaile: bump to 4.0.0, fix some deps

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 media-sound/exaile/Manifest            |  1 +
 media-sound/exaile/exaile-4.0.0.ebuild | 78 ++++++++++++++++++++++++++++++++++
 2 files changed, 79 insertions(+)

diff --git a/media-sound/exaile/Manifest b/media-sound/exaile/Manifest
index 722ef0502bc..ab94246d8b7 100644
--- a/media-sound/exaile/Manifest
+++ b/media-sound/exaile/Manifest
@@ -1 +1,2 @@
+DIST exaile-4.0.0.tar.gz 3635774 BLAKE2B 91a5a0a4b8f3c55ec1c8f6487f30bbc8193b1e8b861bbc4bf3cba18dcef91c8a58c937e7a581378eec9da518565826c35e55b7ab157b7ee4634d36cd71a85c4e SHA512 50ab8ec7a65dc431f2bc71a302d21e59ac3d5939b89a90ec161527e1d5c0b80b8c396f8f323b2959e0b807f577e021863fe423bf26a8f7165a6dd112afca6e45
 DIST exaile-4.0.0rc3.tar.gz 3627782 BLAKE2B 1c986309798d4cb78969a7443e4c29e02ca3a9c8e316264641ffafe97dd46b6a1745988230c13469ce2d9c37aadf7b07eee5bcd5836f33b1b2d25e3ebb69f574 SHA512 d3822a7d88934c90a2856074f177a346b19896ecca54f33e7506d37a0b25170983c057feaae162c2685780e7f0d1a6edc8ce7addbcc04cacf2d2b25e0c9f36de

diff --git a/media-sound/exaile/exaile-4.0.0.ebuild b/media-sound/exaile/exaile-4.0.0.ebuild
new file mode 100644
index 00000000000..304677b1794
--- /dev/null
+++ b/media-sound/exaile/exaile-4.0.0.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 )
+PYTHON_REQ_USE="sqlite"
+inherit python-single-r1 xdg-utils
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/exaile/exaile.git"
+else
+	SRC_URI="https://github.com/${PN}/${PN}/releases/download/${PV/_/-}/${PN}-${PV/_/}.tar.gz"
+	KEYWORDS="~amd64 ~sparc ~x86"
+	S="${WORKDIR}/${PN}-${PV/_/}"
+fi
+
+DESCRIPTION="GTK+ based media player aiming to be similar to Amarok"
+HOMEPAGE="https://www.exaile.org/"
+
+LICENSE="GPL-2 GPL-3"
+SLOT="0"
+IUSE="cddb libnotify nls scrobbler"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	dev-python/bsddb3[${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/gst-python:1.0[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	>=dev-python/pygobject-3.13.2:3[${PYTHON_USEDEP}]
+	>=media-libs/gst-plugins-base-1.6:1.0
+	>=media-libs/gst-plugins-good-1.4:1.0
+	>=media-libs/mutagen-1.10[${PYTHON_USEDEP}]
+	media-plugins/gst-plugins-meta:1.0
+	>=x11-libs/gtk+-3.10:3[introspection]
+	cddb? ( dev-python/cddb-py )
+	libnotify? ( >=x11-libs/libnotify-0.7[introspection] )
+	scrobbler? ( dev-python/pylast[${PYTHON_USEDEP}] )
+"
+BDEPEND="
+	nls? (
+		dev-util/intltool
+		sys-devel/gettext
+	)
+"
+
+RESTRICT="test" #315589
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_compile() {
+	use nls && emake locale
+}
+
+src_install() {
+	emake \
+		PREFIX=/usr \
+		LIBINSTALLDIR=/usr/$(get_libdir) \
+		DESTDIR="${D}" \
+		install$(use nls || echo _no_locale)
+
+	python_optimize "${D}/usr/$(get_libdir)/${PN}"
+	python_optimize "${D}/usr/share/${PN}"
+}
+
+pkg_postinst() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_desktop_database_update
+	xdg_mimeinfo_database_update
+}