[gentoo-commits] repo/gentoo:master commit in: net-libs/gtk-vnc/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     b49574d76efd7aaae7060dadf80a8d9beeb668cb
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Fri Mar 22 12:58:13 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Fri Mar 22 13:28:29 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=b49574d7

net-libs/gtk-vnc: bump to 0.9.0

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 net-libs/gtk-vnc/Manifest             |  1 +
 net-libs/gtk-vnc/gtk-vnc-0.9.0.ebuild | 70 +++++++++++++++++++++++++++++++++++
 2 files changed, 71 insertions(+)

diff --git a/net-libs/gtk-vnc/Manifest b/net-libs/gtk-vnc/Manifest
index 2e16468b725..cd55e139fad 100644
--- a/net-libs/gtk-vnc/Manifest
+++ b/net-libs/gtk-vnc/Manifest
@@ -1 +1,2 @@
 DIST gtk-vnc-0.8.0.tar.xz 448984 BLAKE2B e9de98a969297832ff6eaba79707a44494b20d944264ac6902596f882b95e8ab1bc6b7eb25e040d17f939d678a81eec730f983942db38d73c81751fc2afd45df SHA512 9b66e4028e56b01af8d0ded5b833fc6c0ba752ac72cd664293b0009868bbec0bc8750b619ece9786eddc06155e390ecccc4c5bc84717c49ac4bd866e6febd8e3
+DIST gtk-vnc-0.9.0.tar.xz 444736 BLAKE2B cf1afc0e856659012738060a584c72d7ad1b70459afd8bf92630d69cf32d380264814304a68a93d8a5a70d6573b6754658450005a2ea2b96f13ae03f9e87fcba SHA512 498b368eb53ac58172db280c80f9da71ce82b636c39f186046e4f674e44c574ff4b63c3f777acc79d32c17d70e4efcdc207768ed49b3d1842bc4b73618296215

diff --git a/net-libs/gtk-vnc/gtk-vnc-0.9.0.ebuild b/net-libs/gtk-vnc/gtk-vnc-0.9.0.ebuild
new file mode 100644
index 00000000000..c2931f94f27
--- /dev/null
+++ b/net-libs/gtk-vnc/gtk-vnc-0.9.0.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python3_{5,6,7} )
+GNOME2_LA_PUNT="yes"
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+
+inherit vala gnome2 python-any-r1
+
+DESCRIPTION="VNC viewer widget for GTK"
+HOMEPAGE="https://wiki.gnome.org/Projects/gtk-vnc"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="examples +introspection pulseaudio sasl +vala"
+REQUIRED_USE="
+	vala? ( introspection )
+"
+
+# libview is used in examples/gvncviewer -- no need
+# glib-2.30.1 needed to avoid linking failure due to .la files (bug #399129)
+RDEPEND="
+	>=dev-libs/glib-2.42.0:2
+	>=dev-libs/libgcrypt-1.5.0:0=
+	dev-libs/libgpg-error
+	>=net-libs/gnutls-3.1.18:0=
+	>=x11-libs/cairo-1.2
+	x11-libs/libX11
+	>=x11-libs/gtk+-3.0.0:3[introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-0.9.4:= )
+	pulseaudio? ( media-sound/pulseaudio )
+	sasl? ( dev-libs/cyrus-sasl )
+"
+# Keymap databases code is generated with python3; configure picks up $PYTHON exported from python-any-r1_pkg_setup
+DEPEND="${RDEPEND}
+	${PYTHON_DEPS}
+	>=dev-lang/perl-5
+	dev-util/glib-utils
+	>=dev-util/intltool-0.40
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? (
+		$(vala_depend)
+		>=dev-libs/gobject-introspection-0.9.4 )
+"
+# eautoreconf requires gnome-common
+
+src_prepare() {
+	vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with examples)
+		$(use_enable introspection)
+		$(use_with pulseaudio)
+		$(use_with sasl)
+		$(use_enable vala)
+		--with-coroutine=gthread
+		--without-libview
+		--disable-static
+		--with-gtk=3.0
+	)
+
+	gnome2_src_configure ${myconf[@]}
+}