[gentoo-commits] repo/gentoo:master commit in: dev-util/sysprof/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     1d6e644ed366475a164746391fd65fbe7f2d06ae
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Sat Jul 27 08:07:10 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Sat Jul 27 08:35:53 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=1d6e644e

dev-util/sysprof: bump to 3.32.0

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 dev-util/sysprof/Manifest              |  1 +
 dev-util/sysprof/sysprof-3.32.0.ebuild | 74 ++++++++++++++++++++++++++++++++++
 2 files changed, 75 insertions(+)

diff --git a/dev-util/sysprof/Manifest b/dev-util/sysprof/Manifest
index 570316497d7..bfb234f676b 100644
--- a/dev-util/sysprof/Manifest
+++ b/dev-util/sysprof/Manifest
@@ -1 +1,2 @@
 DIST sysprof-3.30.2.tar.xz 393420 BLAKE2B 5e86a78c231d2d2c601198e066c463d8bec95ab1ae6d0f6678e6e80305b8a6d53c604ce54d9fc2a473e4679695cef709f0e1a9514f1091719f33a58b92c896eb SHA512 70c49f7c20742aad82c8d9b1e303d06ca5fd2d27a6868872d28affea22278d381bf3eb0d181cbd1bfa490bda2878c52748ac29273e9e608452e9bf4f29fd9e2a
+DIST sysprof-3.32.0.tar.xz 296052 BLAKE2B f409c64d40bd3451037e601683f270ff93ea2a60a2c104d22edc6bad5ff3f5c974f80137776b6329dae932852fa0871f2b7b9960a282147ddef5402ad840d9ef SHA512 7b9d84ac241d376a5e545082b1224e7db96af26ae0ee297d5f0b2d45abc4676e23009dbd560085e5d4879378a8dd79eefb4449df3961fbfd09238bd2056061d0

diff --git a/dev-util/sysprof/sysprof-3.32.0.ebuild b/dev-util/sysprof/sysprof-3.32.0.ebuild
new file mode 100644
index 00000000000..16e41d08213
--- /dev/null
+++ b/dev-util/sysprof/sysprof-3.32.0.ebuild
@@ -0,0 +1,74 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit gnome.org gnome2-utils meson systemd xdg
+
+DESCRIPTION="System-wide Linux Profiler"
+HOMEPAGE="http://sysprof.com/"
+
+LICENSE="GPL-3+ GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="elogind gtk systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+RDEPEND="
+	>=dev-libs/glib-2.44:2
+	sys-auth/polkit
+	gtk? ( >=x11-libs/gtk+-3.22.0:3 )
+	elogind? ( >=sys-auth/elogind-239.3 )
+	systemd? ( >=sys-apps/systemd-222:0= )
+"
+DEPEND="${RDEPEND}"
+# libxml2 required for glib-compile-resources; appstream-glib for appdata.xml developer_name tag translation
+BDEPEND="
+	dev-libs/appstream-glib
+	dev-libs/libxml2:2
+	dev-util/itstool
+	>=sys-devel/gettext-0.19.8
+	>=sys-kernel/linux-headers-2.6.32
+	virtual/pkgconfig
+"
+
+PATCHES=( "${FILESDIR}"/3.30.2-elogind.patch )
+
+src_configure() {
+	# -Dwith_sysprofd=host currently unavailable from ebuild
+	local emesonargs=(
+		$(meson_use gtk enable_gtk)
+		-Dwith_sysprofd=$(usex systemd bundled $(usex elogind bundled none))
+		-Dsystemdunitdir=$(systemd_get_systemunitdir)
+		# -Ddebugdir
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+
+	elog "On many systems, especially amd64, it is typical that with a modern"
+	elog "toolchain -fomit-frame-pointer for gcc is the default, because"
+	elog "debugging is still possible thanks to gcc4/gdb location list feature."
+	elog "However sysprof is not able to construct call trees if frame pointers"
+	elog "are not present. Therefore -fno-omit-frame-pointer CFLAGS is suggested"
+	elog "for the libraries and applications involved in the profiling. That"
+	elog "means a CPU register is used for the frame pointer instead of other"
+	elog "purposes, which means a very minimal performance loss when there is"
+	elog "register pressure."
+	if ! use systemd && ! use elogind; then
+		elog ""
+		elog "Without systemd or elogind, sysprof may not function when launched as a"
+		elog "regular user, thus suboptimal running from root account may be necessary."
+		if use gtk; then
+			elog "Under wayland, that limits the recording usage to sysprof-cli utility."
+		fi
+	fi
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}