[gentoo-commits] repo/gentoo:master commit in: dev-libs/libmirage/

["Michał Górny" <mgorny@gentoo.org>]

commit:     a3717395e289afc54b60e4ae03b7aa0ffc41b1f4
Author:     Michał Górny <mgorny <AT> gentoo <DOT> org>
AuthorDate: Tue Mar  5 14:10:48 2019 +0000
Commit:     Michał Górny <mgorny <AT> gentoo <DOT> org>
CommitDate: Tue Mar  5 14:28:59 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a3717395

dev-libs/libmirage: Bump to 3.2.1

Signed-off-by: Michał Górny <mgorny <AT> gentoo.org>

 dev-libs/libmirage/Manifest               |  1 +
 dev-libs/libmirage/libmirage-3.2.1.ebuild | 51 +++++++++++++++++++++++++++++++
 2 files changed, 52 insertions(+)

diff --git a/dev-libs/libmirage/Manifest b/dev-libs/libmirage/Manifest
index 72a3a8357c9..fdb088ca838 100644
--- a/dev-libs/libmirage/Manifest
+++ b/dev-libs/libmirage/Manifest
@@ -1 +1,2 @@
 DIST libmirage-3.2.0.tar.bz2 234214 BLAKE2B f2b8c42eed89efaeddb8051160c51814b4df45c1ca7cdb4cef683b86ea73dcd1446c6806588a9df0410da5b3971ce8945f2479022f21177237ee8b0d4b18d2d3 SHA512 15507154441b660f5a58e1101d4e6f9931a7640b90d3de5e387274c72be07f367b54a6be34dd31442bc504459414f611ffc39f86ff6a7381a820d059aef1d6d6
+DIST libmirage-3.2.1.tar.bz2 233650 BLAKE2B 2ac7bc30108c0bfbf27524819a5cb3d24fde1abc70f720bec50d37196386cfb46f7f9876c45437aadd79d6f9f3318afe50449a97ad36a7bcedd0872ef434a687 SHA512 fa22c26562eea600a1056e730bfb4690918b09f61be91319229a87975b0468803fa026e8f06bdeb9551ef5242179a3dec023e0fcd7f0773608ff77c32741dea6

diff --git a/dev-libs/libmirage/libmirage-3.2.1.ebuild b/dev-libs/libmirage/libmirage-3.2.1.ebuild
new file mode 100644
index 00000000000..f9e9460bd4d
--- /dev/null
+++ b/dev-libs/libmirage/libmirage-3.2.1.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="6"
+
+inherit cmake-utils xdg-utils
+
+DESCRIPTION="CD and DVD image access library"
+HOMEPAGE="http://cdemu.org"
+SRC_URI="mirror://sourceforge/cdemu/${P}.tar.bz2"
+
+LICENSE="GPL-2+"
+SLOT="0/11" # subslot = libmirage soname version
+KEYWORDS="~amd64 ~hppa ~x86"
+IUSE="doc +introspection"
+
+RDEPEND=">=app-arch/bzip2-1:=
+	>=app-arch/xz-utils-5:=
+	>=dev-libs/glib-2.38:2
+	>=media-libs/libsamplerate-0.1:=
+	>=media-libs/libsndfile-1.0:=
+	sys-libs/zlib:=
+	introspection? ( >=dev-libs/gobject-introspection-1.30 )"
+DEPEND="${RDEPEND}
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-util/gtk-doc )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DGTKDOC_ENABLED="$(usex doc)"
+		-DINTROSPECTION_ENABLED="$(usex introspection)"
+		-DPOST_INSTALL_HOOKS=OFF # avoid sandbox violation, #487304
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	local DOCS=( AUTHORS README )
+	cmake-utils_src_install
+}
+
+pkg_postinst() {
+	xdg_mimeinfo_database_update
+}
+
+pkg_postrm() {
+	xdg_mimeinfo_database_update
+}