From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1069106-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (unknown [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id EF3E3138334
for <garchives@archives.gentoo.org>; Sun, 27 Jan 2019 16:37:23 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 006E7E1257;
Sun, 27 Jan 2019 16:37:23 +0000 (UTC)
Received: from smtp.gentoo.org (woodpecker.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id B4E04E1257
for <gentoo-commits@lists.gentoo.org>; Sun, 27 Jan 2019 16:37:22 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id ABBA1335D60
for <gentoo-commits@lists.gentoo.org>; Sun, 27 Jan 2019 16:37:20 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 551344FA
for <gentoo-commits@lists.gentoo.org>; Sun, 27 Jan 2019 16:37:19 +0000 (UTC)
From: "Jeroen Roovers" <jer@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Jeroen Roovers" <jer@gentoo.org>
Message-ID: <1548607036.ad489cd37d5f1b6af6ddc14d961b706e9b968872.jer@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: net-misc/youtube-dl/
X-VCS-Repository: repo/gentoo
X-VCS-Files: net-misc/youtube-dl/Manifest net-misc/youtube-dl/youtube-dl-2019.01.27.ebuild
X-VCS-Directories: net-misc/youtube-dl/
X-VCS-Committer: jer
X-VCS-Committer-Name: Jeroen Roovers
X-VCS-Revision: ad489cd37d5f1b6af6ddc14d961b706e9b968872
X-VCS-Branch: master
Date: Sun, 27 Jan 2019 16:37:19 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: dc516870-2aad-4b6b-b212-1d502f8fcc2c
X-Archives-Hash: 8f666e6b5b8d4f5790554d349d879dd7
commit: ad489cd37d5f1b6af6ddc14d961b706e9b968872
Author: Jeroen Roovers <jer <AT> gentoo <DOT> org>
AuthorDate: Sun Jan 27 16:30:07 2019 +0000
Commit: Jeroen Roovers <jer <AT> gentoo <DOT> org>
CommitDate: Sun Jan 27 16:37:16 2019 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=ad489cd3
net-misc/youtube-dl: Version 2019.01.27
Package-Manager: Portage-2.3.58, Repoman-2.3.12
Signed-off-by: Jeroen Roovers <jer <AT> gentoo.org>
net-misc/youtube-dl/Manifest | 1 +
net-misc/youtube-dl/youtube-dl-2019.01.27.ebuild | 117 +++++++++++++++++++++++
2 files changed, 118 insertions(+)
diff --git a/net-misc/youtube-dl/Manifest b/net-misc/youtube-dl/Manifest
index 319444a9b49..b3db9a85c1e 100644
--- a/net-misc/youtube-dl/Manifest
+++ b/net-misc/youtube-dl/Manifest
@@ -1,2 +1,3 @@
DIST youtube-dl-2019.01.17.tar.gz 3088912 BLAKE2B 6cd46442d78126b3428135fcb820eb02bb2d567fe41fbfefcd80fc68a9ece0faaf2aa4981e31c619c3be1f789a9539236b1a71e72490c4ee667953837b25f0e5 SHA512 b8e81c2b2ec284033a5a92f49a965375d681d92435bc0402bb891b443f94d1321716a15717fe4e3c1fbc54ec610445282c52c18c046e140dd53731560230bd3f
DIST youtube-dl-2019.01.24.tar.gz 3099596 BLAKE2B e8833a0432e32e843ed8a3e971b9572bc0f4f8e90ea9c26fe6426ccc95231d21cf85601615634611129405115fe1d3fc192f423c0d700beab7fbccfcfe25dc68 SHA512 23d81769dc202c6598a8ece772f104ed7a048464b3d14305492e562aa77dc77ef32e56ae7a1084b144460e18dcfb2a9d7813ef88f7fdc34760f62f4de23e4602
+DIST youtube-dl-2019.01.27.tar.gz 3102349 BLAKE2B 4d078cacc220e7c0ec46a395c58fddcefbdc4c6abfb68ba36eec0aa8a4506896132ac14c0edf1cafb8d55473931d1ce7f80cf0b08f2217c72c16d8084ed7afaf SHA512 33c7ac784b57feaa7b28b1cc0916f722fd958d111e3caeff6edf30bfe7d4f96bd61ee666dfaf672c75f1da7abc7d54510f7c9b7d7fdc2479e0dfd4625f4c6a42
diff --git a/net-misc/youtube-dl/youtube-dl-2019.01.27.ebuild b/net-misc/youtube-dl/youtube-dl-2019.01.27.ebuild
new file mode 100644
index 00000000000..6ef55f59a57
--- /dev/null
+++ b/net-misc/youtube-dl/youtube-dl-2019.01.27.ebuild
@@ -0,0 +1,117 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="7"
+PYTHON_COMPAT=(python{2_7,3_4,3_5,3_6})
+inherit bash-completion-r1 distutils-r1 readme.gentoo-r1
+
+DESCRIPTION="Download videos from YouTube.com (and more sites...)"
+HOMEPAGE="https://rg3.github.com/youtube-dl/"
+SRC_URI="https://youtube-dl.org/downloads/${PV}/${P}.tar.gz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ppc ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
+IUSE="+offensive test"
+
+RDEPEND="
+ dev-python/setuptools[${PYTHON_USEDEP}]
+"
+DEPEND="
+ ${RDEPEND}
+ test? ( dev-python/nose[coverage(+)] )
+"
+
+S="${WORKDIR}/${PN}"
+
+python_prepare_all() {
+ if ! use offensive; then
+ sed -i -e "/..version../s|'$|+gentoo.no.offensive.sites'|g" \
+ youtube_dl/version.py || die
+ # these have single line import statements
+ local xxx=(
+ alphaporno anysex behindkink camwithher chaturbate eporner
+ eroprofile extremetube foxgay goshgay hellporno hentaistigma
+ hornbunny keezmovies lovehomeporn mofosex myvidster porn91 porncom
+ pornflip pornhd pornotube pornovoisines pornoxo ruleporn sexu
+ slutload spankbang spankwire sunporno thisav vporn watchindianporn
+ xbef xnxx xtube xvideos xxxymovies youjizz youporn
+ )
+ # these have multi-line import statements
+ local mxxx=(
+ drtuber fourtube motherless pornhub redtube tnaflix tube8 xhamster
+ )
+ # do single line imports
+ sed -i \
+ -e $( printf '/%s/d;' ${xxx[@]} ) \
+ youtube_dl/extractor/extractors.py \
+ || die
+
+ # do multiple line imports
+ sed -i \
+ -e $( printf '/%s/,/)/d;' ${mxxx[@]} ) \
+ youtube_dl/extractor/extractors.py \
+ || die
+
+ sed -i \
+ -e $( printf '/%s/d;' ${mxxx[@]} ) \
+ youtube_dl/extractor/generic.py \
+ || die
+
+ rm \
+ $( printf 'youtube_dl/extractor/%s.py ' ${xxx[@]} ) \
+ $( printf 'youtube_dl/extractor/%s.py ' ${mxxx[@]} ) \
+ test/test_age_restriction.py \
+ || die
+ fi
+
+ eapply_user
+
+ distutils-r1_python_prepare_all
+}
+
+src_compile() {
+ distutils-r1_src_compile
+}
+
+python_test() {
+ emake test
+}
+
+python_install_all() {
+ dodoc README.txt
+ doman ${PN}.1
+
+ newbashcomp ${PN}.bash-completion ${PN}
+
+ insinto /usr/share/zsh/site-functions
+ newins ${PN}.zsh _${PN}
+
+ insinto /usr/share/fish/vendor_completions.d
+ doins ${PN}.fish
+
+ distutils-r1_python_install_all
+
+ rm -r "${ED}"/usr/etc || die
+ rm -r "${ED}"/usr/share/doc/youtube_dl || die
+}
+
+pkg_postinst() {
+ elog "${PN}(1) / https://bugs.gentoo.org/355661 /"
+ elog "https://github.com/rg3/${PN}/blob/master/README.md#faq :"
+ elog
+ elog "${PN} works fine on its own on most sites. However, if you want"
+ elog "to convert video/audio, you'll need avconf (media-video/libav) or"
+ elog "ffmpeg (media-video/ffmpeg). On some sites - most notably YouTube -"
+ elog "videos can be retrieved in a higher quality format without sound."
+ elog "${PN} will detect whether avconv/ffmpeg is present and"
+ elog "automatically pick the best option."
+ elog
+ elog "Videos or video formats streamed via RTMP protocol can only be"
+ elog "downloaded when rtmpdump (media-video/rtmpdump) is installed."
+ elog "Downloading MMS and RTSP videos requires either mplayer"
+ elog "(media-video/mplayer) or mpv (media-video/mpv) to be installed."
+ elog
+ elog "If you want ${PN} to embed thumbnails from the metadata into the"
+ elog "resulting MP4 files, consider installing media-video/atomicparsley"
+}