[gentoo-commits] repo/gentoo:master commit in: dev-python/cssutils/

["Patrice Clement" <monsieurp@gentoo.org>]

commit:     f2ff5819b7af9d93a882eb5c3951b4dcd7360567
Author:     Zamarin Arthur <arthurzam <AT> gmail <DOT> com>
AuthorDate: Tue Mar 19 17:22:10 2019 +0000
Commit:     Patrice Clement <monsieurp <AT> gentoo <DOT> org>
CommitDate: Wed Mar 20 21:35:22 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=f2ff5819

dev-python/cssutils: add support for Python3.7, EAPI 7.

Closes: https://bugs.gentoo.org/679494
Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Zamarin Arthur <arthurzam <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/11354
Signed-off-by: Patrice Clement <monsieurp <AT> gentoo.org>

 dev-python/cssutils/cssutils-1.0.2-r1.ebuild | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)

diff --git a/dev-python/cssutils/cssutils-1.0.2-r1.ebuild b/dev-python/cssutils/cssutils-1.0.2-r1.ebuild
new file mode 100644
index 00000000000..0542c6dff73
--- /dev/null
+++ b/dev-python/cssutils/cssutils-1.0.2-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} pypy )
+
+inherit distutils-r1
+
+DESCRIPTION="A CSS Cascading Style Sheets library"
+HOMEPAGE="https://pypi.org/project/cssutils/ https://bitbucket.org/cthedot/cssutils http://cthedot.de/cssutils/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="test"
+
+RDEPEND="dev-python/setuptools[${PYTHON_USEDEP}]"
+DEPEND="${RDEPEND}
+	test? (
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/nose[${PYTHON_USEDEP}]
+	)"
+
+python_prepare_all() {
+	# Disable test failing with dev-python/pyxml installed.
+	if has_version dev-python/pyxml; then
+		sed -e "s/test_linecol/_&/" \
+			-i src/cssutils/tests/test_errorhandler.py \
+			|| die
+	fi
+
+	# requires old pbr, does it really?
+	sed \
+		-e '/tests_require/d' \
+		-i setup.py || die
+
+	distutils-r1_python_prepare_all
+}
+
+python_test() {
+	ln -s "${S}/sheets" "${BUILD_DIR}/sheets" || die
+	# esetup.py test
+	# exclude tests that connect to the network
+	set --  nosetests \
+		-e test_parseUrl -e test_handlers -P "${BUILD_DIR}/lib/cssutils/tests"
+	echo "$@"
+	"$@" || die "Testing failed with ${EPYTHON}"
+}