From mboxrd@z Thu Jan 1 00:00:00 1970
Return-Path: <gentoo-commits+bounces-1061870-garchives=archives.gentoo.org@lists.gentoo.org>
Received: from lists.gentoo.org (pigeon.gentoo.org [208.92.234.80])
(using TLSv1.2 with cipher ECDHE-RSA-AES256-GCM-SHA384 (256/256 bits))
(No client certificate requested)
by finch.gentoo.org (Postfix) with ESMTPS id A1FB1138335
for <garchives@archives.gentoo.org>; Wed, 12 Dec 2018 11:56:23 +0000 (UTC)
Received: from pigeon.gentoo.org (localhost [127.0.0.1])
by pigeon.gentoo.org (Postfix) with SMTP id A3834E08A6;
Wed, 12 Dec 2018 11:56:22 +0000 (UTC)
Received: from smtp.gentoo.org (smtp.gentoo.org [140.211.166.183])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by pigeon.gentoo.org (Postfix) with ESMTPS id 5BAC7E08A6
for <gentoo-commits@lists.gentoo.org>; Wed, 12 Dec 2018 11:56:21 +0000 (UTC)
Received: from oystercatcher.gentoo.org (unknown [IPv6:2a01:4f8:202:4333:225:90ff:fed9:fc84])
(using TLSv1.2 with cipher ECDHE-RSA-AES128-GCM-SHA256 (128/128 bits))
(No client certificate requested)
by smtp.gentoo.org (Postfix) with ESMTPS id 7FC10335CE7
for <gentoo-commits@lists.gentoo.org>; Wed, 12 Dec 2018 11:56:19 +0000 (UTC)
Received: from localhost.localdomain (localhost [IPv6:::1])
by oystercatcher.gentoo.org (Postfix) with ESMTP id 558A24E4
for <gentoo-commits@lists.gentoo.org>; Wed, 12 Dec 2018 11:56:17 +0000 (UTC)
From: "Andreas Sturmlechner" <asturm@gentoo.org>
To: gentoo-commits@lists.gentoo.org
Content-Transfer-Encoding: 8bit
Content-type: text/plain; charset=UTF-8
Reply-To: gentoo-dev@lists.gentoo.org, "Andreas Sturmlechner" <asturm@gentoo.org>
Message-ID: <1544615747.063024b3f99dab58a00b69d56283c7ef5d1fc143.asturm@gentoo>
Subject: [gentoo-commits] repo/gentoo:master commit in: media-libs/mlt/
X-VCS-Repository: repo/gentoo
X-VCS-Files: media-libs/mlt/mlt-6.10.0-r1.ebuild
X-VCS-Directories: media-libs/mlt/
X-VCS-Committer: asturm
X-VCS-Committer-Name: Andreas Sturmlechner
X-VCS-Revision: 063024b3f99dab58a00b69d56283c7ef5d1fc143
X-VCS-Branch: master
Date: Wed, 12 Dec 2018 11:56:17 +0000 (UTC)
Precedence: bulk
List-Post: <mailto:gentoo-commits@lists.gentoo.org>
List-Help: <mailto:gentoo-commits+help@lists.gentoo.org>
List-Unsubscribe: <mailto:gentoo-commits+unsubscribe@lists.gentoo.org>
List-Subscribe: <mailto:gentoo-commits+subscribe@lists.gentoo.org>
List-Id: Gentoo Linux mail <gentoo-commits.gentoo.org>
X-BeenThere: gentoo-commits@lists.gentoo.org
X-Auto-Response-Suppress: DR, RN, NRN, OOF, AutoReply
X-Archives-Salt: 98c2e9a9-c490-4c22-ad85-81d45bf9cb75
X-Archives-Hash: f41d4b058dd003db103e362f66f2f058
commit: 063024b3f99dab58a00b69d56283c7ef5d1fc143
Author: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
AuthorDate: Wed Dec 12 11:55:17 2018 +0000
Commit: Andreas Sturmlechner <asturm <AT> gentoo <DOT> org>
CommitDate: Wed Dec 12 11:55:47 2018 +0000
URL: https://gitweb.gentoo.org/repo/gentoo.git/commit/?id=063024b3
media-libs/mlt: Switch 6.10.0 to ruby24
Bug: https://bugs.gentoo.org/672984
Package-Manager: Portage-2.3.52, Repoman-2.3.12
Signed-off-by: Andreas Sturmlechner <asturm <AT> gentoo.org>
media-libs/mlt/mlt-6.10.0-r1.ebuild | 214 ++++++++++++++++++++++++++++++++++++
1 file changed, 214 insertions(+)
diff --git a/media-libs/mlt/mlt-6.10.0-r1.ebuild b/media-libs/mlt/mlt-6.10.0-r1.ebuild
new file mode 100644
index 00000000000..5b9cd6ea7dc
--- /dev/null
+++ b/media-libs/mlt/mlt-6.10.0-r1.ebuild
@@ -0,0 +1,214 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 )
+# this ebuild currently only supports installing ruby bindings for a single ruby version
+# so USE_RUBY must contain only a single value (the latest stable) as the ebuild calls
+# /usr/bin/${USE_RUBY} directly
+USE_RUBY="ruby24"
+inherit python-single-r1 ruby-single toolchain-funcs
+
+DESCRIPTION="Open source multimedia framework for television broadcasting"
+HOMEPAGE="https://www.mltframework.org/"
+SRC_URI="https://github.com/mltframework/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
+IUSE="compressed-lumas cpu_flags_x86_mmx cpu_flags_x86_sse cpu_flags_x86_sse2 debug ffmpeg fftw frei0r
+gtk jack kdenlive libav libsamplerate lua melt opencv opengl python qt5 rtaudio ruby sdl vdpau xine xml"
+# java perl php tcl vidstab
+IUSE="${IUSE} kernel_linux"
+
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+#rtaudio will use OSS on non linux OSes
+RDEPEND="
+ >=media-libs/libebur128-1.2.2
+ ffmpeg? (
+ libav? ( >=media-video/libav-12:0=[vdpau?] )
+ !libav? ( media-video/ffmpeg:0=[vdpau?] )
+ )
+ fftw? ( sci-libs/fftw:3.0= )
+ frei0r? ( media-plugins/frei0r-plugins )
+ gtk? (
+ media-libs/libexif
+ x11-libs/gtk+:2
+ x11-libs/pango
+ )
+ jack? (
+ >=dev-libs/libxml2-2.5
+ media-libs/ladspa-sdk
+ virtual/jack
+ )
+ libsamplerate? ( >=media-libs/libsamplerate-0.1.2 )
+ lua? ( >=dev-lang/lua-5.1.4-r4:= )
+ opencv? ( >=media-libs/opencv-3.2.0:= )
+ opengl? ( media-video/movit )
+ python? ( ${PYTHON_DEPS} )
+ qt5? (
+ dev-qt/qtcore:5
+ dev-qt/qtgui:5
+ dev-qt/qtsvg:5
+ dev-qt/qtwidgets:5
+ dev-qt/qtxml:5
+ media-libs/libexif
+ x11-libs/libX11
+ )
+ rtaudio? (
+ >=media-libs/rtaudio-4.1.2
+ kernel_linux? ( media-libs/alsa-lib )
+ )
+ ruby? ( ${RUBY_DEPS} )
+ sdl? (
+ media-libs/libsdl2[X,opengl,video]
+ media-libs/sdl2-image
+ )
+ xine? ( >=media-libs/xine-lib-1.1.2_pre20060328-r7 )
+ xml? ( >=dev-libs/libxml2-2.5 )"
+# java? ( >=virtual/jre-1.5 )
+# perl? ( dev-lang/perl )
+# php? ( dev-lang/php )
+# sox? ( media-sound/sox )
+# tcl? ( dev-lang/tcl:0= )
+# vidstab? ( media-libs/libvidstab )
+SWIG_DEPEND=">=dev-lang/swig-2.0"
+DEPEND="${RDEPEND}
+ virtual/pkgconfig
+ compressed-lumas? ( virtual/imagemagick-tools[png] )
+ lua? ( ${SWIG_DEPEND} virtual/pkgconfig )
+ python? ( ${SWIG_DEPEND} )
+ ruby? ( ${SWIG_DEPEND} )"
+# java? ( ${SWIG_DEPEND} >=virtual/jdk-1.5 )
+# perl? ( ${SWIG_DEPEND} )
+# php? ( ${SWIG_DEPEND} )
+# tcl? ( ${SWIG_DEPEND} )
+
+DOCS=( AUTHORS ChangeLog NEWS README docs/{framework,melt,mlt{++,-xml}}.txt )
+
+PATCHES=( "${FILESDIR}"/${P}-swig-underlinking.patch )
+
+pkg_setup() {
+ use python && python-single-r1_pkg_setup
+}
+
+src_prepare() {
+ default
+
+ # respect CFLAGS LDFLAGS when building shared libraries. Bug #308873
+ for x in python lua; do
+ sed -i "/mlt.so/s: -lmlt++ :& ${CFLAGS} ${LDFLAGS} :" src/swig/$x/build || die
+ done
+ sed -i "/^LDFLAGS/s: += :& ${LDFLAGS} :" src/swig/ruby/build || die
+
+ sed -i -e "s/env ruby/${USE_RUBY}/" src/swig/ruby/* || die
+}
+
+src_configure() {
+ tc-export CC CXX
+
+ local myconf=(
+ --enable-gpl
+ --enable-gpl3
+ --enable-motion-est
+ --target-arch=$(tc-arch)
+ --disable-kde
+ --disable-sdl
+ --disable-swfdec
+ $(use_enable debug)
+ $(use compressed-lumas && echo ' --luma-compress')
+ $(use_enable cpu_flags_x86_sse sse)
+ $(use_enable cpu_flags_x86_sse2 sse2)
+ $(use_enable gtk gtk2)
+ $(use_enable jack jackrack)
+ $(use_enable ffmpeg avformat)
+ $(use ffmpeg && echo ' --avformat-swscale')
+ $(use_enable fftw plus)
+ $(use_enable frei0r)
+ $(use_enable melt)
+ $(use_enable opencv)
+ $(use_enable opengl)
+ $(use_enable libsamplerate resample)
+ $(use_enable rtaudio)
+ $(use vdpau && echo ' --avformat-vdpau')
+ $(use_enable sdl sdl2)
+ $(use_enable xml)
+ $(use_enable xine)
+ $(use_enable kdenlive)
+ --disable-sox
+ )
+ #$(use_enable sox) FIXME
+
+ if use qt5 ; then
+ myconf+=(
+ --enable-qt
+ --qt-includedir=$(pkg-config Qt5Core --variable=includedir)
+ --qt-libdir=$(pkg-config Qt5Core --variable=libdir)
+ )
+ else
+ myconf+=( --disable-qt )
+ fi
+
+ if use x86 || use amd64 ; then
+ myconf+=( $(use_enable cpu_flags_x86_mmx mmx) )
+ else
+ myconf+=( --disable-mmx )
+ fi
+
+ if ! use melt; then
+ sed -i -e "s;src/melt;;" Makefile || die
+ fi
+
+ # TODO: add swig language bindings
+ # see also https://www.mltframework.org/twiki/bin/view/MLT/ExtremeMakeover
+
+ local swig_lang
+ # TODO: java perl php tcl
+ for i in lua python ruby ; do
+ use $i && swig_lang="${swig_lang} $i"
+ done
+ [[ -z "${swig_lang}" ]] && swig_lang="none"
+
+ econf ${myconf[@]} --swig-languages="${swig_lang}"
+
+ sed -i -e s/^OPT/#OPT/ "${S}/config.mak" || die
+}
+
+src_install() {
+ emake DESTDIR="${D}" install
+ einstalldocs
+
+ dodir /usr/share/${PN}
+ insinto /usr/share/${PN}
+ doins -r demo
+
+ docinto swig
+
+ # Install SWIG bindings
+ if use lua; then
+ cd "${S}"/src/swig/lua || die
+ exeinto $(pkg-config --variable INSTALL_CMOD lua)
+ doexe mlt.so
+ dodoc play.lua
+ fi
+
+ if use python; then
+ cd "${S}"/src/swig/python || die
+ insinto $(python_get_sitedir)
+ doins mlt.py
+ exeinto $(python_get_sitedir)
+ doexe _mlt.so
+ dodoc play.py
+ python_optimize
+ fi
+
+ if use ruby; then
+ cd "${S}"/src/swig/ruby || die
+ exeinto $("${EPREFIX}"/usr/bin/${USE_RUBY} -r rbconfig -e 'print RbConfig::CONFIG["sitearchdir"]')
+ doexe mlt.so
+ dodoc play.rb thumbs.rb
+ fi
+ # TODO: java perl php tcl
+}