[gentoo-commits] repo/gentoo:master commit in: dev-libs/libevent/

["Aaron Bauman" <bman@gentoo.org>]

commit:     fe3f91852f725c56ef363c82f49fee5220f157ce
Author:     Stefan Strogin <stefan.strogin <AT> gmail <DOT> com>
AuthorDate: Sat Feb 16 08:01:16 2019 +0000
Commit:     Aaron Bauman <bman <AT> gentoo <DOT> org>
CommitDate: Sat Feb 16 18:58:25 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fe3f9185

dev-libs/libevent: fix slot operator for libressl dependency

Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Stefan Strogin <stefan.strogin <AT> gmail.com>
Closes: https://github.com/gentoo/gentoo/pull/11065
Signed-off-by: Aaron Bauman <bman <AT> gentoo.org>

 dev-libs/libevent/libevent-2.1.8-r1.ebuild | 66 ++++++++++++++++++++++++++++++
 1 file changed, 66 insertions(+)

diff --git a/dev-libs/libevent/libevent-2.1.8-r1.ebuild b/dev-libs/libevent/libevent-2.1.8-r1.ebuild
new file mode 100644
index 00000000000..a9e66dc5bce
--- /dev/null
+++ b/dev-libs/libevent/libevent-2.1.8-r1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit autotools eutils multilib-minimal
+
+DESCRIPTION="Library to execute a function when a specific event occurs on a file descriptor"
+HOMEPAGE="http://libevent.org/ https://github.com/libevent/libevent/"
+SRC_URI="https://github.com/${PN}/${PN}/releases/download/release-${PV}-stable/${P}-stable.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+# libevent-2.1.so.6
+SLOT="0/2.1-6"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
+IUSE="debug libressl +ssl static-libs test +threads"
+
+DEPEND="
+	ssl? (
+		!libressl? ( >=dev-libs/openssl-1.0.1h-r2:0=[${MULTILIB_USEDEP}] )
+		libressl? ( dev-libs/libressl:0=[${MULTILIB_USEDEP}] )
+	)
+"
+RDEPEND="
+	${DEPEND}
+	!<=dev-libs/9libs-1.0
+"
+
+MULTILIB_WRAPPED_HEADERS=(
+	/usr/include/event2/event-config.h
+)
+
+S=${WORKDIR}/${P}-stable
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+multilib_src_configure() {
+	# fix out-of-source builds
+	mkdir -p test || die
+
+	ECONF_SOURCE="${S}" \
+	econf \
+		--disable-samples \
+		$(use_enable debug debug-mode) \
+		$(use_enable debug malloc-replacement) \
+		$(use_enable ssl openssl) \
+		$(use_enable static-libs static) \
+		$(use_enable test libevent-regress) \
+		$(use_enable threads thread-support)
+}
+
+src_test() {
+	# The test suite doesn't quite work (see bug #406801 for the latest
+	# installment in a riveting series of reports).
+	:
+	# emake -C test check | tee "${T}"/tests
+}
+
+DOCS=( ChangeLog{,-1.4,-2.0} )
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}