[gentoo-commits] repo/gentoo:master commit in: net-libs/libsignon-glib/

["Alexey Shvetsov" <alexxy@gentoo.org>]

commit:     b7e3e4dfec7e50e381412c2dcd2d627f59563fc1
Author:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
AuthorDate: Sat Aug  3 20:36:04 2019 +0000
Commit:     Alexey Shvetsov <alexxy <AT> gentoo <DOT> org>
CommitDate: Sat Aug  3 20:36:04 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b7e3e4df

net-libs/libsignon-glib: Works with py3.7

Package-Manager: Portage-2.3.69, Repoman-2.3.16
Signed-off-by: Alexey Shvetsov <alexxy <AT> gentoo.org>

 .../libsignon-glib/libsignon-glib-1.14-r1.ebuild   | 88 ++++++++++++++++++++++
 1 file changed, 88 insertions(+)

diff --git a/net-libs/libsignon-glib/libsignon-glib-1.14-r1.ebuild b/net-libs/libsignon-glib/libsignon-glib-1.14-r1.ebuild
new file mode 100644
index 00000000000..bd73aa4de09
--- /dev/null
+++ b/net-libs/libsignon-glib/libsignon-glib-1.14-r1.ebuild
@@ -0,0 +1,88 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python2_7 python3_{5,6,7} )
+inherit autotools python-r1 vcs-snapshot xdg-utils
+
+DESCRIPTION="GLib binding for the D-Bus API provided by signond"
+HOMEPAGE="https://01.org/gsso/"
+SRC_URI="https://gitlab.com/accounts-sso/libsignon-glib/repository/archive.tar.gz?ref=VERSION_${PV} -> ${P}.tar.gz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="debug doc +introspection python test"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} introspection )"
+
+RDEPEND="
+	dev-libs/glib:2
+	net-libs/signond
+	introspection? ( dev-libs/gobject-introspection:= )
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}]
+	)
+"
+DEPEND="${RDEPEND}
+	dev-util/glib-utils
+	dev-util/gdbus-codegen
+	doc? ( dev-util/gtk-doc )
+"
+
+DOCS=( AUTHORS NEWS README.md )
+
+# needs more love
+RESTRICT="test"
+
+PATCHES=( "${FILESDIR}/${P}-default-opts.patch" )
+
+src_prepare() {
+	default
+
+	if ! use doc; then
+		eapply "${FILESDIR}/${PN}-1.12-doc-disable.patch"
+	fi
+
+	eautoreconf
+}
+
+src_configure() {
+	xdg_environment_reset
+
+	myconfigure() {
+		local myeconfargs=(
+			$(use_enable debug)
+			$(use_enable doc gtk-doc)
+			$(use_enable introspection)
+			$(use_enable python)
+			$(use_enable test tests)
+		)
+
+		econf "${myeconfargs[@]}"
+	}
+
+	if use python; then
+		python_copy_sources
+		python_foreach_impl run_in_build_dir myconfigure
+	else
+		myconfigure
+	fi
+}
+
+src_compile() {
+	default
+	if use python; then
+		python_foreach_impl run_in_build_dir default
+	fi
+}
+
+src_install() {
+	default
+	if use python; then
+		python_foreach_impl run_in_build_dir default
+	fi
+	find "${D}" -name '*.la' -delete || die
+}