[gentoo-commits] repo/gentoo:master commit in: dev-python/aiohttp/

["Michał Górny" <mgorny@gentoo.org>]

commit:     7e6974737304fdc36b1ee947ca1f522bffee7ad6
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Sun Jul 14 11:57:39 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Sun Jul 14 12:26:33 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=7e697473

dev-python/aiohttp: Bump to 3.5.4, enable py3.7

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-python/aiohttp/Manifest             |  1 +
 dev-python/aiohttp/aiohttp-3.5.4.ebuild | 80 +++++++++++++++++++++++++++++++++
 2 files changed, 81 insertions(+)

diff --git a/dev-python/aiohttp/Manifest b/dev-python/aiohttp/Manifest
index 20cd0e08e64..b5bd635eeff 100644
--- a/dev-python/aiohttp/Manifest
+++ b/dev-python/aiohttp/Manifest
@@ -5,3 +5,4 @@ DIST aiohttp-2.3.2.tar.gz 841030 BLAKE2B a291baa1c5e915815ec80ea1cbd8434b31f4098
 DIST aiohttp-3.0.6.tar.gz 738111 BLAKE2B 28a3560a7b351ee974db8bbdd372798e01696e66660b6330707c542253c4d8a0405e6e8c2c8ec03c3b0ea8b548516ffb2dfe14b800b5f17e908991244bfd9335 SHA512 43f1b3c2da1bc57ac6e83a01abb3568b71ed5514e9331aaba4b691ff036d2d3e72eeddadd0f2f20608fa1f622a673ce1d4489bced2096ae546a350ad5f438d0d
 DIST aiohttp-3.3.0.tar.gz 722307 BLAKE2B 3bf1906e8a518d443a2f1bfff536fe9c4024dd18d12ed791dd4a81cfa3f81260bbbf293ae093086fa45c068f3417bcc797d1ee01e64a890a9427944ac9836760 SHA512 e7dd320abb0d9baa0dd583ce034b2d2dd328aa37750197789207e80eabfaf1e998a58e9aa0a6b98ff213f8c78ca90b85698ac559c57f44ce1b643fc317735a4b
 DIST aiohttp-3.4.4.tar.gz 822110 BLAKE2B 808c125f0d826b11d5b333ecfc35ed15cfe5a4f4242df5dd1b1e8edf6502c78d6162ad21e4fb7026294bc7013251a3b55d50c9cf34539b06b32348be2b1627a9 SHA512 968b701b8a19aa445a4af402f4bb38754565e3b80b4248127e5017671c921c370eea63fcec4148b7229ac1a74bb8739f33513abd6cb7fe02f3feddfd3ec1a6b1
+DIST aiohttp-3.5.4.tar.gz 1097647 BLAKE2B 27d3631cf33cc5052deecfeca23f6c052fce344d9a889b0c0c0e68d9dcc19eb56e2ef2496f025c795dea4f906a59ae579ecd489188f8c56bc41255b4f450f4bf SHA512 9bc31457029f7db5bbfe1e213c1f428bf90ac96d83b6d2c8838261a3910ab9f7632a4299618377acb1bed04b0cbb4b4f6d9ee814495c05f210ed9bb4f4c61714

diff --git a/dev-python/aiohttp/aiohttp-3.5.4.ebuild b/dev-python/aiohttp/aiohttp-3.5.4.ebuild
new file mode 100644
index 00000000000..3b9fe39c93d
--- /dev/null
+++ b/dev-python/aiohttp/aiohttp-3.5.4.ebuild
@@ -0,0 +1,80 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{5,6,7} )
+
+inherit distutils-r1
+
+DESCRIPTION="http client/server for asyncio"
+HOMEPAGE="https://pypi.org/project/aiohttp/"
+SRC_URI="mirror://pypi/${P:0:1}/${PN}/${P}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+CDEPEND="
+	>=dev-python/async_timeout-3.0.0[${PYTHON_USEDEP}]
+	>=dev-python/attrs-17.3.0[${PYTHON_USEDEP}]
+	dev-python/chardet[${PYTHON_USEDEP}]
+	>=dev-python/multidict-4.0.0[${PYTHON_USEDEP}]
+	>=dev-python/yarl-1.0[${PYTHON_USEDEP}]
+	dev-python/idna-ssl[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep 'dev-python/typing-extensions[${PYTHON_USEDEP}]' \
+		python3_{5,6})
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/alabaster-0.6.2[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-asyncio[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-blockdiag[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-newsfeed[${PYTHON_USEDEP}]
+		dev-python/sphinxcontrib-spelling[${PYTHON_USEDEP}]
+		dev-python/sphinx[${PYTHON_USEDEP}]
+		dev-python/sphinx-aiohttp-theme[${PYTHON_USEDEP}]
+	)
+	test? (
+		${CDEPEND}
+		dev-python/async_generator[${PYTHON_USEDEP}]
+		dev-python/brotlipy[${PYTHON_USEDEP}]
+		>=dev-python/pytest-3.4.0[${PYTHON_USEDEP}]
+		dev-python/pytest-mock[${PYTHON_USEDEP}]
+		dev-python/pytest-timeout[${PYTHON_USEDEP}]
+		dev-python/trustme[${PYTHON_USEDEP}]
+		www-servers/gunicorn[${PYTHON_USEDEP}]
+	)
+"
+RDEPEND="${CDEPEND}"
+
+DOCS=( CHANGES.rst CONTRIBUTING.rst CONTRIBUTORS.txt HISTORY.rst README.rst )
+
+python_prepare_all() {
+	# FIXME
+	rm tests/test_pytest_plugin.py || die
+	sed -i -e 's:test_testcase_no_app:_&:' tests/test_test_utils.py || die
+
+	# remove pointless dep on pytest-cov
+	sed -i -e '/addopts/s/--cov=aiohttp//' pytest.ini || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+
+	distutils-r1_python_install_all
+}