[gentoo-commits] repo/gentoo:master commit in: gnome-base/gnome-control-center/

["Mart Raudsepp" <leio@gentoo.org>]

commit:     e0cd6d94a2cbc09b5a276887d8a9c8d44eeb140f
Author:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
AuthorDate: Mon Mar  4 10:55:08 2019 +0000
Commit:     Mart Raudsepp <leio <AT> gentoo <DOT> org>
CommitDate: Mon Mar  4 10:55:34 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=e0cd6d94

gnome-base/gnome-control-center: bump to 3.28.2

colord is no longer partially optional, because it is needed by
display panel for night light anyways, so didn't bother with
making the color profile management panel optional either. It
does mean an unconditional colord-gtk and gnome-color-manager
dep, but so be it - if colord and core code pulled in via
gnome-settings-daemon[colord] already, might as well make full
use of it always.
Instead grilo is now separately optional from gnome-online-accounts,
as this is about background images from flickr, which needs separate
extra runtime deps too.

Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Mart Raudsepp <leio <AT> gentoo.org>

 gnome-base/gnome-control-center/Manifest           |   2 +
 .../gnome-control-center-3.28.2.ebuild             | 149 +++++++++++++++++++++
 gnome-base/gnome-control-center/metadata.xml       |  10 +-
 3 files changed, 155 insertions(+), 6 deletions(-)

diff --git a/gnome-base/gnome-control-center/Manifest b/gnome-base/gnome-control-center/Manifest
index 3f1db77fa71..72ad065bb98 100644
--- a/gnome-base/gnome-control-center/Manifest
+++ b/gnome-base/gnome-control-center/Manifest
@@ -2,3 +2,5 @@ DIST gnome-control-center-3.24.4-patchset.tar.xz 8076 BLAKE2B e70086987957b4c33f
 DIST gnome-control-center-3.24.4.tar.xz 7320232 BLAKE2B 29a5860b8cc27f161451ae8c053db1d28e8c5f8714cbccac7674c00689569ac4e51f7deb0a341e0868b1467a095f87d685ea0ec733f69274f02ecaf5badfef6e SHA512 34a59d4d89971054b1f54e7a7e3cbc3c306a3fbe3cc94adf1241ad37076a6179c93f04a95e51e57982eda57187e578005060d711a5d955734d5a138e61b3598a
 DIST gnome-control-center-3.26.2-patchset.tar.xz 159088 BLAKE2B 521af115f7d4372ecf645b915e9081607a6699528b2914e73f11856fc9a8ae80406c210ad97b5d84b616d324d0c1539e2155c5e6db4920cbd8355b85f21a8e3b SHA512 90bf9e19b98dcc39fe5af6604876e5d9fe31358a4da602fe518589d9b3a9261fee3b3785f40a889295e3e7b38370173d03350f475be576830efa2ad74718c19e
 DIST gnome-control-center-3.26.2.tar.xz 7386516 BLAKE2B 156c24bc2ab60943ade1e255976e29478c9b0e9dbad12921a835ec55f09ad62c71886750a50fa74f2a0afb660cac073c9ff54cef4b72c790b6dd91c7cac8aaa9 SHA512 d3ad9067c7e66a3a6bf5b6c058f3862f6e4b59c0254fd47f0b4a9093f3b7e2d7f1900b510aba8bbdac7c1212a0f6cdd4974c3d04003af63edb72ed3e56f7dbca
+DIST gnome-control-center-3.28.2-patchset.tar.xz 75820 BLAKE2B 7f7cda69248862eb9ddba5d69d84c6cf1e550a9db6d914d4f5327b107d01bcb4b40152889ffc13700a8e777b805b037a267e9b641df65612a86099e0851ab417 SHA512 927287e98d1b958b27a644a90fe3da38ba3040a60e4318268f46e764226906d851148370635ab232748f5ef78cf9406b71025738cdec951582042ce4282914c6
+DIST gnome-control-center-3.28.2.tar.xz 5857128 BLAKE2B 253c220fdc759a26f23210a7665323ccdfb18e5f76652791718f2523badbac1f42c9c0fd75e5505c1e3d5f7391abc344b47cb101741ef35ed60859c4c16d7988 SHA512 3e1b54cf1a603ee7c47d8b0f1fb025405c8d133c9e0dbe0eaf2f287eff82109e95581c79f131d227422d682b7049ccb6e6297dba1ff2276cff5f715308195d7f

diff --git a/gnome-base/gnome-control-center/gnome-control-center-3.28.2.ebuild b/gnome-base/gnome-control-center/gnome-control-center-3.28.2.ebuild
new file mode 100644
index 00000000000..e48ea0dd21f
--- /dev/null
+++ b/gnome-base/gnome-control-center/gnome-control-center-3.28.2.ebuild
@@ -0,0 +1,149 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit gnome.org gnome2-utils meson xdg
+
+DESCRIPTION="GNOME's main interface to configure various aspects of the desktop"
+HOMEPAGE="https://git.gnome.org/browse/gnome-control-center/"
+SRC_URI+=" https://dev.gentoo.org/~leio/distfiles/${P}-patchset.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="2"
+IUSE="+bluetooth +cups debug flickr +gnome-online-accounts +ibus input_devices_wacom kerberos networkmanager v4l wayland"
+REQUIRED_USE="flickr? ( gnome-online-accounts )"
+KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~sh ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~x86-solaris"
+
+# kerberos unfortunately means mit-krb5; build fails with heimdal
+# display panel requires colord and gnome-settings-daemon[colord]
+# wacom panel requires gsd-enums.h from gsd at build time, probably also runtime support
+# printer panel requires cups and smbclient (the latter is not patched yet to be separately optional)
+# >=polkit-0.114 for .policy files gettext ITS
+clutter_gtk_dep="media-libs/clutter-gtk:1.0"
+# First block is toplevel meson.build deps in order of occurrence (plus deeper deps if in same conditional). Second block is dependency() from subdir meson.builds, sorted by directory name occurrence order
+COMMON_DEPEND="
+	gnome-online-accounts? ( >=net-libs/gnome-online-accounts-3.25.3:= )
+	>=media-sound/pulseaudio-2.0[glib]
+	>=sys-apps/accountsservice-0.6.39
+	>=x11-misc/colord-0.1.34:0=
+	>=x11-libs/gdk-pixbuf-2.23.0:2
+	>=dev-libs/glib-2.53.0:2
+	>=gnome-base/gnome-desktop-3.27.90:3=
+	>=gnome-base/gnome-settings-daemon-3.25.90[colord,input_devices_wacom?]
+	>=gnome-base/gsettings-desktop-schemas-3.27.2
+	dev-libs/libxml2:2
+	>=sys-auth/polkit-0.114
+	>=sys-power/upower-0.99:=
+	x11-libs/libX11
+	>=x11-libs/libXi-1.2
+	flickr? ( >=media-libs/grilo-0.3.0:0.3= )
+	>=x11-libs/gtk+-3.22.0:3[X,wayland=]
+	cups? (
+		>=net-print/cups-1.7[dbus]
+		>=net-fs/samba-4.0.0[client]
+	)
+	v4l? (
+		${clutter_gtk_dep}
+		>=media-video/cheese-3.28.0 )
+	ibus? ( >=app-i18n/ibus-1.5.2 )
+	wayland? ( virtual/libgudev )
+	networkmanager? (
+		>=gnome-extra/nm-applet-1.2.0
+		>=net-misc/networkmanager-1.2.0:=[modemmanager]
+		>=net-misc/modemmanager-0.7.990 )
+	bluetooth? ( >=net-wireless/gnome-bluetooth-3.18.2:= )
+	input_devices_wacom? (
+		${clutter_gtk_dep}
+		>=dev-libs/libwacom-0.27
+		>=media-libs/clutter-1.11.3:1.0 )
+	kerberos? ( app-crypt/mit-krb5 )
+
+	x11-libs/cairo[glib]
+	>=x11-libs/colord-gtk-0.1.24
+	net-libs/libsoup:2.4
+	media-libs/fontconfig
+	gnome-base/libgtop:2=
+	>=media-libs/libcanberra-0.13[gtk3]
+	>=dev-libs/libpwquality-1.2.2
+"
+# libgnomekbd needed only for gkbd-keyboard-display tool
+# gnome-color-manager needed for gcm-calibrate and gcm-viewer calls from color panel
+# <gnome-color-manager-3.1.2 has file collisions with g-c-c-3.1.x
+#
+# mouse panel needs a concrete set of X11 drivers at runtime, bug #580474
+# Also we need newer driver versions to allow wacom and libinput drivers to
+# not collide
+#
+# system-config-printer provides org.fedoraproject.Config.Printing service and interface
+# cups-pk-helper provides org.opensuse.cupspkhelper.mechanism.all-edit policykit helper policy
+RDEPEND="${COMMON_DEPEND}
+	|| ( >=sys-apps/systemd-31 ( app-admin/openrc-settingsd sys-auth/consolekit ) )
+	x11-themes/adwaita-icon-theme
+	>=gnome-extra/gnome-color-manager-3.1.2
+	cups? (
+		app-admin/system-config-printer
+		net-print/cups-pk-helper )
+	>=gnome-base/libgnomekbd-3
+	wayland? ( dev-libs/libinput )
+	!wayland? (
+		>=x11-drivers/xf86-input-libinput-0.19.0
+		input_devices_wacom? ( >=x11-drivers/xf86-input-wacom-0.33.0 ) )
+	flickr? ( media-plugins/grilo-plugins:0.3[flickr,gnome-online-accounts] )
+
+	!<gnome-base/gdm-2.91.94
+	!gnome-extra/gnome-media[pulseaudio]
+	!<gnome-extra/gnome-media-2.32.0-r300
+	!<net-wireless/gnome-bluetooth-3.3.2
+"
+# PDEPEND to avoid circular dependency; gnome-session-check-accelerated called by info panel
+# gnome-session-2.91.6-r1 also needed so that 10-user-dirs-update is run at login
+PDEPEND=">=gnome-base/gnome-session-2.91.6-r1"
+
+DEPEND="${COMMON_DEPEND}
+	dev-libs/libxslt
+	app-text/docbook-xsl-stylesheets
+	app-text/docbook-xml-dtd:4.2
+	x11-base/xorg-proto
+	dev-libs/libxml2:2
+	dev-util/gdbus-codegen
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	# Patches from gnome-3-28 branch on top of 3.28.2
+	# Makes some panels and dependencies optional
+	# https://bugzilla.gnome.org/686840, 697478, 700145
+	# Fix some absolute paths to be appropriate for Gentoo
+	"${WORKDIR}"/patches/
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bluetooth)
+		$(meson_use v4l cheese)
+		-Dcups=$(usex cups enabled disabled)
+		-Ddocumentation=true # manpage
+		-Dgoa=$(usex gnome-online-accounts enabled disabled)
+		-Dgrilo=$(usex flickr enabled disabled)
+		$(meson_use ibus)
+		-Dkerberos=$(usex kerberos enabled disabled)
+		$(meson_use networkmanager network_manager)
+		$(meson_use input_devices_wacom wacom)
+		$(meson_use wayland)
+		# bashcompletions installed to $datadir/bash-completion/completions by v3.28.2, which is the same as $(get_bashcompdir)
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	gnome2_schemas_update
+}
+
+pkg_postrm() {
+	xdg_pkg_postrm
+	gnome2_schemas_update
+}

diff --git a/gnome-base/gnome-control-center/metadata.xml b/gnome-base/gnome-control-center/metadata.xml
index 4e40862668d..f1ac0fd9a7b 100644
--- a/gnome-base/gnome-control-center/metadata.xml
+++ b/gnome-base/gnome-control-center/metadata.xml
@@ -6,11 +6,9 @@
 		<name>Gentoo GNOME Desktop</name>
 	</maintainer>
 	<use>
-		<flag name="colord">Support color management using
-			<pkg>x11-misc/colord</pkg></flag>
-		<flag name="gnome-online-accounts">Enable configuration panel for
-			<pkg>net-libs/gnome-online-accounts</pkg> accounts</flag>
-		<flag name="ibus">Enable support for enhanced input methods through
-			<pkg>app-i18n/ibus</pkg></flag>
+		<flag name="colord">Support color management using <pkg>x11-misc/colord</pkg></flag>
+		<flag name="flickr">Add support for using photos from flickr as desktop background</flag>
+		<flag name="gnome-online-accounts">Enable configuration panel for <pkg>net-libs/gnome-online-accounts</pkg> accounts</flag>
+		<flag name="ibus">Enable support for enhanced input methods through <pkg>app-i18n/ibus</pkg></flag>
 	</use>
 </pkgmetadata>