[gentoo-commits] repo/gentoo:master commit in: net-im/pidgin/

["Lars Wendler" <polynomial-c@gentoo.org>]

commit:     05736e5cdde9e44ebeb40dafef124f94ac30fc69
Author:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 17 18:01:27 2019 +0000
Commit:     Lars Wendler <polynomial-c <AT> gentoo <DOT> org>
CommitDate: Sun Feb 17 18:01:39 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=05736e5c

net-im/pidgin: Removed old.

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c <AT> gentoo.org>

 net-im/pidgin/Manifest             |   1 -
 net-im/pidgin/pidgin-2.12.0.ebuild | 268 -------------------------------------
 2 files changed, 269 deletions(-)

diff --git a/net-im/pidgin/Manifest b/net-im/pidgin/Manifest
index dcf2864d2ff..1793616a9ac 100644
--- a/net-im/pidgin/Manifest
+++ b/net-im/pidgin/Manifest
@@ -1,4 +1,3 @@
 DIST pidgin-2.10.9-irc_join_sleep.patch 534 BLAKE2B 0215cebb93993e19e700e4d4974351ab5e9a00ea094775076d8f439569b34c0ec2faaed360965867df58bc42677516983ce11a2601dd322c1bdf2f288253a5b8 SHA512 8de0d6f05e48cd5a3e894576e06c7fb82e4bfc778cce8bb179fa22e2a05f5c2390a0e4c5b626ee4b910a18eab170d8f4be200f435ce408a86575af99e51e3bdf
-DIST pidgin-2.12.0.tar.bz2 9270704 BLAKE2B d12b84c4ff94e4dec67bf5e13607510a4ccd54b81868a244a5078f760b2c1178670fa25149478032437dcee0641547993c027e34e42b5af96e222e14a43d901f SHA512 e87b39888432982ee36332fd14b272f49f7974de9e8694f7fe3bec2821748d6e6026ac5a63615a93386a033d6ee7c4de5ae0a86b725f63b9cc55650f0ab94b06
 DIST pidgin-2.13.0.tar.bz2 8994457 BLAKE2B 32be31509a90b924fba4a4dbaba304580d88dfc6d3bbe0c88ef12eef381f70e031af1a55ada2abfb6968a9967a9fdadfa69973482b80dea7bb554a983a96fa12 SHA512 68b3d1eefee111544c7eb347386d0aea4f47c3e320d5963a4e0d833ed6af7b1be243a7bcd6a38c9234b58601d10a9aebf8541f1d97decfeca754fa78dc693047
 DIST pidgin-eds-3.6.patch.bz2 2352 BLAKE2B 1d69dc55f43b9efe5d5278a017642702d67a297fe2587467ec0fdca7f9888e26640efe9ac2a18f77ae9c523bf125a2cec6d0bf621f0b2b16f55d30df1bf470df SHA512 a0195679ab55ed9c7ea18ace6dbf0fc994698f1f4eea9d8335dfdcdcd6a68975c0191bd22f150bf5a9a0a691ce7e9e73d79598e1e8be541efa1d9824a633d877

diff --git a/net-im/pidgin/pidgin-2.12.0.ebuild b/net-im/pidgin/pidgin-2.12.0.ebuild
deleted file mode 100644
index 7ae41c6756a..00000000000
--- a/net-im/pidgin/pidgin-2.12.0.ebuild
+++ /dev/null
@@ -1,268 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-GENTOO_DEPEND_ON_PERL=no
-PYTHON_COMPAT=( python2_7 )
-
-inherit autotools flag-o-matic gnome2 toolchain-funcs multilib perl-module python-single-r1
-
-DESCRIPTION="GTK Instant Messenger client"
-HOMEPAGE="http://pidgin.im/"
-SRC_URI="
-	mirror://sourceforge/${PN}/${P}.tar.bz2
-	https://dev.gentoo.org/~polynomial-c/${PN}-eds-3.6.patch.bz2
-	https://gist.githubusercontent.com/imcleod/77f38d11af11b2413ada/raw/46e9d6cb4d2f839832dad2d697bb141a88028e04/pidgin-irc-join-sleep.patch -> ${PN}-2.10.9-irc_join_sleep.patch"
-
-LICENSE="GPL-2"
-SLOT="0/2" # libpurple version
-KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-macos"
-IUSE="dbus debug doc eds gadu gnutls +gstreamer +gtk idn meanwhile pie"
-IUSE+=" networkmanager nls perl silc tcl tk spell sasl ncurses"
-IUSE+=" groupwise prediction python +xscreensaver zephyr zeroconf" # mono"
-IUSE+=" aqua"
-
-# dbus requires python to generate C code for dbus bindings (thus DEPEND only).
-# finch uses libgnt that links with libpython - {R,}DEPEND. But still there is
-# no way to build dbus and avoid libgnt linkage with python. If you want this
-# send patch upstream.
-# purple-url-handler and purple-remote require dbus-python thus in reality we
-# rdepend on python if dbus enabled. But it is possible to separate this dep.
-RDEPEND="
-	>=dev-libs/glib-2.16
-	>=dev-libs/libxml2-2.6.18
-	ncurses? (
-		sys-libs/ncurses:0=[unicode]
-		dbus? ( ${PYTHON_DEPS} )
-		python? ( ${PYTHON_DEPS} )
-	)
-	gtk? (
-		>=x11-libs/gtk+-2.10:2[aqua=]
-		x11-libs/libSM
-		xscreensaver? ( x11-libs/libXScrnSaver )
-		spell? ( >=app-text/gtkspell-2.0.2:2 )
-		eds? ( >=gnome-extra/evolution-data-server-3.6:= )
-		prediction? ( >=dev-db/sqlite-3.3:3 )
-	)
-	gstreamer? (
-		media-libs/gstreamer:1.0
-		media-libs/gst-plugins-base:1.0
-		>=net-libs/farstream-0.2.7:0.2
-	)
-	zeroconf? ( net-dns/avahi[dbus] )
-	dbus? (
-		>=dev-libs/dbus-glib-0.71
-		>=sys-apps/dbus-0.90
-		dev-python/dbus-python
-	)
-	perl? ( >=dev-lang/perl-5.16:= )
-	gadu? (
-		|| (
-			>=net-libs/libgadu-1.11.0[ssl,gnutls]
-			>=net-libs/libgadu-1.11.0[-ssl]
-		)
-	)
-	gnutls? ( net-libs/gnutls )
-	!gnutls? (
-		dev-libs/nspr
-		dev-libs/nss
-	)
-	meanwhile? ( net-libs/meanwhile )
-	silc? ( >=net-im/silc-toolkit-1.0.1 )
-	tcl? ( dev-lang/tcl:0= )
-	tk? ( dev-lang/tk:0= )
-	sasl? ( dev-libs/cyrus-sasl:2 )
-	networkmanager? ( net-misc/networkmanager )
-	idn? ( net-dns/libidn:= )
-	!<x11-plugins/pidgin-facebookchat-1.69-r1"
-	# Mono support crashes pidgin
-	#mono? ( dev-lang/mono )"
-
-# We want nls in case gtk is enabled, bug #
-NLS_DEPEND=">=dev-util/intltool-0.41.1 sys-devel/gettext"
-
-DEPEND="$RDEPEND
-	dev-lang/perl
-	dev-perl/XML-Parser
-	virtual/pkgconfig
-	gtk? (
-		x11-base/xorg-proto
-		${NLS_DEPEND}
-	)
-	dbus? ( ${PYTHON_DEPS} )
-	doc? ( app-doc/doxygen )
-	!gtk? ( nls? ( ${NLS_DEPEND} ) )"
-
-DOCS="AUTHORS HACKING NEWS README ChangeLog"
-
-REQUIRED_USE="
-	dbus? ( ${PYTHON_REQUIRED_USE} )
-	networkmanager? ( dbus )
-	python? ( ${PYTHON_REQUIRED_USE} )
-"
-
-# Enable Default protocols
-DYNAMIC_PRPLS="irc,jabber,oscar,simple"
-
-# List of plugins
-#   app-accessibility/pidgin-festival
-#   net-im/librvp
-#   x11-plugins/guifications
-#	x11-plugins/msn-pecan
-#   x11-plugins/pidgin-encryption
-#   x11-plugins/pidgin-extprefs
-#   x11-plugins/pidgin-hotkeys
-#   x11-plugins/pidgin-latex
-#   x11-plugins/pidgintex
-#   x11-plugins/pidgin-libnotify
-#	x11-plugins/pidgin-mbpurple
-#	x11-plugins/pidgin-bot-sentry
-#   x11-plugins/pidgin-otr
-#   x11-plugins/pidgin-rhythmbox
-#   x11-plugins/purple-plugin_pack
-#   x11-themes/pidgin-smileys
-#	x11-plugins/pidgin-knotify
-# Plugins in Sunrise:
-#	x11-plugins/pidgin-audacious-remote
-#	x11-plugins/pidgin-autoanswer
-#	x11-plugins/pidgin-birthday-reminder
-#	x11-plugins/pidgin-blinklight
-#	x11-plugins/pidgin-convreverse
-#	x11-plugins/pidgin-embeddedvideo
-#	x11-plugins/pidgin-extended-blist-sort
-#	x11-plugins/pidgin-gfire
-#	x11-plugins/pidgin-lastfm
-#	x11-plugins/pidgin-sendscreenshot
-#	x11-plugins/pidgimpd
-
-PATCHES=(
-	"${FILESDIR}/${PN}-2.10.0-gold.patch"
-	"${WORKDIR}/${PN}-eds-3.6.patch"
-	"${FILESDIR}/${PN}-2.10.9-fix-gtkmedia.patch"
-	"${FILESDIR}/${PN}-2.10.10-eds-3.6-configure.ac.patch"
-	"${FILESDIR}/${PN}-2.10.11-tinfo.patch"
-	"${DISTDIR}/${PN}-2.10.9-irc_join_sleep.patch" # 577286
-)
-
-pkg_setup() {
-	if ! use gtk && ! use ncurses ; then
-		elog "You did not pick the ncurses or gtk use flags, only libpurple"
-		elog "will be built."
-	fi
-	if use python || use dbus ; then
-		python-single-r1_pkg_setup
-	fi
-
-	# dbus is enabled, no way to disable linkage with python => python is enabled
-	#REQUIRED_USE="gtk? ( nls ) dbus? ( python )"
-	if use gtk && ! use nls; then
-		ewarn "gtk build => nls is enabled!"
-	fi
-	if use dbus && ! use python; then
-		elog "dbus is enabled, no way to disable linkage with python => python is enabled"
-	fi
-}
-
-src_prepare() {
-	default
-	eautoreconf
-}
-
-src_configure() {
-	# Stabilize things, for your own good
-	strip-flags
-	replace-flags -O? -O2
-	use pie && append-cflags -fPIE -pie
-
-	local myconf=()
-
-	use gadu 	&& DYNAMIC_PRPLS+=",gg"
-	use groupwise 	&& DYNAMIC_PRPLS+=",novell"
-	use silc 	&& DYNAMIC_PRPLS+=",silc"
-	use meanwhile 	&& DYNAMIC_PRPLS+=",sametime"
-	use zephyr 	&& DYNAMIC_PRPLS+=",zephyr"
-	use zeroconf 	&& DYNAMIC_PRPLS+=",bonjour"
-
-	if use gnutls; then
-		einfo "Disabling NSS, using GnuTLS"
-		myconf+=( --enable-nss=no --enable-gnutls=yes )
-		myconf+=( --with-gnutls-includes="${EPREFIX}/usr/include/gnutls" )
-		myconf+=( --with-gnutls-libs="${EPREFIX}/usr/$(get_libdir)" )
-	else
-		einfo "Disabling GnuTLS, using NSS"
-		myconf+=( --enable-gnutls=no --enable-nss=yes )
-	fi
-
-	if use dbus || { use ncurses && use python ; } ; then
-		myconf+=( --with-python=${PYTHON} )
-	else
-		myconf+=( --without-python )
-	fi
-
-	local myeconfargs=(
-		--disable-mono
-		--with-dynamic-prpls="${DYNAMIC_PRPLS}"
-		--with-system-ssl-certs="${EPREFIX}/etc/ssl/certs/"
-		--x-includes="${EPREFIX}"/usr/include/X11
-		$(use_enable ncurses consoleui)
-		$(use_enable gtk gtkui)
-		$(use_enable gtk sm)
-		$(usex gtk '--enable-nls' "$(use_enable nls)")
-		$(use gtk && use_enable xscreensaver screensaver)
-		$(use gtk && use_enable prediction cap)
-		$(use gtk && use_enable eds gevolution)
-		$(use gtk && use_enable spell gtkspell)
-		$(use_enable perl)
-		$(use_enable tk)
-		$(use_enable tcl)
-		$(use_enable debug)
-		$(use_enable dbus)
-		$(use_enable meanwhile)
-		$(use_enable gstreamer)
-		$(use_with gstreamer gstreamer 1.0)
-		$(use_enable gstreamer farstream)
-		$(use_enable gstreamer vv)
-		$(use_enable sasl cyrus-sasl )
-		$(use_enable doc doxygen)
-		$(use_enable networkmanager nm)
-		$(use_enable zeroconf avahi)
-		$(use_enable idn)
-		${myconf[@]}
-	)
-	econf "${myeconfargs[@]}"
-}
-
-src_install() {
-	gnome2_src_install
-
-	if use gtk; then
-		# Fix tray pathes for e16 (x11-wm/enlightenment) and other
-		# implementations that are not complient with new hicolor theme yet, #323355
-		local pixmapdir
-		for d in 16 22 32 48; do
-			pixmapdir=${ED}/usr/share/pixmaps/pidgin/tray/hicolor/${d}x${d}/actions
-			mkdir "${pixmapdir}" || die
-			pushd "${pixmapdir}" >/dev/null || die
-			for f in ../status/*; do
-				ln -s ${f} || die
-			done
-			popd >/dev/null
-		done
-	fi
-	use perl && perl_delete_localpod
-
-	if use python && use dbus ; then
-		python_fix_shebang "${D}"
-		python_optimize
-	fi
-
-	dodoc ${DOCS} finch/plugins/pietray.py
-	docompress -x /usr/share/doc/${PF}/pietray.py
-
-	find "${ED}" \( -name "*.a" -o -name "*.la" \) -delete || die
-}
-
-src_test() {
-	emake check
-}