[gentoo-commits] repo/gentoo:master commit in: sci-geosciences/merkaartor/

["Andreas Sturmlechner" <asturm@gentoo.org>]

commit:     92c5867ebd7a58c7b73a6d279c5b1d6a933088fd
Author:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Jan  9 11:21:02 2019 +0000
Commit:     Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Jan  9 11:51:58 2019 +0000
URL:        https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=92c5867e

sci-geosciences/merkaartor: Drop 0.18.3-r3

Package-Manager: Portage-2.3.54, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>

 .../merkaartor/merkaartor-0.18.3-r3.ebuild         | 91 ----------------------
 1 file changed, 91 deletions(-)

diff --git a/sci-geosciences/merkaartor/merkaartor-0.18.3-r3.ebuild b/sci-geosciences/merkaartor/merkaartor-0.18.3-r3.ebuild
deleted file mode 100644
index 19e627bdad4..00000000000
--- a/sci-geosciences/merkaartor/merkaartor-0.18.3-r3.ebuild
+++ /dev/null
@@ -1,91 +0,0 @@
-# Copyright 1999-2018 Gentoo Foundation
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=6
-
-PLOCALES="ar cs de en es et fr hr hu id_ID it ja nl pl pt_BR pt ru sk sv uk vi zh_CN zh_TW"
-
-inherit gnome2-utils l10n qmake-utils xdg-utils
-
-DESCRIPTION="Qt based map editor for the openstreetmap.org project"
-HOMEPAGE="http://www.merkaartor.be https://github.com/openstreetmap/merkaartor"
-SRC_URI="https://github.com/openstreetmap/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2"
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="debug exif gps libproxy"
-
-RDEPEND="
-	dev-qt/qtconcurrent:5
-	dev-qt/qtcore:5
-	dev-qt/qtgui:5
-	dev-qt/qtprintsupport:5
-	dev-qt/qtsvg:5
-	dev-qt/qtwebkit:5
-	dev-qt/qtwidgets:5
-	dev-qt/qtxml:5
-	dev-qt/qtsingleapplication[X,qt5(+)]
-	>=sci-libs/gdal-1.6.0
-	>=sci-libs/proj-4.6
-	sys-libs/zlib
-	exif? ( media-gfx/exiv2:= )
-	gps? ( >=sci-geosciences/gpsd-3.17-r2 )
-	libproxy? ( net-libs/libproxy )
-"
-DEPEND="${RDEPEND}
-	dev-qt/linguist-tools:5
-	virtual/pkgconfig
-"
-PATCHES=( "${FILESDIR}/${P}-sharedir-pluginsdir.patch" ) # bug 621826
-DOCS=( AUTHORS CHANGELOG )
-
-src_prepare() {
-	default
-
-	my_rm_loc() {
-		sed -i -e "s:../translations/${PN}_${1}.\(ts\|qm\)::" src/src.pro || die
-		rm "translations/${PN}_${1}.ts" || die
-	}
-
-	if [[ -n "$(l10n_get_locales)" ]]; then
-		l10n_for_each_disabled_locale_do my_rm_loc
-		$(qt5_get_bindir)/lrelease src/src.pro || die
-	fi
-
-	# build system expects to be building from git
-	sed -i "${S}"/src/Config.pri -e "s:SION = .*:SION = \"${PV}\":g" || die
-}
-
-src_configure() {
-	# TRANSDIR_SYSTEM is for bug #385671
-	eqmake5 \
-		PREFIX="${ED%/}/usr" \
-		LIBDIR="${ED%/}/usr/$(get_libdir)" \
-		PLUGINS_DIR="/usr/$(get_libdir)/plugins" \
-		SHARE_DIR_PATH="/usr/share/${PN}" \
-		TRANSDIR_MERKAARTOR="${ED%/}/usr/share/${PN}/translations" \
-		TRANSDIR_SYSTEM="${EPREFIX}/usr/share/qt5/translations" \
-		SYSTEM_QTSA=1 \
-		RELEASE=1 \
-		NODEBUG="$(usex debug '0' '1')" \
-		GEOIMAGE="$(usex exif '1' '0')" \
-		GPSDLIB="$(usex gps '1' '0')" \
-		LIBPROXY="$(usex libproxy '1' '0')" \
-		ZBAR=0 \
-		Merkaartor.pro
-}
-
-pkg_preinst() {
-	gnome2_icon_savelist
-}
-
-pkg_postinst() {
-	xdg_desktop_database_update
-	gnome2_icon_cache_update
-}
-
-pkg_postrm() {
-	xdg_desktop_database_update
-	gnome2_icon_cache_update
-}