From: "Göktürk Yüksek" <gokturk@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Subject: [gentoo-commits] repo/gentoo:master commit in: mate-extra/mate-screensaver/
Date: Sun, 12 May 2019 21:04:35 +0000 (UTC) [thread overview]
Message-ID: <1557694936.5493535866ff42b0469550da06137079eff232ba.gokturk@gentoo> (raw)
commit: 5493535866ff42b0469550da06137079eff232ba
Author: NP-Hardass <NP-Hardass <AT> gentoo <DOT> org>
AuthorDate: Sun May 12 20:20:17 2019 +0000
Commit: Göktürk Yüksek <gokturk <AT> gentoo <DOT> org>
CommitDate: Sun May 12 21:02:16 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=54935358
mate-extra/mate-screensaver: bump to 1.22.1, fix deps and configure
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Göktürk Yüksek <gokturk <AT> gentoo.org>
| 1 +
.../mate-screensaver-1.22.1.ebuild | 119 +++++++++++++++++++++
2 files changed, 120 insertions(+)
--git a/mate-extra/mate-screensaver/Manifest b/mate-extra/mate-screensaver/Manifest
index 924483e776d..fe18ac4fc76 100644
--- a/mate-extra/mate-screensaver/Manifest
+++ b/mate-extra/mate-screensaver/Manifest
@@ -1 +1,2 @@
DIST mate-screensaver-1.22.0.tar.xz 4959732 BLAKE2B 23d7622ea992c8a29966a12a4e8db36fb489d0d07124907cb3fc2325dedb7fb99394bc551b0d889247989bbea27ba540fb17f55dbd12644e10a9abc242b07d8a SHA512 e253495ad700264ee7833d7b5a732cabff53058384801ff5e874d45f812cea1e4bd3877a1688ecec6197c37f32761f69a4924a47a6556332f1fec736e540e333
+DIST mate-screensaver-1.22.1.tar.xz 4942928 BLAKE2B e82b6482ed9ec655bb8bea2795b0e2559cbdfcb2be5f27a2264486a2013b8234cb02292b6ca547f8812e6dc0c74646f51af8a2f8d7baf2f28bf1b688508350d5 SHA512 7ffb94d88095ff5580862fe9c958a2e4af7a424d40dc5e0f3c1da49a258035179573721fc7052710624916678e953a6347a898b53ff872a49e022987b8c02904
diff --git a/mate-extra/mate-screensaver/mate-screensaver-1.22.1.ebuild b/mate-extra/mate-screensaver/mate-screensaver-1.22.1.ebuild
new file mode 100644
index 00000000000..1d364261256
--- /dev/null
+++ b/mate-extra/mate-screensaver/mate-screensaver-1.22.1.ebuild
@@ -0,0 +1,119 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit mate readme.gentoo-r1
+
+if [[ ${PV} != 9999 ]]; then
+ KEYWORDS="~amd64 ~arm ~arm64 ~x86"
+fi
+
+DESCRIPTION="Replaces xscreensaver, integrating with the MATE desktop"
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="X debug consolekit elogind kernel_linux libnotify opengl pam systemd"
+REQUIRED_USE="?? ( elogind systemd )"
+
+DOC_CONTENTS="
+ Information for converting screensavers is located in
+ /usr/share/doc/${PF}/xss-conversion.txt*
+"
+
+COMMON_DEPEND="
+ >=dev-libs/dbus-glib-0.71:0
+ >=dev-libs/glib-2.50:2
+ gnome-base/dconf
+ >=mate-base/libmatekbd-1.17.0
+ >=mate-base/mate-desktop-1.17.0
+ >=mate-base/mate-menus-1.21.0
+ >=sys-apps/dbus-0.30
+ >=x11-libs/gdk-pixbuf-2.14:2
+ >=x11-libs/libX11-1
+ x11-libs/cairo
+ >=x11-libs/gtk+-3.22:3
+ x11-libs/libXext
+ x11-libs/libXrandr
+ x11-libs/libXScrnSaver
+ x11-libs/libXxf86misc
+ x11-libs/libXxf86vm
+ x11-libs/libxklavier
+ x11-libs/pango
+ virtual/libintl
+ consolekit? ( sys-auth/consolekit )
+ libnotify? ( >=x11-libs/libnotify-0.7:0 )
+ opengl? ( virtual/opengl )
+ pam? ( gnome-base/gnome-keyring virtual/pam )
+ !pam? ( kernel_linux? ( sys-apps/shadow ) )
+ elogind? ( sys-auth/elogind )
+ systemd? ( sys-apps/systemd:= )
+ !!<gnome-extra/gnome-screensaver-3"
+
+RDEPEND="${COMMON_DEPEND}
+ >=mate-base/mate-session-manager-1.6"
+
+DEPEND="${COMMON_DEPEND}
+ >=dev-util/intltool-0.50.1
+ sys-devel/gettext:*
+ x11-base/xorg-proto
+ virtual/pkgconfig:*"
+
+src_configure() {
+ local myconf=(
+ --enable-locking
+ --with-kbd-layout-indicator
+ --with-xf86gamma-ext
+ --with-xscreensaverdir=/usr/share/xscreensaver/config
+ --with-xscreensaverhackdir=/usr/$(get_libdir)/misc/xscreensaver
+ $(use_with X x)
+ $(use_with consolekit console-kit)
+ $(use_with elogind)
+ $(use_with libnotify)
+ $(use_with opengl libgl)
+ $(use_with systemd)
+ $(use_enable debug)
+ $(use_enable pam)
+ )
+
+ mate_src_configure "${myconf[@]}"
+}
+
+src_install() {
+ mate_src_install
+
+ # Install the conversion script in the documentation.
+ dodoc "${S}"/data/migrate-xscreensaver-config.sh
+ dodoc "${S}"/data/xscreensaver-config.xsl
+ dodoc "${FILESDIR}"/xss-conversion.txt
+
+ # Non PAM users will need this suid to read the password hashes.
+ # OpenPAM users will probably need this too when
+ # https://bugzilla.gnome.org/show_bug.cgi?id=370847
+ # is fixed.
+ if ! use pam ; then
+ fperms u+s /usr/libexec/mate-screensaver-dialog
+ fi
+
+ readme.gentoo_create_doc
+}
+
+pkg_postinst() {
+ mate_pkg_postinst
+
+ if has_version "<x11-base/xorg-server-1.5.3-r4" ; then
+ ewarn "You have a too old xorg-server installation. This will cause"
+ ewarn "mate-screensaver to eat up your CPU. Please consider upgrading."
+ echo
+ fi
+
+ if has_version "<x11-misc/xscreensaver-4.22-r2" ; then
+ ewarn "You have xscreensaver installed, you probably want to disable it."
+ ewarn "To prevent a duplicate screensaver entry in the menu, you need to"
+ ewarn "build xscreensaver with -gnome in the USE flags."
+ ewarn "echo \"x11-misc/xscreensaver -gnome\" >> /etc/portage/package.use"
+ echo
+ fi
+
+ readme.gentoo_print_elog
+}
next reply other threads:[~2019-05-12 21:04 UTC|newest]
Thread overview: 46+ messages / expand[flat|nested] mbox.gz Atom feed top
2019-05-12 21:04 Göktürk Yüksek [this message]
-- strict thread matches above, loose matches on Subject: below --
2024-10-06 7:17 [gentoo-commits] repo/gentoo:master commit in: mate-extra/mate-screensaver/ Sam James
2024-09-17 17:50 Andreas Sturmlechner
2024-06-18 8:06 Joonas Niilola
2023-05-15 11:32 David Seifert
2023-01-20 1:34 Sam James
2022-12-21 10:00 Andreas Sturmlechner
2022-12-16 20:39 Arthur Zamarin
2022-09-10 11:21 Sam James
2022-06-28 2:03 WANG Xuerui
2022-01-09 15:48 Andreas Sturmlechner
2021-12-10 20:10 Jakov Smolić
2021-12-10 11:35 Jakov Smolić
2021-06-30 22:43 Adam Feldman
2020-10-08 19:58 Mikle Kolyada
2020-09-25 20:32 Adam Feldman
2020-09-02 6:02 Adam Feldman
2019-10-12 21:04 Mikle Kolyada
2019-07-07 18:48 Göktürk Yüksek
2019-07-07 18:48 Göktürk Yüksek
2019-04-14 21:25 Mikle Kolyada
2019-04-14 16:24 Mikle Kolyada
2019-04-14 15:27 Mikle Kolyada
2019-03-31 10:47 Andreas Sturmlechner
2019-03-17 11:11 Mikle Kolyada
2018-10-06 20:25 Mart Raudsepp
2018-09-10 16:19 Mikle Kolyada
2018-09-09 23:53 Thomas Deutschmann
2018-02-11 15:03 Ettore Di Giacinto
2018-01-14 17:18 Ettore Di Giacinto
2017-10-02 1:35 NP Hardass
2017-09-27 3:23 NP Hardass
2016-12-08 15:31 Ettore Di Giacinto
2016-08-13 18:49 NP Hardass
2016-08-12 5:38 NP Hardass
2016-08-12 5:13 NP Hardass
2016-08-06 2:12 NP Hardass
2016-07-25 18:36 NP Hardass
2016-07-20 22:49 NP Hardass
2016-05-30 19:18 Mikle Kolyada
2016-04-19 13:12 Michał Górny
2016-03-26 2:37 NP Hardass
2016-03-15 17:53 Agostino Sarubbo
2016-03-06 8:09 Mikle Kolyada
2016-02-09 2:49 NP Hardass
2015-12-31 10:04 Amy Winston
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1557694936.5493535866ff42b0469550da06137079eff232ba.gokturk@gentoo \
--to=gokturk@gentoo.org \
--cc=gentoo-commits@lists.gentoo.org \
--cc=gentoo-dev@lists.gentoo.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox