From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1063129-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id 6345C138334
for <garchives@archives.gentoo.org>; Fri, 21 Dec 2018 17:21:33 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id 1BD4EE0BBE;
Fri, 21 Dec 2018 17:21:32 +0000 (UTC)
Received: from smtp.gentoo.org (dev.gentoo.org [IPv6:2001:470:ea4a:1:5054:ff:fec7:86e4])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id CE324E0BBE
for <gentoo-commits@lists.gentoo.org>; Fri, 21 Dec 2018 17:21:31 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 09858335C8C
for <gentoo-commits@lists.gentoo.org>; Fri, 21 Dec 2018 17:21:29 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 1ED3242F
for <gentoo-commits@lists.gentoo.org>; Fri, 21 Dec 2018 17:21:27 +0000 (UTC)
From: "Matt Turner" <mattst88@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Matt Turner" <mattst88@gentoo.org>
Message-ID: <1545412848.fd1b284e3c0e0e6470b632aa4d2cbcd9280efca7.mattst88@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: dev-libs/libinput/
X-VCS-Repository: repo/gentoo
X-VCS-Files: dev-libs/libinput/Manifest dev-libs/libinput/libinput-1.12.4.ebuild
X-VCS-Directories: dev-libs/libinput/
X-VCS-Committer: mattst88
X-VCS-Committer-Name: Matt Turner
X-VCS-Revision: fd1b284e3c0e0e6470b632aa4d2cbcd9280efca7
X-VCS-Branch: master
Date: Fri, 21 Dec 2018 17:21:27 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 3e43f400-a4e1-49b8-9135-0de10533ebed
X-Archives-Hash: 4dc3cc5d31bd8f7ede02811603278634
commit: fd1b284e3c0e0e6470b632aa4d2cbcd9280efca7
Author: Matt Turner <mattst88 <AT> gentoo <DOT> org>
AuthorDate: Fri Dec 21 17:16:25 2018 +0000
Commit: Matt Turner <mattst88 <AT> gentoo <DOT> org>
CommitDate: Fri Dec 21 17:20:48 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=fd1b284e
dev-libs/libinput: Version bump to 1.12.4
Signed-off-by: Matt Turner <mattst88 <AT> gentoo.org>
dev-libs/libinput/Manifest | 1 +
dev-libs/libinput/libinput-1.12.4.ebuild | 79 ++++++++++++++++++++++++++++++++
2 files changed, 80 insertions(+)
diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 259d4c8253c..dc13e741edd 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -3,3 +3,4 @@ DIST libinput-1.11.3.tar.xz 487408 BLAKE2B 38dc14cf018ca59279e8b6e85fd91f4b29545
DIST libinput-1.12.1.tar.xz 520072 BLAKE2B 2d2b2d82f27ac01ff25b3bf6fd7b77ca56467ab818cdc5d4a641629fed623ef5042915889f54f71b1881595af1d85770bbf4ecfd798c079878efa0a0546c4a36 SHA512 de1714526ee1244e3086729efa5b72724b2b989fa8d04418e633d1ef5a8ea777ae3cd4b8c5b015ca0da2b8cf5b07111bff2283c7d6068abcdfa81c3f71b81d68
DIST libinput-1.12.2.tar.xz 517712 BLAKE2B 3a8b1e5120334d44dcd14461fef4d20d51ec2f910c95bf10e54201dcd8b6ef2913a284940f05f0088ed810c0841b7e3cbfd1b33d7bcce3a81031330cb42bfe18 SHA512 f7122a1d18dd2d0072a34fd9897ebe25a065100b3754052d7ec133bddb56d5c2a5a94950cfc8366ef5d117180c28b3ff99b1a62f3ab95df5ac22f86721fbdc67
DIST libinput-1.12.3.tar.xz 519496 BLAKE2B 15cd2aa14b6ad754534bceb6b99e05fc911666493f38e1c92097f5e08a06b751a17a4b0546176d5450ca8fde205bcb0dc5d7eaffe41739ae1bc6527205d8349b SHA512 cdc512cb53442ae85d5a23e10db9dd3548bcca0de24d7fcc48954a60773563d84d9b10278b6a693ade95d0789bb5d42bbb8b7cf1c178fe85401cb09a5402ff02
+DIST libinput-1.12.4.tar.xz 519596 BLAKE2B 87802d2eb841360ada3216a4064cdf750f43f3bf85377f08d35b4e9144319dc0115b03bf9a67f819c708763c677650100ffb783e8432d3c1a42cfb2355e7acaa SHA512 4e43ed5213059a481e5a73549c8325e5729d08512c4f580b924d4338a1b69dabd77fb612bec418f294c1da96c738ce26e45f8de8fbc222ab1af71a1535b3240f
diff --git a/dev-libs/libinput/libinput-1.12.4.ebuild b/dev-libs/libinput/libinput-1.12.4.ebuild
new file mode 100644
index 00000000000..fd569fa961e
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.12.4.ebuild
@@ -0,0 +1,79 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{2_7,3_{4,5,6,7}} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~sparc ~x86"
+IUSE="doc input_devices_wacom"
+# Tests require write access to udev rules directory which is a no-no for live system.
+# Other tests are just about logs, exported symbols and autotest of the test library.
+RESTRICT="test"
+
+RDEPEND="
+ input_devices_wacom? ( >=dev-libs/libwacom-0.20 )
+ >=dev-libs/libevdev-1.3
+ >=sys-libs/mtdev-1.1
+ virtual/libudev:=
+ virtual/udev
+"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ doc? (
+ $(python_gen_any_dep '
+ dev-python/commonmark[${PYTHON_USEDEP}]
+ dev-python/recommonmark[${PYTHON_USEDEP}]
+ dev-python/sphinx[${PYTHON_USEDEP}]
+ >=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+ ')
+ >=app-doc/doxygen-1.8.3
+ >=media-gfx/graphviz-2.38.0
+ )
+"
+# test? (
+# >=dev-libs/check-0.9.10
+# dev-util/valgrind
+# sys-libs/libunwind )
+
+python_check_deps() {
+ has_version "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+ has_version "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+ has_version ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+ use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+ # gui can be built but will not be installed
+ local emesonargs=(
+ -Ddebug-gui=false
+ $(meson_use doc documentation)
+ $(meson_use input_devices_wacom libwacom)
+ -Dtests=false # tests are restricted
+ -Dudev-dir="$(get_udevdir)"
+ )
+ meson_src_configure
+}
+
+src_install() {
+ meson_src_install
+ if use doc ; then
+ docinto html
+ dodoc -r "${BUILD_DIR}"/Documentation/.
+ fi
+}
+
+pkg_postinst() {
+ udevadm hwdb --update --root="${ROOT%/}"
+}