[gentoo-commits] proj/kde:master commit in: x11-misc/xdg-desktop-portal/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     a7a03fdd41da7cdc8cde7d822676f5568480c9bb
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Sun Feb 17 10:40:50 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Sun Feb 17 11:09:35 2019 +0000
URL:        https://gitweb.gentoo.org/proj/kde.git/commit/?id=a7a03fdd

x11-misc/xdg-desktop-portal: 1.2.0 version bump, add USE geoclue

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../xdg-desktop-portal-1.2.0.ebuild                | 47 ++++++++++++++++++++++
 1 file changed, 47 insertions(+)

diff --git a/x11-misc/xdg-desktop-portal/xdg-desktop-portal-1.2.0.ebuild b/x11-misc/xdg-desktop-portal/xdg-desktop-portal-1.2.0.ebuild
new file mode 100644
index 0000000000..90099e8c1c
--- /dev/null
+++ b/x11-misc/xdg-desktop-portal/xdg-desktop-portal-1.2.0.ebuild
@@ -0,0 +1,47 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools systemd
+
+DESCRIPTION="Desktop integration portal"
+HOMEPAGE="https://flatpak.org/ https://github.com/flatpak/xdg-desktop-portal"
+SRC_URI="https://github.com/flatpak/${PN}/releases/download/${PV}/${P}.tar.xz"
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc geolocation"
+
+BDEPEND="
+	dev-util/gdbus-codegen
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? (
+		app-text/xmlto
+		app-text/docbook-xml-dtd:4.3
+	)
+"
+DEPEND="
+	dev-libs/glib:2[dbus]
+	sys-fs/fuse:0
+	geolocation? ( app-misc/geoclue:2.0 )
+"
+RDEPEND="${DEPEND}"
+
+src_prepare() {
+	default
+	sed -e "/^PKG_CHECK_MODULES(FLATPAK/s/^/# DONT /" -i configure.ac || die
+	eautoreconf
+}
+
+src_configure() {
+	local myeconfargs=(
+		--disable-pipewire
+		--with-systemduserunitdir="$(systemd_get_userunitdir)"
+		$(use_enable doc docbook-docs)
+		$(use_enable geolocation geoclue)
+	)
+	econf "${myeconfargs[@]}"
+}