[gentoo-commits] repo/gentoo:master commit in: dev-db/sqlitebrowser/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     a8edb29d6d2db42e46a490989b39bda11511b5e8
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Thu Feb 14 21:45:55 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Thu Feb 14 23:06:32 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=a8edb29d

dev-db/sqlitebrowser: Fix RDEPENDs, gnome2-utils -> xdg, EAPI-7 bump

Closes: https://bugs.gentoo.org/664496
Package-Manager: Portage-2.3.60, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../sqlitebrowser/sqlitebrowser-3.10.1-r1.ebuild   | 59 ++++++++++++++++++++++
 1 file changed, 59 insertions(+)

diff --git a/dev-db/sqlitebrowser/sqlitebrowser-3.10.1-r1.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-3.10.1-r1.ebuild
new file mode 100644
index 00000000000..009bf7b5d94
--- /dev/null
+++ b/dev-db/sqlitebrowser/sqlitebrowser-3.10.1-r1.ebuild
@@ -0,0 +1,59 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils desktop xdg
+
+DESCRIPTION="SQLite Database Browser"
+HOMEPAGE="https://sqlitebrowser.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="test"
+
+BDEPEND="
+	dev-qt/linguist-tools:5
+	test? ( dev-qt/qttest:5 )
+"
+DEPEND="
+	dev-cpp/antlr-cpp:2
+	dev-db/sqlite:3
+	>=dev-libs/qcustomplot-2.0.0[qt5(+)]
+	dev-qt/qtcore:5
+	dev-qt/qtgui:5
+	dev-qt/qtnetwork:5[ssl]
+	dev-qt/qtwidgets:5
+	>=x11-libs/qscintilla-2.10.1:=[qt5(+)]
+"
+RDEPEND="${DEPEND}
+	app-editors/qhexedit2
+	dev-qt/qtsvg:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.10.1-unbundle.patch )
+
+src_prepare() {
+	cmake-utils_src_prepare
+	find libs/{antlr-2.7.7,qcustomplot-source,qscintilla} -delete || die
+
+	sed -e "/^project/ s/\".*\"/sqlitebrowser/" -i CMakeLists.txt || die
+
+	if ! use test; then
+		sed -e "/qt5_use_modules/ s/ Test//" -i CMakeLists.txt || die
+	fi
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DENABLE_TESTING=$(usex test)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doicon images/sqlitebrowser.svg
+}